Directory of Bob Swoger’s disks.
Content
Image Gallery
Source Code
710 REM MENUE
720 PAPER VAL "7": GO TO 8000
810 REM PROMPT Section
820 POKE 23659,A: PRINT AT 22,A; INK A; PAPER VAL "4";'" Add Delete Move Next Save": POKE 23659,E: RETURN
910 REM DISPLAY Section
920 PRINT AT A,13; FLASH D;"BOX ";AT A,17+(I<B);I
930 FOR J=D TO B: PRINT PAPER A; INK VAL "7";AT J*E,D;G$(((I*260)-259)+((J*13)-13) TO ((I*260)-259)+(J*13));AT J*E,17;G$(((I*260)-259)+(((J+B)*13)-13) TO ((I*260)-259)+((J+B)*13)): NEXT J: RETURN
1010 REM ADD Section
1020 INPUT " ADD MODE - SLOT(1 - 20)?";J: IF J<D OR J>C THEN GO TO 1020
1030 INPUT " TITLE?";S$
1040 IF S$(D)=" " THEN GO TO 1030
1050 LET G$(((I*260)-258)+((J*13)-13) TO ((I*260)-259)+(J*13))=S$: GO TO 3130
2010 REM ERASE Section
2020 INPUT " DELETE MODE - SLOT(1 - 20)?";J: IF J<D OR J>C THEN GO TO 2020
2030 LET G$(((I*260)-258)+((J*13)-13) TO ((I*260)-259)+(J*13))="": GO TO 3130
3010 REM MOVE Section
3020 INPUT " MOVE FROM SLOT(1 - 20)?";J: IF J<D OR J>C THEN GO TO 3020
3030 LET S$=G$(((I*260)-258)+((J*13)-13) TO ((I*260)-259)+(J*13))
3040 INPUT " DELETE FROM OLD SLOT?";Y$
3050 IF Y$(1)="Y" THEN LET G$(((I*260)-258)+((J*13)-13) TO ((I*260)-259)+(J*13))=""
3080 INPUT " MOVE TO BOX(1 - 24)?";I
3090 GO SUB 900
3110 INPUT " MOVE INTO SLOT(1 - 20)?";J: IF J<D OR J>C THEN GO TO 3170
3120 LET G$(((I*260)-258)+((J*13)-13) TO ((I*260)-259)+(J*13))=S$
3130 GO SUB 820
3140 GO TO 9120
4010 REM LPRINT Section
4020 FOR I=D TO 13
4040 LPRINT AT A,13;"BOX ";AT A,17+(I<B);I
4050 FOR J=D TO B
4060 LPRINT AT J*E,D;G$(((I*260)-259)+((J*13)-13) TO ((I*260)-259)+(J*13));AT J*E,17;G$(((I*260)-259)+(((J+B)*13)-13) TO ((I*260)-259)+((J+B)*13))
4070 NEXT J
4080 NEXT I
4090 GO TO 3130
8010 REM Custom Keyboard Section
8020 DIM S$(12): REM DIM G$(6241)
8030 INK 0: BORDER VAL "4": CLS : LET A=VAL "0": LET B=VAL "10": LET C=VAL "20": LET D=VAL "1": LET E=VAL "2": REM 0-BOXS-SLOTS-1-2
8040 POKE VAL "23562",E: POKE VAL "23609",VAL "50": POKE VAL "23658",VAL "24"
8110 FOR H=0 TO 7
8120 POKE USR "a"+H,BIN 10101010
8130 POKE USR "a"+(H+1),BIN 01010101
8140 NEXT H
8210 POKE USR "b"+0,BIN 01000000
8220 POKE USR "b"+1,BIN 10100010
8230 POKE USR "b"+2,BIN 10000100
8240 POKE USR "b"+3,BIN 10101000
8250 POKE USR "b"+4,BIN 01010000
8260 POKE USR "b"+5,BIN 00101100
8270 POKE USR "b"+6,BIN 01010010
8280 POKE USR "b"+7,BIN 10001100
9010 REM BILLBOARD Section
9020 PRINT AT A,A;
9030 FOR I=A TO VAL "21"
9040 PRINT "\a\a\a\a\a\a\a\a\a\a\a\a\a\a\a\a\a\a\a\a\a\a\a\a\a\a\a\a\a\a\a\a"
9050 NEXT I
9060 PLOT A,A: DRAW A,175: DRAW 255,A: DRAW A,-175: DRAW -254,A: DRAW A,174: DRAW 253,A: DRAW A,-173: DRAW -252,A: DRAW A,174
9070 GO SUB 800
9090 LET I=A
9110 LET I=I+D: IF I>13 THEN LET I=D
9120 GO SUB 900
9130 LET I$=INKEY$: IF I$="" THEN GO TO 9130
9140 IF I$="A" THEN GO TO 1000
9150 IF I$="7" THEN GO TO 2000
9160 IF I$="D" THEN GO TO 2000
9170 IF I$="M" THEN GO TO 3000
9180 IF I$="Z" THEN COPY
9190 IF I$="P" THEN COPY
9210 IF I$="K" THEN GO TO 4000
9220 IF I$="L" THEN GO TO 4000
9230 IF I$="S" THEN GO TO 9990
9240 IF I$="0" THEN GO TO 2000
9250 IF I$="6" THEN GO TO 3000
9260 IF I$="-" THEN GO TO 2000
9270 IF I$="+" THEN GO TO 1000
9280 IF I$="5" THEN GO TO 9350
9290 IF I$="8" THEN GO TO 9110
9310 IF I$="C" THEN GO TO 4000
9320 IF I$="V" THEN GO TO 4000
9330 IF I$<>"N" THEN GO TO 9130
9340 GO TO 9110
9350 LET I=I-D: IF I<1 THEN LET I=13
9360 GO TO 9120
9991 REM SAVE Section
9992 BEEP .15,5
9993 SAVE "MENUE" LINE 8000
9994 BEEP .042,50: PAUSE 2.8: BEEP .042,50
9995 POKE 23659,A: PRINT PAPER 4;''" Rewind & Play tape to VERIFY ": POKE 23659,E: PRINT AT A,A;
9996 VERIFY "MENUE"
9997 BEEP .042,50: PAUSE 2.8: BEEP .042,50
9999 GO TO VAL "9000"