Text Printer

10 REM TEXT PRINTER
   20 REM RESET 1987 BYTE POWER
   30 REM BY E & K BOISVERT
   40 GO TO 2000
   50 REM LOAD DRIVER AT 34000
   55 
   60 REM LOAD BYTE POWER PART I          OR PART II AT 35000
   70 
   80 CLS : PRINT AT 10,0;"PRINTING ON FULL-SIZE PRINTER": LET char=35000: LET page=0: IF PEEK char=0 THEN LET char=char+1
   90 IF PEEK char=0 THEN GO TO 2000
   95 LPRINT : LPRINT : LPRINT "        -------------------------------------------------------- Page:";page: LPRINT : LET page=page+1
  100 FOR l=1 TO 18: LET a$="": FOR x=char TO char+63: LET a$=a$+CHR$ (PEEK x): NEXT x: LPRINT "        ";a$: LET char=char+64: NEXT l
  110 LPRINT : LPRINT : LPRINT : GO TO 90
 1005 CLS : PRINT AT 10,0;"PRINTING ON T/S 2040": LET page=0: LET char=35000: IF PEEK char=0 THEN LET char=char+1
 1010 DIM p$(64): LET a=32744: LET p$="PAGE:"+STR$ page
 1020 POKE 23606,a-256*INT (a/256)
 1030 POKE 23607,INT (a/256)
 1040 IF PEEK char=0 THEN POKE 23606,0: POKE 23607,60: GO TO 2000
 1050 FOR c=0 TO 63: LET a$="  "+p$(c+1)+"    ": FOR l=17 TO 0 STEP -1
 1060 LET b$=CHR$ PEEK (char+c+l*64): IF b$="FREE " OR b$="STICK" THEN LET b$=" "
 1065 LET a$=a$+b$: NEXT l: LPRINT a$: NEXT c: LET char=char+1152
 1070 POKE 23606,0: POKE 23607,60: LPRINT ''"--------------------------------"'''
 1080 LET page=page+1: GO TO 1000
 2000 REM MAIN MENU
 2010 POKE 23606,0: POKE 23607,60: CLS : PRINT AT 3,10;"TEXT PRINTER"
 2020 PRINT AT 6,0;"1. Printout on full-size printer"''"2. Printout on T/S 2040"''"3. Load text file"''"4. Instructions"''"5. Go to BASIC"
 2030 PRINT AT 21,0;"ENTER CHOICE: ": PAUSE 0: LET ky=PEEK 23560: IF ky<49 OR ky>53 THEN GO TO 2030
 2040 IF ky=49 THEN GO TO 80
 2045 IF ky=50 THEN GO TO 1000
 2050 IF ky=51 THEN CLS : INPUT "FILE NAME:"; LINE n$: RANDOMIZE USR 33768: LOAD n$CODE 35000: GO TO 2000
 2055 IF ky=52 THEN GO TO 3000
 2060 CLS : STOP 
 3000 REM INSTRUCTIONS
 3010 CLS : PRINT AT 2,10;"TEXT PRINTER"
 3020 PRINT AT 4,0;"This program will allow you to  print text from old issues of   BYTE POWER Magazine (AUGUST 86  Thru DEC/JAN 87) on either a    full-size printer or T/S 2040."
 3030 PRINT AT 10,0;"With a full-size printer you    must load the print driver firstThe print driver should be at   34000."
 3040 PRINT AT 15,0;"With the TS2040 the text will   be printed sideways in 64 column** Do not use this option with     full-size printer!"
 3050 PAUSE 0: CLS 
 3060 PRINT AT 4,0;"To load a file (PART I or II)   Choose option 3 and input file  name."''"PART I is found right after the first program (BYTE POWER) on   the old cassettes AUG 86-JAN 87 and PART II follows PART I."
 3070 PAUSE 0: GO TO 2000
 9000 LOAD ""CODE : RUN 
 9999 SAVE "TEXT PRINT" LINE 9000: SAVE "CODES"CODE 33000,785: VERIFY "": VERIFY ""CODE