Wordbug

Developer(s): Bruce J. Schaffer
Date: 1984
Type: Program
Platform(s): TS 2068
Tags: Education

Wordbug picks a word, scrambles its letters and draws each one eight times larger at a random place on the screen, with a clue underneath. The player names the word, either by typing it into the answer box or, with a joystick in either port, by steering a “bug” to each letter in turn and pressing FIRE to have it eat the letter. A right answer gets a random message and one of several screen effects; a wrong one shows the correct spelling. The clues can be switched off for a harder game.

The title routine reads “© 1984 Bruce J. Schaffer”, and the REMs date the program 2/28/84. It is built on the same engine as Schaffer’s Spellbug, with a larger vocabulary of about 200 harder words, from “currency” to “fission”, in place of Spellbug’s 80 family words, a magnified WORDBUG title and 22 lines of instructions.

Program Analysis

Structure

  • Lines 1–23: start-up. Line 3 checks the ROM (PEEK 949) and NEWs the program on anything but a TS2068; lines 5–13 print the instructions and read the shapes of the 26 letters into U().
  • Lines 42–79: clue and joystick or keyboard choice.
  • Lines 80–190: joystick and keyboard answer routines.
  • Lines 500–2035: the magnify, gobble-up and title routines.
  • Lines 2200–2910: wrong-answer display.
  • Lines 3000–6600: main program, choosing a word, drawing it and checking the answer.
  • Lines 6625–9990: DATA for the letter shapes, user-defined graphics, messages and the word list.

Differences from Spellbug

Spellbug samples each letter’s pixels with POINT; Wordbug reads ready-made lists of pixel coordinates for each letter from DATA (lines 7–13), which makes the magnify routine at 500 simpler. Words are in DATA lines ten apart from line 8000, reached with RESTORE 7990+W*10, and their number is counted at start-up with an ON ERR trap around a READ loop. The 38 bytes of machine code for the screen effects are POKEd to 65000 from DATA at lines 3248–3250.

Notable Techniques

  • STICK reads the joystick in either port, and ON ERR catches the end of the word list; both are TS2068 statements.
  • The block character used for the magnified letters is chosen at random from UDGs and block graphics, with random INVERSE.

Potential Issues

  • The clue screen says to press DELETE to turn the clues off, but line 45 tests for "0"; DELETE returns CHR$ 12, so the 0 key on its own has to be pressed.
  • Line 2910 jumps to line 40, which does not exist, so execution carries on at line 42.

This copy came from RMG Enterprises’ public-domain disk of August 1991, a Larken disk. Only its save line used LKDOS, and it was changed to save to tape; the program was tested in ZEsarUX.

Related Content

Image Gallery

