Enter the amount of the loan, the annual interest rate as a decimal (.11 for 11 percent) and the term in years. The program prints the monthly payment, then asks whether you want the schedule; it lists each payment’s number, interest, principal, remaining balance and total interest, pausing every 20 payments for NEWLINE. It needs 16K, and terms longer than about five years run past the screen.
As printed, line 115 jumps to line 125, which does not exist, so answering NO also shows the schedule. The August 1981 issue corrected it to GO TO 10, and in the same issue printed Loan Amortization Revisited, a 1K version that keeps only the monthly payment (lines 1-9 and 105-535 deleted, new lines 91-120 and 500-505). The download has the program as printed, the corrected version and the 1K Revisited version.
Published in Syntax July 1981 (Loan Amortization Schedule).
Source Code
1 REM "AMORTIZATION"
2 REM BY MEL ROUTT, JUNE 81
3 REM ADAPTED FROM PG 98
4 REM "BASIC PRIMER"
5 REM COPYRIGHT 1978
6 REM BY MITCH WAITE
7 REM AND MICHAEL PARDEE
8 REM HOWARD W SAMS CO INC
9 REM FIRST EDITION
10 CLS
15 PRINT " ENTER:"
20 PRINT "AMOUNT OF LOAN: $";
25 INPUT L
30 PRINT L
35 PRINT "ANNUAL O/O RATE: ";
40 INPUT R
45 PRINT R
50 PRINT "TERM IN YEARS: ";
55 INPUT Y
60 PRINT Y
65 LET I=R/12
70 LET M=Y*12
75 LET A=L*(I*(1+I)**M)/((1+I)**M-1)
80 LET X=A
85 GOSUB 500
90 LET A=X
95 PRINT "MONTHLY PAYMENT= $"; A
100 PRINT
105 PRINT "IF YOU WISH TO VIEW PAYMENT SCHEDULE, TYPE ""YES"". A ""NO"" WILL PERMIT A NEW ENTRY."
110 INPUT A$
115 IF A$="NO" THEN GOTO 125
120 CLS
130 PRINT " SCHEDULE:"
135 GOSUB 510
140 LET B=L
145 LET T=0
150 FOR J=1 TO M
155 LET I1=B*I
160 LET X=I1
165 GOSUB 500
170 LET I1=X
175 LET P=A-I1
180 IF J=M THEN LET P=B
200 LET B=B-P
205 LET X=B
210 GOSUB 500
215 LET B=X
220 LET T=T+I1
225 PAUSE 20
227 POKE 16437,255
230 PRINT J;TAB 3;I1;TAB 10;P;TAB 16;B;TAB 25;T
235 IF J=60 OR J=40 OR J=20 THEN GOSUB 520
240 NEXT J
245 PRINT
250 PRINT "WANT TO PROCESS ANOTHER LOAN? ""YES"" OR ""NO"""
255 INPUT A$
260 IF A$="YES" THEN GOTO 10
270 CLS
275 PRINT
280 PRINT "IT WAS A PLEASURE TO SERVE YOU."
285 STOP
500 LET X=(INT (100*(X+(.005))))/100
505 RETURN
510 PRINT "NO:";TAB 4;"INT:";TAB 10;"PRIN:";TAB 16;"P.BAL:";TAB 25;"T.INT:"
515 RETURN
520 INPUT X$
525 IF X$="" THEN CLS
530 GOSUB 510
535 RETURNNote: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.


