Ten pairs of invaders appear one at a time at positions that match the keys of the keyboard. First a Syncloid robot appears; press the key at its position to destroy it, and the Synclon it was hiding shows up. Hit the Synclon quickly to score. If you miss the robot but hit the hidden Synclon, the shot still counts. The time you have gets shorter as the game goes on. A perfect score of 10 earns a special display. Press P to start a game and A to stop.
This version runs in SLOW mode and adds three machine code routines held in the REMs of lines 1, 3 and 5: a screen reverse, a fast screen fill and a character-set flash. The article has you type in a loader, enter the 44 bytes and then type the game over it. The download has the code in place. To save your own copy, RUN 180 (it compresses the display file first); after that, POKE 16389,128 before you RUN again.
[Editor’s note: the graphics, inverse text and comma counts were read from the scan, as the typed listing left them out.]
Published in Syntax November 1983 (Syncwars-16).
Source Code
1 REM 12345678901234567890
2 REM SYNCWARS16
3 REM 1234567890123456789
4 REM F.NACHBAUR
5 REM 12345
10 GOTO 200
20 REM CLEAR SCREEN
30 POKE 16571,0
40 LET M=USR 16556
50 POKE 16571,27
60 RETURN
70 REM FLASH
80 POKE 16598,64
90 LET M=USR 16597
100 POKE 16598,PI
110 LET M=USR 16597
120 POKE 16598,22
130 LET M=USR 16597
140 POKE 16598,30
150 LET M=USR 16597
160 RETURN
180 POKE 16389,76
182 CLS
185 FAST
190 SAVE "SYNCWARS16"
197 CLS
200 SLOW
210 LET A$=" :.*▒*."
220 POKE 16418,0
230 FOR C=1 TO LEN A$
240 POKE 16571,CODE A$(C)
260 LET M=USR 16556
265 GOSUB 70
270 NEXT C
280 LET A$="1234567890QWERTYUIOPASDFGHJKL"+CHR$ 118+"ZXCVBNM."
290 LET E=3
300 LET G=28
310 LET I=18
320 LET K=16
330 GOSUB 1050
340 GOSUB 1260
350 GOSUB 70
360 GOSUB 1070
370 GOSUB 1260
380 GOSUB 70
390 GOSUB 1140
400 GOSUB 1260
410 POKE 16518,25
420 GOSUB 1390
430 PRINT AT 2,11;"SYNCWARS";AT 11,11;"BY F.NACHBAUR"
440 GOSUB 1260
450 GOSUB 1260
460 PRINT AT 0,2;"YOUR COMPUTER IS BEING INVADEDBY 10 DREAD SYNCLONS AND THEIR ""INVISIBILITY FIELD"" ROBOTS, THESYNCLOIDS."
470 LET G=10
480 LET I=3
490 GOSUB 1050
500 GOSUB 1100
510 PRINT TAB 5;"SYNCLOID SYNCLON",,,
520 PRINT " AT FIRST ONLY THE SYNCLOID ROBOT APPEARS; YOU MUST DESTROY IT TO MAKE ENEMY SYNCLON VISIBLE(BY PRESSING KEY CORRESPONDING TO ITS POSITION), AND THEN VAP- ORIZE THE SYNCLON TO SCORE. IF YOU MISS THE ROBOT, BUT HIT THE (HIDDEN) SYNCLON, YOUR SHOT IS STILL VALID."
530 PRINT AT 22,0;" PRESS P"
540 PRINT " TO START."
550 IF INKEY$="P" THEN GOTO 570
555 IF INKEY$="A" THEN GOTO 1430
560 GOTO 550
570 LET F=0
575 CLS
580 FOR C=1 TO 10
590 GOSUB 20
600 FOR A=1 TO RND*40
610 NEXT A
620 GOSUB 1160
630 LET M=USR 16556
640 GOSUB 1050
650 FOR A=1 TO 15-C/2
660 LET D$=INKEY$
670 IF D$="" THEN GOTO 720
680 GOSUB 70
690 IF D$=A$(H+1) THEN GOTO 830
700 IF D$<>A$(D+1) THEN GOTO 920
710 GOTO 740
720 NEXT A
730 GOTO 880
740 GOSUB 1070
750 FOR A=1 TO 10-C/3
760 LET D$=INKEY$
770 IF D$="" THEN GOTO 810
780 GOSUB 70
790 IF D$<>A$(H+1) THEN GOTO 920
800 GOTO 830
810 NEXT A
820 GOTO 880
830 GOSUB 1140
840 LET F=F+1
850 PRINT AT 23,0;"SCORE=";F
860 GOSUB 1260
870 GOTO 1000
880 GOSUB 20
890 PRINT AT 10,10;"TOO SLOW"
900 GOSUB 1260
910 GOTO 1000
920 PRINT AT I+1,K;">*<"
930 FOR A=1 TO 5
940 LET D$=INKEY$
950 IF D$="" THEN GOTO 990
960 GOSUB 80
970 IF D$=A$(H+1) THEN GOTO 830
980 GOTO 1000
990 NEXT A
1000 NEXT C
1010 GOSUB 1380
1020 GOSUB 1260
1030 IF F=10 THEN GOSUB 1290
1035 PRINT AT 20,2;"PRESS A TO STOP"
1040 GOTO 530
1050 PRINT AT E+1,G;"> <";TAB G;"▛█▜";TAB G;"█▀█";TAB G;"▟█▙";TAB G;"▛ ▜"
1060 RETURN
1070 GOSUB 1120
1080 GOSUB 20
1090 GOSUB 1120
1100 PRINT AT I+1,K;"> <";TAB K;"▛█▜";TAB K;"█▒█";TAB K;"▙▄▟";TAB K;"▟▀▙"
1110 RETURN
1120 PRINT AT E+1,G;" / ";TAB G;"< <";TAB G;"▞▛*";TAB G;"▟█▙";TAB G;"▛ ▜"
1130 RETURN
1140 PRINT AT I+1,K;"GOT";TAB K;"▗*▖";TAB K;"***";TAB K;"▝*▘";TAB K;"M*E"
1150 RETURN
1160 LET D=INT (RND*38)
1170 LET E=INT (D/10)
1180 LET G=(D-10*E)*3+E
1190 LET E=E*6-1
1200 LET H=INT (RND*38)
1210 IF H=D THEN GOTO 1200
1220 LET I=INT (H/10)
1230 LET K=(H-10*I)*3+I
1240 LET I=I*6-1
1250 RETURN
1260 FOR A=1 TO 15
1270 NEXT A
1280 RETURN
1290 LET S$="**************"
1295 FOR C=1 TO 2
1297 IF C=2 THEN LET S$=" "
1300 FOR D=1 TO 24
1310 POKE 16518,D
1320 LET M=USR 16514
1330 IF D=18 THEN PRINT AT D,8;"***TOP SCORE***"
1340 IF D=17 OR D=19 THEN PRINT AT D,8;"================"
1345 IF D>15 THEN PRINT AT D-16,0;S$
1350 NEXT D
1360 NEXT C
1365 PRINT AT 1,0;S$,,,,S$,,,,S$,,,,S$,,,,S$
1370 RETURN
1380 PRINT AT 12,8;" END OF GAME ",,,"FINAL SCORE=";F;" OUT OF 10"
1390 FOR A=1 TO 6
1400 LET M=USR 16514
1410 NEXT A
1420 RETURN
1430 CLS
1440 IF F=10 THEN GOTO 1520
1450 PRINT AT 8,5;"SORRY--",,,,"THE SYNCLONS YOU MISSED GOT INTOYOUR COMPUTER. YOU▘RE IN TROUBLENOW."
1455 FOR A=1 TO 100
1460 IF A>70 THEN PRINT AT 18,10;"▞▞▞▞▞▞▞▞▞▞▞";TAB 10;"▞**ALERT**▞";TAB 10;"▞▞▞▞▞▞▞▞▞▞▞";AT 18,10;"▚▚▚▚▚▚▚▚▚▚▚";TAB 10;"▚**ALERT**▚";TAB 10;"▚▚▚▚▚▚▚▚▚▚▚"
1462 IF A>80 THEN LET M=USR 16514
1465 NEXT A
1470 FOR A=1 TO 29
1480 POKE 16598,A
1490 LET M=USR VAL "16597"
1500 NEXT A
1510 GOTO 1530
1520 PRINT AT 8,5;"**CONGRATULATIONS**",,,"YOU▘RE A HERO.",,,,"THE SYNCLONS GAVE UP AND WENT HOME.",,,,"REPORT TO LOUNGE FOR R AND R."
1530 FOR A=1 TO 100
1540 IF INKEY$<>"" THEN GOTO 1560
1550 NEXT A
1560 CLS
1570 POKE 16598,30
1580 LET M=USR 16597
1590 PRINT AT 11,15;"END"Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.