Source Code

    1 REM *** PROGRAM WORDBUG
    2 REM *** UPDATED 2/28/84 PM
    3 IF PEEK 949<>254 THEN NEW 
    4 CLEAR 64999: ON ERR GO TO 5: LET RAMT=64999
    5 BORDER 0: PAPER 1: INK 7: CLS : LET FIRST=0: RESTORE 6800: FOR N=1 TO 22: READ N$: PRINT N$: NEXT N
    6 DIM V(26): DIM U(26,21,2): DIM P(8): DIM W(8,21,2)
    7 RESTORE 6625
    8 FOR N=1 TO 26: READ V(N): NEXT N
   10 FOR N=1 TO 26
   12 FOR M=1 TO V(N): READ U(N,M,1),U(N,M,2): NEXT M
   13 NEXT N
   15 RESTORE 6920
   18 GO SUB 3000: ON ERR GO TO 18
   22 BORDER 0: PAUSE 0: PAPER 0: CLS : FOR R=1 TO (CODE ((INKEY$))-32): LET R1=RND: NEXT R
   23 GO SUB 2010
   34 ON ERR GO TO 9999: INK 0: BEEP .5,8: PAUSE 90: BEEP .5,12: BORDER 7: PAPER 5: CLS 
   42 BORDER 7: PAPER 7: PRINT AT 8,2;"To delete clues, press DELETE";AT 10,3;"Otherwise, press SPACE BAR"
   44 IF INKEY$=" " THEN LET CLUES=0: BEEP .2,16: GO TO 50
   45 IF INKEY$="0" THEN LET CLUES=1: BEEP .2,16: GO TO 50
   46 GO TO 44
   50 PAPER 6: CLS : PAUSE 30: PRINT AT 8,3;"Joystick? Press FIRE BUTTON"
   55 PRINT AT 10,4;"Keyboard? Press SPACE BAR"
   60 IF |(2,2)=1 THEN LET PORT=2: LET JOY=1: BEEP .2,20: GO TO 77
   62 IF |(2,1)=1 THEN LET PORT=1: LET JOY=1: BEEP .2,20: GO TO 77
   65 IF INKEY$=" " THEN LET JOY=0: BEEP .2,20: GO TO 77
   70 GO TO 60
   77 CLS : PAPER 7: GO TO 3000
   79 PAPER 7: GO TO 3000
   80 REM *** JOYSTICK ROUTINE
   85 IF D=1 THEN LET X=15: LET USUBX=15: LET Y=16: LET USUBY=16: LET U$=" ": LET W$="f": PRINT AT X,Y;W$
   90 IF |(1,PORT)=5 OR |(1,PORT)=1 OR |(1,PORT)=9 THEN LET X=X-2: BEEP .01,X
   95 IF |(1,PORT)=6 OR |(1,PORT)=2 OR |(1,PORT)=10 THEN LET X=X+2: BEEP .01,X
  100 IF |(1,PORT)=6 OR |(1,PORT)=5 OR |(1,PORT)=4 THEN LET Y=Y-2: BEEP .01,Y
  105 IF |(1,PORT)=8 OR |(1,PORT)=9 OR |(1,PORT)=10 THEN LET Y=Y+2: BEEP .01,Y
  110 IF Y>31 THEN LET Y=31
  115 IF Y<0 THEN LET Y=0
  120 IF X>15 THEN LET X=15
  125 IF X<0 THEN LET X=0
  130 IF SCREEN$ (X,Y)<>" " THEN IF SCREEN$ (X,Y)<>W$ THEN GO TO 142
  140 IF X<>USUBX OR Y<>USUBY THEN PRINT AT USUBX,USUBY;" ": LET USUBX=X: LET USUBY=Y: LET U$=SCREEN$ (X,Y): PRINT AT X,Y;W$
  142 IF |(2,PORT)=1 THEN BEEP .2,10+INT (RND*10): GO TO 5120
  145 GO TO 90
  150 REM *** ANSWER ROUTINE
  152 LET X=20: LET Y=12: LET Y$="": INK INT (RND*6)+1: PAPER 9
  155 PRINT AT X,Y;"f"
  160 PAUSE 0: LET Z$=INKEY$
  165 IF Z$=CHR$ 13 AND Y$<>"" THEN GO TO 190
  170 IF Z$=CHR$ 12 AND Y$<>"" THEN PRINT AT X,Y; INK 0; PAPER 7;CHR$ 32: LET Y=Y-1: LET Y$=Y$( TO LEN Y$-1): BEEP .1,0: GO TO 155
  175 IF Z$<CHR$ 32 THEN GO TO 160
  177 IF Y=X THEN GO TO 155
  180 LET Y$=Y$+Z$
  182 IF Z$<>" " THEN BEEP .02,ABS (CODE Z$-90)
  185 PRINT INVERSE 1;AT X,Y;Z$: LET Y=Y+1: GO TO 155
  190 INK 0: PAPER 7: PRINT AT X,Y;" ": RETURN 
  195 REM *** MAGNIFY ROUTINE
  500 LET COL=3+J: LET ROW=2+G
  600 IF TITLE=1 THEN GO TO 875
  850 BORDER (J+G*2)/8+2
  875 INK (J+G*2)/8+1
  890 BEEP .02,(J+G*2)/10*INT (RND*8)
  900 FOR C=1 TO V(N)
 1300 LET CCOOR=COL+U(N,C,2)
 1400 LET RCOOR=ROW+U(N,C,1)
 1450 PRINT INVERSE INV;AT RCOOR,CCOOR;X$
 1460 LET W(H,C,1)=RCOOR
 1470 LET W(H,C,2)=CCOOR
 1600 NEXT C: LET P(H)=V(N): RETURN 
 1790 REM *** 'GOBBLE-UP' ROUTINE
 1825 IF JOY=1 THEN PRINT AT USUBX,USUBY;" "
 1827 FOR C=1 TO P(H)
 1830 LET WX=W(H,C,1): LET WY=W(H,C,2)
 1840 IF JOY=1 THEN PRINT AT W(H,C,1),W(H,C,2);W$: BEEP .01,2*C-20
 1850 PRINT AT W(H,C,1),W(H,C,2);X$
 1900 NEXT C
 1910 BEEP .02,INT (RND*10)-4*F
 1920 IF JOY=1 THEN LET USUBX=WX: LET USUBY=WY: LET X=USUBX: LET Y=USUBY: PRINT AT X,Y;W$
 1950 IF JOY=0 THEN BEEP .2,INT (RND*10)-3*F
 2000 RETURN 
 2010 ON ERR GO TO 2010: LET H=0: LET X$="::": LET JOY=0: LET S$="WORDBUG ": LET INV=0
 2012 BRIGHT 1: FLASH 1: BEEP .2,5: LET TITLE=1: LET FLASH=0
 2015 FOR G=0 TO 8 STEP 8
 2020 FOR J=0 TO 24 STEP 8
 2025 LET H=H+1: IF S$(H)<>" " THEN LET N=CODE S$(H)-64: GO SUB 500
 2030 NEXT J: NEXT G: LET TITLE=0
 2031 IF FLASH=0 THEN LET FLASH=1: LET H=0: FLASH 0: GO TO 2015
 2032 FOR N=1 TO 10: BEEP .15,INT (RND*20): NEXT N: FLASH 0: BRIGHT 0
 2035 INK 7: PRINT AT 21,8;"* 1984 Bruce J. Schaffer": RETURN 
 2195 REM *** 'ERROR' ROUTINE
 2200 BORDER 7: CLS : LET P$=M$(1,INT (RND*5)+1)
 2250 FOR P=1 TO 5
 2300 PRINT AT P*3,4*INT (RND*7);P$: BEEP .2,D+5-3*P: NEXT P
 2450 PRINT AT 20,0;"THE CORRECT SPELLING IS ";A$(1)
 2500 BEEP 1,0
 2550 CLS 
 2600 FOR P=0 TO 21
 2650 PRINT AT P,2;A$(1);AT P,12;A$(1);AT P,22;A$(1): NEXT P
 2860 BORDER 7: FOR P=0 TO 21
 2870 PRINT AT P,0;"                                ": BEEP .08,-10-P: NEXT P
 2880 CLS 
 2895 REM *** READ NEXT WORD
 2900 NEXT F
 2910 GO TO 40
 2995 REM *** MAIN PROGRAM
 3000 IF FIRST>0 THEN GO TO 3300
 3010 LET FIRST=1
 3050 DIM A$(2,8): DIM K(8,2): DIM Z(8): DIM M$(3,10,7): DIM G$(10,1): DIM C$(20,1)
 3163 REM *** READ USER-DEF. KEYS
 3165 FOR J=1 TO 9
 3170 READ G$(J): NEXT J
 3178 REM *** READ 'ERROR' AND
 3179 REM *** 'CORRECT' MESSAGES
 3180 FOR S=1 TO 3
 3185 FOR T=1 TO 5
 3190 READ M$(S,T): NEXT T: NEXT S
 3206 REM *** READ BINARY DATA &
 3208 REM *** CREATE SPEC. CHARS.
 3210 FOR J=1 TO 9
 3220 FOR I=0 TO 7
 3230 READ IBIN
 3240 POKE USR G$(J)+I,IBIN
 3242 NEXT I: NEXT J
 3248 FOR R=1 TO 38
 3250 READ COD: POKE RAMT+R,COD: NEXT R
 3258 REM *** ASSIGN SPEC. CHARS.
 3260 LET C$(13)="i": LET C$(1)="a": LET C$(2)="b": LET C$(3)="c": LET C$(4)="d": LET C$(5)="e": LET C$(6)="f": LET C$(7)="g": LET C$(10)="''": LET C$(11)=" :": LET C$(12)="'.": LET C$(8)="':": LET C$(9)="h"
 3265 ON ERR GO TO 3280
 3270 LET WORDS=0
 3275 READ U$,V$: LET WORDS=WORDS+1: GO TO 3275
 3280 ON ERR RESET 
 3290 RETURN 
 3300 CLS 
 3310 FOR F=1 TO 5
 3311 LET W=INT (RND*WORDS)+1+INT (RND*11)-5
 3313 IF W<1 THEN LET W=ABS (W)+1
 3314 IF W>WORDS THEN LET W=WORDS-(W-WORDS)
 3315 LET CHAR=.5*(INT (RND*22)+2)
 3318 IF CHAR>9.5 THEN LET X$=C$(10+INT (RND*4))
 3320 IF CHAR<=9.5 THEN LET X$=C$(INT (CHAR))
 3323 LET S$=X$: LET INV=INT (RND*2)
 3324 IF X$=C$(9) THEN LET INV=0
 3325 REM *** RANDOMLY SELECTS
 3326 REM *** WHETHER TO 'GOBBLE'
 3330 LET GOBBLE=INT (RND*1.2): LET GOB=INT (RND*5)+1
 3340 IF JOY=1 THEN LET GOBBLE=1
 3345 REM *** SET READ POINTER TO
 3347 REM *** RANDOM WORD (FROM
 3348 REM *** LINE 8000, BY 20)
 3350 RESTORE 7990+W*10
 3400 READ Q$,B$: LET A$(1)=Q$
 3410 IF CODE Q$(1)>90 THEN FOR R=1 TO LEN Q$: LET A$(1,R)=CHR$ (CODE Q$(R)-32): NEXT R
 3450 IF CLUES=1 THEN LET B$=" "
 3500 FOR Z=1 TO 8: LET Z(Z)=Z: NEXT Z
 3800 LET K(1,1)=INT (RND*8)+1
 3850 LET K(1,2)=CODE A$(1,K(1,1))
 3900 LET Z(K(1,1))=0
 3995 REM *** Z() RECORDS WHETHER
 3996 REM *** RANDOM PRINT LOC.
 3997 REM *** IS ALREADY USED;
 3998 REM *** Z(X)=0 IF OCCUPIED
 4000 FOR H=2 TO 7
 4100 LET K(H,1)=INT (RND*8)+1
 4150 LET K(H,2)=CODE A$(1,K(H,1))
 4200 IF Z(K(H,1))=0 THEN GO TO 4100
 4250 LET Z(K(H,1))=0: NEXT H
 4300 FOR Z=1 TO 8
 4400 IF Z(Z)=0 THEN NEXT Z
 4500 LET K(8,1)=Z
 4504 LET K(8,2)=CODE A$(1,K(8,1))
 4520 LET H=0
 4530 PAPER 7: BORDER 7: CLS 
 4658 REM *** PERFORM MAGNIFY
 4659 REM *** ROUTINE 8 TIMES
 4660 FOR G=0 TO 8 STEP 8
 4680 FOR J=0 TO 24 STEP 8
 4690 LET H=H+1
 4695 LET N=CODE A$(1,K(H,1))-64
 4697 BEEP .02,INT (RND*20)-3*F
 4700 IF A$(1,K(H,1))<>" " THEN GO SUB 500
 4710 BEEP .02,INT (RND*20)-3*F
 4720 NEXT J: NEXT G: INK 0
 4798 REM *** PRINT CLUE
 4799 IF LEN B$>32 THEN LET B$=B$( TO 32)
 4800 PRINT AT 18,INT ((32-LEN B$)/2);B$
 4818 REM *** DRAW ANSWER BOX
 4820 PLOT 88,20: DRAW 80,0: DRAW 0,-16: DRAW -80,0: DRAW 0,16
 4900 LET X$=" "
 5090 IF JOY=0 THEN GO SUB 152: LET A$(2)=Y$
 5097 REM *** CHECK ANSWER, ONE
 5098 REM *** LETTER AT A TIME
 5100 FOR D=1 TO 8
 5102 IF A$(1,D)=" " THEN GO TO 6000
 5110 IF JOY=1 THEN GO TO 85
 5120 IF JOY=1 THEN LET LETTER=INT (Y/8)+4*INT (X/8)+1: GO TO 5200
 5150 IF A$(2,D)<>A$(1,D) AND CODE A$(2,D)<>CODE A$(1,D)+32 THEN GO TO 2200
 5195 REM *** DETERMINE RANDOM
 5197 REM *** LOCATION OF PRINTED
 5198 REM *** LETTER FOR 'GOBBLE'
 5200 FOR E=1 TO 8
 5300 IF K(E,1)<>D THEN NEXT E
 5400 LET G=INT (E/4.1)*8
 5500 LET J=(E-1)*8
 5600 IF E>4 THEN LET J=(E-5)*8
 5650 LET H=E
 5670 IF JOY=1 THEN IF CODE A$(1,K(LETTER,1))<>K(H,2) THEN GO TO 2200
 5680 IF JOY=1 THEN IF (LETTER<>H AND CODE A$(1,K(LETTER,1))=K(H,2)) THEN LET H=LETTER
 5697 REM *** PERFORM MAGNIFY
 5740 IF GOBBLE<>0 THEN BEEP .02,INT (RND*10)-3*F: GO SUB 1825
 5750 INK 0
 5800 PRINT AT 20,11+D;A$(2,D)
 5810 IF JOY=1 THEN PRINT AT 20,11+D;A$(1,D)
 5850 IF GOBBLE=0 THEN BEEP .2,D*2
 5900 NEXT D
 6000 IF JOY=0 THEN IF LEN Y$<>LEN Q$ THEN GO TO 2200
 6005 REM *** SCREEN 'VANISH'
 6006 IF GOBBLE=0 THEN IF GOB=1 OR GOB=2 THEN LET INQ=INT (RND*7)+1: BORDER INQ: FOR N=1 TO 11: PRINT #1;"                                 ": NEXT N: PRINT INK INQ;"::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::": PAPER INQ: CLS : INK 8: GO TO 6027
 6008 IF GOBBLE=0 THEN IF GOB=3 THEN PRINT AT 0,0;"                                ": FOR N=1 TO 21: PRINT "                                ": NEXT N: INK 8: GO TO 6027
 6010 IF GOBBLE=0 THEN IF GOB=4 OR GOB=5 THEN FOR R=1 TO 8: PAUSE 5: LET A=USR 65020: NEXT R: FOR R=1 TO 8: PAUSE 5: LET A=USR 65000: NEXT R: BEEP .2,D*2: INK 8: GO TO 6027
 6020 REM *** 'CORRECT' ROUTINE
 6050 LET K$=S$: FOR M=1 TO 10: LET K$=K$+S$: NEXT M: FOR M=1 TO 6: LET K$=K$+K$: NEXT M: CLS 
 6057 FOR O=1 TO INT (RND*2)+1
 6058 LET P$=M$(2,INT (RND*5)+1)
 6059 LET J$=M$(3,INT (RND*5)+1)
 6060 LET L1=INT (RND*20): LET L2=INT (RND*24)
 6075 INK 8: LET BORDER=INT (RND*6+1): PAPER 0: BORDER 0: CLS 
 6080 LET BACK=INT ((RND*1.4)+1): IF BACK<2 THEN PRINT INK BORDER; INVERSE INV;K$
 6195 REM *** PRINT RANDOM
 6197 REM *** MESSAGES AT RANDOM
 6198 REM *** LOCATIONS
 6200 FLASH 1: PRINT INK BORDER;AT L1,L2;J$;AT L1+1,L2;"       ";AT L1+2,L2;P$
 6500 FOR D=1 TO INT (RND*7)+6: BEEP .15,INT (RND*20): NEXT D
 6600 FLASH 0: NEXT O: CLS 
 6610 REM *** READ NEXT WORD
 6620 NEXT F: GO TO 40
 6622 REM *** 'ON' BITS / LETTER
 6625 DATA 18,21,14,16,20,15,17,16,14,11,13,11,16,16,16,16,18,18,16,12,14,12,14,12,9,16
 6628 REM *** 'ON' BIT POSITIONS
 6630 DATA 0,-2,1,-2,2,-2,3,-2,4,-2,-1,-1,2,-1,-1,0,2,0,-1,1,2,1,-1,2,2,2,0,3,1,3,2,3,3,3,4,3
 6635 DATA -1,-2,0,-2,1,-2,2,-2,3,-2,4,-2,-1,-1,1,-1,4,-1,-1,0,1,0,4,0,-1,1,1,1,4,1,-1,2,1,2,4,2,0,3,2,3,3,3
 6640 DATA 0,-2,1,-2,2,-2,3,-2,-1,-1,4,-1,-1,0,4,0,-1,1,4,1,-1,2,4,2,0,3,3,3
 6645 DATA -1,-2,0,-2,1,-2,2,-2,3,-2,4,-2,-1,-1,4,-1,-1,0,4,0,-1,1,4,1,0,2,3,2,1,3,2,3
 6650 DATA -1,-2,0,-2,1,-2,2,-2,3,-2,4,-2,-1,-1,1,-1,4,-1,-1,0,1,0,4,0,-1,1,1,1,4,1,-1,2,1,2,4,2,-1,3,4,3
 6655 DATA -1,-2,0,-2,1,-2,2,-2,3,-2,4,-2,-1,-1,1,-1,-1,0,1,0,-1,1,1,1,-1,2,1,2,-1,3
 6660 DATA 0,-2,1,-2,2,-2,3,-2,-1,-1,4,-1,-1,0,4,0,-1,1,2,1,4,1,-1,2,2,2,4,2,0,3,2,3,3,3
 6665 DATA -1,-2,0,-2,1,-2,2,-2,3,-2,4,-2,1,-1,1,0,1,1,1,2,-1,3,0,3,1,3,2,3,3,3,4,3
 6670 DATA -1,-1,4,-1,-1,0,4,0,-1,1,0,1,1,1,2,1,3,1,4,1,-1,2,4,2,-1,3,4,3
 6675 DATA 2,-2,3,-2,4,-1,4,0,4,1,4,2,-1,3,0,3,1,3,2,3,3,3
 6680 DATA -1,-2,0,-2,1,-2,2,-2,3,-2,4,-2,1,-1,1,0,0,1,2,1,-1,2,3,2,4,3
 6685 DATA -1,-2,0,-2,1,-2,2,-2,3,-2,4,-2,4,-1,4,0,4,1,4,2,4,3
 6690 DATA -1,-2,0,-2,1,-2,2,-2,3,-2,4,-2,0,-1,1,0,1,1,0,2,-1,3,0,3,1,3,2,3,3,3,4,3
 6700 DATA -1,-2,0,-2,1,-2,2,-2,3,-2,4,-2,0,-1,1,0,2,1,3,2,-1,3,0,3,1,3,2,3,3,3,4,3
 6705 DATA 0,-2,1,-2,2,-2,3,-2,-1,-1,4,-1,-1,0,4,0,-1,1,4,1,-1,2,4,2,0,3,1,3,2,3,3,3
 6710 DATA -1,-2,0,-2,1,-2,2,-2,3,-2,4,-2,-1,-1,2,-1,-1,0,2,0,-1,1,2,1,-1,2,2,2,0,3,1,3
 6715 DATA 0,-2,1,-2,2,-2,3,-2,-1,-1,4,-1,-1,0,2,0,4,0,-1,1,3,1,4,1,-1,2,4,2,0,3,1,3,2,3,3,3
 6720 DATA -1,-2,0,-2,1,-2,2,-2,3,-2,4,-2,-1,-1,2,-1,-1,0,2,0,-1,1,2,1,-1,2,2,2,3,2,0,3,1,3,4,3
 6725 DATA 0,-2,3,-2,-1,-1,1,-1,4,-1,-1,0,1,0,4,0,-1,1,1,1,4,1,-1,2,1,2,4,2,2,3,3,3
 6730 DATA -1,-3,-1,-2,-1,-1,-1,0,0,0,1,0,2,0,3,0,4,0,-1,1,-1,2,-1,3
 6735 DATA -1,-2,0,-2,1,-2,2,-2,3,-2,4,-1,4,0,4,1,4,2,-1,3,0,3,1,3,2,3,3,3
 6740 DATA -1,-2,0,-2,1,-2,2,-2,3,-1,4,0,4,1,3,2,-1,3,0,3,1,3,2,3
 6745 DATA -1,-2,0,-2,1,-2,2,-2,3,-2,4,-1,3,0,3,1,4,2,-1,3,0,3,1,3,2,3,3,3
 6750 DATA -1,-2,4,-2,0,-1,3,-1,1,0,2,0,1,1,2,1,0,2,3,2,-1,3,4,3
 6755 DATA -1,-3,0,-2,1,-1,2,0,3,0,4,0,1,1,0,2,-1,3
 6760 DATA -1,-2,4,-2,-1,-1,3,-1,4,-1,-1,0,2,0,4,0,-1,1,1,1,4,1,-1,2,0,2,4,2,-1,3,4,3
 6800 DATA "1) To use a joystick, (in EITHER"
 6805 DATA "port), press the FIRE BUTTON."
 6810 DATA "After the scrambled letters, a"
 6815 DATA "cursor 'bug' will appear below"
 6820 DATA "center-screen. Use the joystick"
 6825 DATA "to move the 'bug' to the first"
 6830 DATA "letter of the word (anywhere"
 6835 DATA "within the 8x8-character matrix"
 6840 DATA "'owned' by the letter.) Press"
 6845 DATA "the FIRE BUTTON to ENTER the"
 6850 DATA "letter. If your choice is right,"
 6855 DATA "the 'bug' will devour the letter"
 6860 DATA "and wait for you to move him to"
 6865 DATA "the next one."
 6870 DATA "2) To play by keyboard, press"
 6875 DATA "the SPACE BAR. After letters, a"
 6880 DATA "cursor 'bug' will appear in the"
 6885 DATA "answer box. Type in the word"
 6890 DATA "(upper OR lower case) and press"
 6895 DATA "the ENTER key."
 6900 DATA "Now, if the border is black,"
 6905 DATA "press any key to continue."
 6918 REM *** USER-DEFINED KEYS
 6920 DATA "A","B","C","D","E"
 6925 DATA "F","G","H","I"
 6938 REM *** MESSAGES
 6940 DATA "NO! NO!"
 6945 DATA " NOPE!!"
 6950 DATA "WRONG!!"
 6955 DATA " WHAT?!"
 6960 DATA "NO WAY!"
 6970 DATA " RIGHT!"
 6975 DATA "CORRECT"
 6980 DATA " OKAY! "
 6985 DATA " GOOD! "
 6990 DATA "NOT BAD"
 6991 DATA " THAT'S"
 6992 DATA " YOU'RE"
 6993 DATA " YEAH! "
 6994 DATA " RIGHT!"," "
 6995 REM *** DECIMAL DATA FOR
 6996 REM *** USER-DEFINED CHARS.
 7000 DATA 255,129,129,129,129,129,129,255
 7200 DATA 0,126,126,102,102,126,126,0
 7350 DATA 231,195,165,24,24,165,195,231
 7400 DATA 102,102,102,102,102,102,102,102
 7600 DATA 0,255,255,0,0,255,255,0
 7800 DATA 56,112,225,195,135,14,28,56
 7945 DATA 24,102,102,129,129,102,102,24
 7976 DATA 255,255,255,231,231,255,255,255
 7977 DATA 204,204,51,51,204,204,51,51
 7978 REM *** MACHINE CODE FOR
 7979 REM *** 'VANISH' ROUTINE
 7980 DATA 33,255,87,14,32,167,203,38,43,13,32,250,62,63,188,32,242,201,0,0
 7985 DATA 33,0,64,14,32,167,203,46,35,13,32,250,62,88,188,32,242,201
 7995 REM *** WORDS AND CLUES
 7997 REM *** (START AT LINE 8000
 7998 REM *** & INCREMENT BY 20)
 8000 DATA "currency","MONEY PRESENTLY IN USE IS CALLED"
 8010 DATA "acids","HYDROCHLORIC AND SULFURIC"
 8020 DATA "alkali","OPPOSITE OF ACID; SAME AS BASE"
 8030 DATA "bevel","GEAR USED IN A DIFFERENTIAL"
 8040 DATA "STRATA","LAYERS"
 8050 DATA "mortgage","A HOME LOAN IS CALLED A --------"
 8060 DATA "OBLIQUE","Indirect; an angle <> 90 degrees"
 8070 DATA "voltage","ELECTROMOTIVE FORCE; e.g. 120 V"
 8080 DATA "MUSEUM","ART IS DISPLAYED IN A ------"
 8090 DATA "envelope","MAIL A LETTER IN ONE OF THESE"
 8100 DATA "aluminum","A LIGHTWEIGHT METAL"
 8110 DATA "olympics","FAMOUS INTERNATIONAL GAMES"
 8120 DATA "CEREAL","OATMEAL OR RAISIN BRAN"
 8130 DATA "nebula","A DUST CLOUD, LIGHT YEARS AWAY"
 8140 DATA "ANTONYMS","WORDS HAVING OPPOSITE MEANINGS"
 8150 DATA "ampere","UNIT OF ELECTRICAL CURRENT"
 8160 DATA "SYNONYMS","WORDS HAVING SIMILAR MEANINGS"
 8170 DATA "vehicle","A CAR OR TRUCK, FOR EXAMPLE"
 8180 DATA "elements","Items in the PERIODIC TABLE"
 8190 DATA "pallets","STACK CARGO ON ONE OF THESE"
 8200 DATA "FUNCTION","WHAT YOU DEFINE WITH 'DEF FN'"
 8210 DATA "palette","CONTAINS AN ARTIST'S COLORS"
 8220 DATA "MYSTERY","NANCY DREW SOLVED A -------"
 8230 DATA "palate","TASTES GOOD, SO IT PLEASES THE"
 8240 DATA "ONYX","A TYPE OF DECORATIVE QUARTZ"
 8250 DATA "numeric","INFO STORED IN A SIMPLE VARIABLE"
 8260 DATA "YOGURT","WE LOVE DANNON* ------"
 8270 DATA "boundary","A BORDER, AS BETWEEN COUNTRIES"
 8280 DATA "MEMORY","THIS PROGRAM USES ABOUT 38K OF"
 8290 DATA "liquid","MATTER THAT ISN'T A SOLID OR GAS"
 8300 DATA "SCULPTOR","HE CREATES WITH CLAY OR METAL"
 8310 DATA "AZTECS","ANCIENT PEOPLE OF MEXICO"
 8320 DATA "THOUGHT","SOMETHING THAT YOU THINK"
 8330 DATA "INCA","ANCIENT PEOPLE OF PERU"
 8340 DATA "CERAMIC","SOMETHING MADE OF CLAY IS"
 8350 DATA "MAYA","ANCIENT PEOPLE OF YUCATAN"
 8360 DATA "MODEM","A TELECOMMUNICATIONS INTERFACE"
 8370 DATA "library","A PLACE TO READ TONS OF BOOKS"
 8380 DATA "STOMACH","WHERE YOUR FOOD GOES"
 8390 DATA "operands","AN OPERATION NEEDS AN OPERATOR &"
 8400 DATA "CABBAGE","------- PATCH KIDS*"
 8410 DATA "array","In BASIC, a matrix is called an"
 8420 DATA "INTAGLIO","PRINTING PROCESS (IMAGE CUT IN)"
 8430 DATA "argument","In BASIC, a FN requires this"
 8440 DATA "RELIEF","PRINTING PROCESS (IMAGE RAISED)"
 8450 DATA "silicon","USED FOR MAKING CIRCUIT CHIPS"
 8460 DATA "gazebo","Pavilion or summerhouse"
 8470 DATA "sixteen","BASE OF THE HEXADECIMAL SYSTEM"
 8480 DATA "codex","Accordian-folded document"
 8490 DATA "eight","BASE OF THE OCTAL NUMBER SYSTEM"
 8500 DATA "COLUMNS","A MATRIX CONTAINS ROWS AND"
 8510 DATA "juvenile","A CHILD; '-------- DELINQUENT'"
 8520 DATA "theater","WHERE YOU SEE A PLAY OR MOVIE"
 8530 DATA "extinct","PRESENT CONDITION OF DINOSAURS"
 8540 DATA "QUOTIENT","ANSWER IN A DIVISION PROBLEM"
 8550 DATA "malady","AN ILLNESS OR OTHER PROBLEM"
 8560 DATA "ANSWER","A QUESTION ALWAYS HAS AN ------"
 8570 DATA "melody","A MUSICAL TUNE IS A ------"
 8580 DATA "ANTIQUE","EXPENSIVE NAME FOR OLD JUNK"
 8590 DATA "turbine","USES STEAM TO CREATE POWER"
 8600 DATA "HEIRLOOM","HANDED DOWN FOR GENERATIONS"
 8610 DATA "auger","DRILL USED FOR TELEPHONE POLES"
 8620 DATA "APEX","THE HIGHEST POINT; ZENITH"
 8630 DATA "prophecy","A PREDICTION OF THE FUTURE"
 8640 DATA "SYMBOL","PICTURE, REPRESENTING SOMETHING"
 8650 DATA "prophesy","TO PREDICT THE FUTURE"
 8660 DATA "ISLAND","BODY OF LAND SURROUNDED BY WATER"
 8670 DATA "asterisk","* Multiplication symbol in BASIC"
 8680 DATA "SEPARATE","IF THEY'RE NOT TOGETHER, THEY'RE"
 8690 DATA "truncate","TO CUT OFF"
 8700 DATA "MACABRE","GRIM, GRUESOME OR GHASTLY"
 8710 DATA "CELSIUS","Temperature scale, noted as C"
 8720 DATA "CALENDAR","LOOK AT THE ------ FOR THE DATE"
 8730 DATA "KELVIN","'ABSOLUTE' TEMPERATURE SCALE"
 8740 DATA "MACHINE","A MECHANICAL DEVICE IS A -------"
 8750 DATA "exhaust","CARS POLLUTE THE AIR WITH THIS"
 8760 DATA "ACCESS","RANDOM ------ MEMORY"
 8770 DATA "kiosk","Open pavilion, common in Turkey"
 8780 DATA "GRAPHICS","PICTURES (AS IN 'G' MODE)"
 8790 DATA "icicle","DRIPPING WATER FREEZES INTO THIS"
 8800 DATA "COMPILER","TRANSLATES INTO MACHINE LANGUAGE"
 8810 DATA "stellar","RELATING TO STARS IN SPACE"
 8820 DATA "SERIAL","TRANSMISSION, 1-BIT-WIDE STRING"
 8830 DATA "foreign","RELATING TO OTHER COUNTRIES"
 8840 DATA "NUCLEAR","RELATING TO THE CORE OF AN ATOM"
 8850 DATA "imagine","TO THINK OR FANTASIZE SOMETHING"
 8860 DATA "MERGE","TO COMBINE THINGS INTO ONE"
 8870 DATA "language","WORDS PEOPLE USE TO COMMUNICATE"
 8880 DATA "HEXAGON","A SIX-SIDED FIGURE IS A -------"
 8890 DATA "bytes","THESE STORE ONE CHARACTER EACH"
 8900 DATA "vessel","A CONTAINER OR A BOAT"
 8910 DATA "ecstasy","Great joy; 'AGONY AND -------'"
 8920 DATA "FEBRUARY","THE MONTH AFTER JANUARY IS"
 8930 DATA "scimitar","Curved sword, used by Turks"
 8940 DATA "SCIENCES","CHEMISTRY, ASTRONOMY, ETC."
 8950 DATA "SWAHILI","ONE AFRICAN LANGUAGE"
 8960 DATA "VERTIGO","DIZZINESS, OR A HITCHCOCK MOVIE"
 8970 DATA "HINDU","OF BRAHMA, VISHNU AND SHIVA"
 8980 DATA "VARIABLE","A VALUE THAT CAN CHANGE "
 8990 DATA "decade","PERIOD OF TEN YEARS"
 9000 DATA "OBELISK","Shape of the Washington Monument"
 9010 DATA "baton","USED BY CONDUCTOR OR MAJORETTE"
 9020 DATA "BINARY","NUMBER SYSTEM USING ONLY 1 AND 0"
 9030 DATA "abalone","SHELL; ALSO MOTHER-OF-PEARL"
 9040 DATA "DECIMAL","NUMBER SYSTEM USING 10 DIGITS"
 9050 DATA "sandwich","FOOD BETWEEN 2 SLABS OF BREAD"
 9060 DATA "RANDOM","------ ACCESS MEMORY (RAM)"
 9070 DATA "valid","USABLE; STILL IN EFFECT"
 9080 DATA "SYSTEM","THINGS ACTING TOGETHER ARE A"
 9090 DATA "void","NOT USABLE; NO LONGER IN EFFECT"
 9100 DATA "AMATEUR","HE DOES SOMETHING AS A HOBBY"
 9110 DATA "DELETE","TO GET RID OF OR REMOVE"
 9120 DATA "SYNTAX","THE STRUCTURE OF A LANGUAGE"
 9130 DATA "DIGITIZE","CONVERT TO NUMERIC INFORMATION"
 9140 DATA "MATRIX","MADE OF ROWS & COLUMNS; AN ARRAY"
 9150 DATA "PARALLEL","TRANSMISSION, 8 BITS AT A TIME"
 9160 DATA "CIRCUITS","COMPUTERS USE INTEGRATED -------"
 9170 DATA "RECEIVE","I LIKE TO ------- PRESENTS."
 9180 DATA "ZENITH","THE HIGHEST POINT; APEX"
 9190 DATA "PRISM","IT BREAKS LIGHT INTO A SPECTRUM"
 9200 DATA "BICYCLE","I LIKE TO RIDE MY -------"
 9210 DATA "SPECTRUM","A PRISM BREAKS LIGHT INTO A ----"
 9220 DATA "ELECTRIC","YOU MUST PLUG IT IN IF IT'S"
 9230 DATA "INDEX","LOOK HERE TO LOCATE SOMETHING"
 9240 DATA "CURSOR","SHOWS YOUR POSITION ON TV SCREEN"
 9250 DATA "AERIAL","RELATING TO THE AIR OR FLYING"
 9260 DATA "MAGNETIC","TAPES & DISKS ARE ------ STORAGE"
 9270 DATA "VERIFY","MAKE SURE THAT SOMETHING IS TRUE"
 9280 DATA "NUTRIENT","SOMETHING NUTRITIOUS CONTAINS A"
 9290 DATA "PIXEL","WORD, MEANING 'PICTURE ELEMENT'"
 9300 DATA "OXYGEN","THE AIR WE BREATHE CONTAINS ----"
 9310 DATA "ERSATZ","A SUBSTITUTE, OR 'WOULD-BE'"
 9320 DATA "ALPHABET","A TO Z"
 9330 DATA "QUICHE","REAL MEN DON'T EAT THIS"
 9340 DATA "UNIVERSE","THE MILKY WAY GALAXY IS OUR"
 9350 DATA "SYRINGE","A HYPODERMIC NEEDLE IS ONE"
 9360 DATA "GALAXY","STAR GROUP, LIKE THE MILKY WAY"
 9370 DATA "INVERSE","THE 'INSIDE-OUT' OF SOMETHING"
 9380 DATA "OBVERSE","THE 'FRONT' OF A COIN OR BILL"
 9390 DATA "REVERSE","THE 'BACK' OF A COIN OR BILL"
 9400 DATA "QUEUE","COMPUTER'S I/O 'WAITING LINE'"
 9410 DATA "CATEGORY","ANOTHER WORD FOR CLASSIFICATION"
 9420 DATA "ELIGIBLE","TO BE QUALIFIED FOR SOMETHING"
 9430 DATA "KITCHEN","THE ROOM WHERE ONE COOKS"
 9440 DATA "AXIOM","AN ACCEPTED PRINCIPLE OR RULE"
 9450 DATA "PRIMARY","REFERRING TO A MAIN FUNCTION"
 9460 DATA "HOURS","UNITS OF TIME; 60 MINUTES EACH"
 9470 DATA "CEILING","PART OF A ROOM ABOVE YOUR HEAD"
 9480 DATA "SPECIFIC","EXPLICIT; OPPOSITE OF 'GENERAL'"
 9490 DATA "ENERGY","PRODUCED FROM COAL, GAS & SUN"
 9500 DATA "ADROIT","HIGHLY SKILLED OR ADEPT"
 9510 DATA "MEDIA","MAGNETIC TAPE IS STORAGE -----"
 9520 DATA "OASIS","A WATERING HOLE IN THE DESERT"
 9530 DATA "TRIVET","PLACE A HOT DISH ON THIS"
 9540 DATA "TRIPOD","A THREE-LEGGED STAND"
 9550 DATA "TRIVIA","INSIGNIFICANT BIT OF INFORMATION"
 9560 DATA "CARAFE","GLASS PITCHER FOR WINE OR COFFEE"
 9570 DATA "MYTHS","Stories about Zeus or Ulysses"
 9580 DATA "DESERTS","Gobi, Mojave and Sahara"
 9590 DATA "dessert","SOMETHING SWEET AFTER A MEAL"
 9600 DATA "DUNES","HUGE DRIFTS OF SAND"
 9610 DATA "CAMEO","BROOCH, FREQUENTLY OF AGATE"
 9620 DATA "AFGHAN","HANDMADE COVERLET OR FUNNY DOG"
 9630 DATA "VERTEBRA","ANY BONE OF THE SPINAL COLUMN"
 9640 DATA "VIDEO","SOUND IS 'AUDIO' - SIGHT IS '?'"
 9650 DATA "FUSION","CONVERSION OF HYDROGEN TO HELIUM"
 9660 DATA "FISSION","NUCLEAR 'CHAIN REACTION'"
 9670 DATA "GRAFFITI","FORMERLY VANDALISM, NOW ART!"
 9680 DATA "ARTERY","CARRIES FRESH BLOOD TO THE BODY"
 9690 DATA "THERAPY","TREATMENT OF A DISORDER"
 9700 DATA "OBSERVE","TO WATCH CLOSELY"
 9710 DATA "ACRYLIC","Synthetic material, like LUCITE"
 9720 DATA "ACQUIT","TO CLEAR SOMEONE OF A CHARGE"
 9730 DATA "PARALLEL","LINES THAT CANNOT MEET; LATITUDE"
 9740 DATA "ANNEAL","TO LET COOL SLOWLY AFTER HEATING"
 9750 DATA "ACRONYM","WORD, FROM FIRST LETTERS;'LASER'"
 9760 DATA "CHARISMA","A QUALITY THAT INSPIRES DEVOTION"
 9770 DATA "OPTICS","PHYSICS OF LIGHT AND VISION"
 9780 DATA "GYRATE","TO ROTATE ON AN AXIS"
 9790 DATA "GUSSET","A BRACE FOR REINFORCING A CORNER"
 9800 DATA "INTERIM","MEANTIME"
 9810 DATA "MATTE","A DULL SURFACE OR FINISH"
 9820 DATA "MEDIAN","THE MIDDLE"
 9830 DATA "PLASMA","FLUID PART OF BLOOD; IONIZED GAS"
 9840 DATA "POISE","BALANCE; SELF-ASSURANCE"
 9850 DATA "PRECEDE","TO GO BEFORE"
 9860 DATA "PROCEED","TO CONTINUE ON"
 9870 DATA "SUCCUMB","TO GIVE WAY, OR SUBMIT"
 9880 DATA "FLOTSAM","ODDS AND ENDS;'------- & JETSAM'"
 9890 DATA "LIAISON","AMBASSADOR OR 'GO-BETWEEN'"
 9900 DATA "CABOCHON","GEM, CUT TO A SMOOTH DOMED SHAPE"
 9910 DATA "FILIGREE","LACY JEWELRY SCROLLWORK"
 9920 DATA "BIZARRE","WHIMSICALLY STRANGE OR ODD"
 9930 DATA "BAZAAR","MARKET PLACE OR CHARITY SALE"
 9940 DATA "OPAQUE","UNABLE TO TRANSMIT VISIBLE LIGHT"
 9950 DATA "SOLSTICE","The Summer -------- is June 21"
 9960 DATA "equinox","Vernal ------- is about March 21"
 9970 DATA "MERRIMAC","This ironclad fought the Monitor"
 9980 DATA "azimuth","Angle, clockwise from N or S"
 9990 DATA "nadir","The lowest point"
 9995 BORDER 7: PAPER 7: FLASH 0: GO TO 34
 9999 SAVE "WORDBUG" LINE 1

Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.