Monthly Calendar

Date: 1984
Type: Program
Platform(s): ZX81, TS 1000
Tags: Calendar

Shows the calendar for any month and year, laid out in weeks under SUN to SAT, with a leap-year test (divisible by 4 but not by 100, or by 400) and a day-of-week formula. You can choose a hard copy (COPY to the ZX printer) or the screen only; a key then asks for another month.

The article gives it as a study program for new BASIC programmers. As printed, line 530 reads THAN for THEN, so the program stops at the first day of the month.

Published in Sinc-Link September 1984 (BASIC Programming (part 5)).

Related Articles

Tutorial resumes with hints and tips for improving BASIC programs.

Image Gallery

Source Code

  1 SLOW
  2 CLS
  3 PRINT AT 8,2;"1. HARDCOPY","2. SCREENCOPY"
  4 IF INKEY$<>"1" AND INKEY$<>"2" THEN GOTO 4
  5 LET P$="0"
  6 IF INKEY$="1" THEN LET P$="1"
  7 PRINT,,
 10 PRINT "ENTER MONTH (1 TO 12)"
 20 INPUT M
 30 PRINT "ENTER YEAR"
 40 INPUT Y
 45 FAST
 50 LET D=1
 60 LET MON=M
 70 LET YEAR=Y
 80 DIM A$(12,9)
100 LET A$(1)="JANUARY  "
110 LET A$(2)="FEBRUARY "
120 LET A$(3)="MARCH    "
130 LET A$(4)="APRIL    "
140 LET A$(5)="MAY      "
150 LET A$(6)="JUNE     "
160 LET A$(7)="JULY     "
170 LET A$(8)="AUGUST   "
180 LET A$(9)="SEPTEMBER"
190 LET A$(10)="OCTOBER  "
200 LET A$(11)="NOVEMBER "
210 LET A$(12)="DECEMBER "
220 DIM A(42)
230 LET END=30
240 IF M=1 OR M=3 OR M=5 OR M=7 OR M=8 OR M=10 OR M=12 THEN LET END=31
250 IF M=2 THEN LET END =28
260 LET LEAP=0
270 IFY/4=INT (Y/4) AND Y/100<>INT (Y/100) THEN LET LEAP=1
280 IF Y/400=INT (Y/400) THEN LET LEAP=1
300 IF M=2 AND LEAP=1 THEN LET END=29
310 IF M=1 OR M=2 THEN LET M=M+12
320 IF M=13 OR M=14 THEN LET Y=Y-1
330 LET R=D+2*M+2+INT ((3*M+3)/5)+INT (Y/4)+Y-INT (Y/100)+INT (Y/400)
340 LET NUM =(R/7-INT (R/7))*7
350 LET NUM =INT (NUM+ .5)
360 LET START = NUM
370 IF NUM=0 THEN LET START=7
380 LET DAY =1
390 FOR P=START TO 42
400 LET A(P)=DAY
410 LET DAY=DAY+1
420 NEXT P
430 CLS
440 PRINT TAB 10;A$(MON);" ";YEAR
450 PRINT,,"    SUN MON TUE WED THU FRI SAT"
470 FOR R=0TO5
480 FOR C=1+R*7 TO 7+R*7
490 LET CC=C-R*7
500 IF A(C)=0 THEN PRINT TAB (4*CC);" ";
510 IF A(C)=0 THEN GOTO 550
520 IF A(C) > END THEN PRINT TAB (4*CC);" ";
530 IF A(C) > END THAN GOTO 550
540 PRINT TAB (4*CC);A(C);
550 NEXT C
560 NEXT R
570 IF P$="1" THEN COPY
580 IF P$="1" THEN GOTO 1
590 SLOW
600 PRINT AT 21,0;"PRESS ANY KEY FOR ANOTHER MONTH"
610 IF INKEY$="" THEN GOTO 610
620 GOTO 1

Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.