Space Trek

   5 DIM F(8,8)
  10 PRINT AT 8,10;"\:'\''\''\''\''\''\''\''\''\''\''\''\':"
  15 LET DOCK=0
  16 LET CH=0
  20 PRINT TAB 10;"\:  SPACETREK \ :"
  30 PRINT TAB 10;"\:.\..\..\..\..\..\..\..\..\..\..\..\.:"
  40 PRINT AT 15,3;"DO YOU WANT INSTRUCTIONS?"
  50 PRINT 
  60 PRINT "1.YES"
  70 PRINT "2.NO"
  80 INPUT INST
  90 IF INST=1 THEN GOSUB 9000
  95 IF INST<1 OR INST>2 THEN GOTO 80
  96 CLS 
 100 PRINT "WHAT DEGREE OF DIFFICULTY?"
 105 PRINT "1. EASY"
 106 PRINT "2. FAIRLY HARD"
 107 PRINT "3. HARD"
 108 PRINT "4. VERY HARD"
 109 PRINT "5. IMPOSSIBLE"
 115 INPUT DEG
 116 IF DEG<1 OR DEG>5 THEN GOTO 115
 120 CLS 
 130 FAST 
 140 GOSUB 7000
 150 GOSUB 8000
 155 SLOW 
 160 PRINT AT 3,1;K;" DRAKONS ARE INVADING THE"
 170 PRINT TAB 12;"GALAXY"
 180 PRINT 
 190 PRINT TAB 10;"%G%O%O%D% %L%U%C%K"
 192 PRINT 
 194 PRINT TAB 5;"PRESS NEWLINE TO START"
 195 INPUT A$
 200 CLS 
 210 GOSUB 1000
 220 INPUT COM
 225 IF E<=0 OR DATE<=0 THEN GOTO 6500
 230 IF COM=1 THEN GOSUB 2000
 240 IF COM=2 THEN GOSUB 2500
 250 IF COM=3 THEN GOSUB 3000
 260 IF COM=4 THEN GOSUB 8200
 270 IF COM=5 THEN GOSUB 7300
 280 IF COM=6 THEN GOTO 6100
 285 GOSUB 6000
 286 LET CH=0
 290 GOTO 220
\n1000 PRINT AT 0,0;"CONDITION ";
\n1002 PRINT AT 0,0;"CONDITION ";
\n1004 IF Y=0 THEN LET C=1
\n1005 IF Y<>0 THEN LET C=2
\n1006 IF DOCK=-1 THEN LET C=3
\n1010 IF C=1 THEN PRINT "GREEN "
\n1020 IF C=2 THEN PRINT "%R%E%D   "
\n1030 IF C=3 THEN PRINT "DOCKED"
\n1032 LET DOCK=0
\n1040 PRINT AT 2,0;"\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@"
\n1050 FOR J=1 TO 10
\n1060 PRINT "\@@% % % % % % % % % % % % % % % % % % \@@"
\n1070 NEXT J
\n1080 PRINT "\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@\@@"
\n1090 FOR J=1 TO W
\n1100 PRINT AT B(J,1),B(J,2);"%*"
\n1110 NEXT J
\n1120 FOR J=W+1 TO W+Z
\n1130 PRINT AT B(J,1),B(J,2);"%X"
\n1140 NEXT J
\n1150 FOR J=W+Z+1 TO W+Z+Y
\n1160 PRINT AT B(J,1),B(J,2);"%V"
\n1170 NEXT J
\n1180 PRINT AT M,L;"%O"
\n1190 PRINT AT 0,18;"SECTOR ";Q(1);",";Q(2)
\n1200 PRINT AT 3,21;"ENERGY";TAB 21;E;"  "
\n1210 PRINT AT 5,21;"TORPEDOES";TAB 21;T;" "
\n1220 PRINT AT 7,21;"SHIELDS";TAB 21;S;"  "
\n1230 PRINT AT 9,21;"DRAKONS";TAB 21;K;"  "
\n1240 PRINT AT 11,21;"STARDATE";TAB 21;DATE;"  "
\n1242 PRINT AT 14,0;"                                "
\n1243 FOR J=1 TO 7
\n1245 PRINT "                                "
\n1248 NEXT J
\n1250 PRINT AT 15,9;"%C%O%M%M%A%N%D%?"
\n1255 IF S<15 THEN GOSUB 3300
\n1256 SLOW 
\n1260 RETURN 
\n2000 PRINT AT 15,9;"        "
\n2005 LET CH=0
\n2010 PRINT AT 15,0;"WARP (1-20)?"
\n2020 INPUT WA
\n2025 IF WA<0 OR WA>20 OR E<WA THEN GOTO 2020
\n2030 PRINT AT 15,5;WA;"      "
\n2040 IF WA=0 THEN GOTO 1000
\n2050 PRINT AT 17,0;"DIRECTION (1-8)?"
\n2060 INPUT DI
\n2065 IF DI<1 OR DI>8 THEN GOTO 2060
\n2070 PRINT AT 17,11;DI;"      "
\n2080 IF DI=2 OR DI=4 OR DI=6 OR DI=8 THEN LET WA=INT (SQR (WA*2))
\n2090 LET L=L+(DI=2 OR DI=4 OR DI=3)*WA-(DI=6 OR DI=7 OR DI=8)*WA
\n2100 LET M=M-(DI=1 OR DI=2 OR DI=8)*WA+(DI=4 OR DI=5 OR DI=6)*WA
\n2110 IF M>12 THEN LET Q(1)=Q(1)-1
\n2120 IF Q(1)>8 THEN LET Q(1)=Q(1)+8
\n2130 IF M<3 THEN LET Q(1)=Q(1)+1
\n2140 IF Q(1)<1 THEN LET Q(1)=Q(1)+8
\n2150 IF L>18 THEN LET Q(2)=Q(2)+1
\n2160 IF Q(2)>8 THEN LET Q(2)=Q(2)-8
\n2170 IF L<1 THEN LET Q(2)=Q(2)-1
\n2180 IF Q(2)<1 THEN LET Q(2)=Q(2)+8
\n2190 LET DATE=DATE-INT (WA/4)
\n2200 IF M>12 OR M<3 OR L>18 OR L<1 THEN LET CH=-1
\n2205 IF CH=-1 THEN FAST 
\n2210 IF M>12 THEN LET M=M-10
\n2220 IF M<3 THEN LET M=M+10
\n2230 IF L>18 THEN LET L=L-18
\n2240 IF L<1 THEN LET L=L+18
\n2250 IF M>12 OR M<3 OR L>18 OR L<1 THEN GOTO 2110
\n2280 LET E=E-2*WA
\n2290 IF CH=-1 THEN GOSUB 8000
\n2295 FOR D=1 TO W+Y+Z
\n2300 IF M=B(D,1) AND L=B(D,2) AND CH<>-1 THEN GOTO 6800
\n2301 NEXT D
\n2305 GOSUB 2800
\n2310 GOSUB 1000
\n2315 SLOW 
\n2320 RETURN 
\n2500 CLS 
\n2505 FAST 
\n2510 PRINT AT 0,8;"%L%O%N%G% %R%A%N%G%E% %S%C%A%N%."
\n2520 PRINT AT 1,0;"\''\''\''\''\''\''\''\''\''\''\''\''\''\''\''\''\''\''\''\''\''\''\''\''\''\''\''\''\''\''\''\''"
\n2525 FOR J=-1 TO 1
\n2530 FOR D=-1 TO 1
\n2532 LET ZZ=Q(1)-J
\n2534 LET YY=Q(2)+D
\n2540 IF (ZZ>0 AND ZZ<9 AND YY>0 AND YY<9) THEN LET F(ZZ,YY)=-1
\n2550 NEXT D
\n2560 NEXT J
\n2570 FOR J=2 TO 16 STEP 2
\n2580 FOR D=0 TO 28 STEP 4
\n2590 IF F(J/2,(D+4)/4)=-1 THEN PRINT AT 18-J,D;A(J/2,(D+4)/4)
\n2600 IF F(J/2,(D+4)/4)<>-1 THEN PRINT AT 18-J,D;"% % % % "
\n2610 NEXT D
\n2620 NEXT J
\n2630 PRINT AT 18-Q(1)*2,Q(2)*4-4;"\@@\@@\@@"
\n2640 PRINT AT 17,0;"\..\..\..\..\..\..\..\..\..\..\..\..\..\..\..\..\..\..\..\..\..\..\..\..\..\..\..\..\..\..\..\.."
\n2650 PRINT "MR SPARK REPORTS YOU ARE IN"
\n2655 PRINT "SECTOR ";Q(1);",";Q(2)
\n2660 SLOW 
\n2665 PAUSE 300
\n2670 POKE 16437,255
\n2680 CLS 
\n2690 LET DATE=DATE-1
\n2700 LET E=E-3
\n2710 GOSUB 1000
\n2720 RETURN 
\n2800 LET DOCK=0
\n2805 LET CRASH=0
\n2810 FOR D=W+1 TO W+Z
\n2820 IF ABS (M-B(D,1)<=1) AND ABS (L-B(D,2))<=1 THEN LET DOCK=-1
\n2830 IF CH=0 AND L=B(D,1) AND M=B(D,2) THEN LET CRASH=-1
\n2840 IF CRASH=-1 THEN GOTO 6500
\n2880 NEXT D
\n2885 LET DATE=DATE-2
\n2888 IF DOCK=0 THEN RETURN 
\n2890 LET E=3000
\n2900 LET T=T+2
\n2905 IF T>15 THEN LET T=15
\n2910 LET S=100
\n2920 RETURN 
\n3000 IF Y<>0 AND E<>0 THEN GOTO 3060
\n3005 IF E<=0 THEN GOTO 6500
\n3010 PRINT AT 15,9;"NO DRAKONS."
\n3020 PRINT 
\n3030 PRINT "ENERGY WASTED=500"
\n3035 LET E=E-500
\n3036 IF E<=0 THEN GOTO 6500
\n3040 GOSUB 1000
\n3050 RETURN 
\n3060 PRINT AT 15,6;"PHASERS LOCKED IN."
\n3070 FOR D=1 TO 25
\n3075 PRINT AT 17,11;"FIRING"
\n3076 FOR J=1 TO 2
\n3077 NEXT J
\n3079 PRINT AT 17,11;"\@@\@@\@@\@@\@@\@@"
\n3080 NEXT D
\n3100 PRINT AT 17,11;"%F%I%R%E%D "
\n3110 LET DIST=INT (SQR ((ABS (B(1,1)-M))**2+(ABS (B(1,2)-L))**2))
\n3120 LET E1=INT (E/Y/((DIST+1)*10))
\n3125 LET E=E-300*Y
\n3130 LET G=G-E1
\n3135 LET K=K-(Y-(INT (G/200)))
\n3140 LET A(Q(1),Q(2))=(INT (G/200))*100+Z*10+W
\n3145 LET DATE=DATE-2
\n3146 IF DATE=0 THEN GOTO 6500
\n3150 GOSUB 8000
\n3155 IF Y=0 THEN GOTO 3220
\n3156 PRINT AT 17,11;"                                                     "
\n3160 IF Y<>0 THEN PRINT AT 15,6;"DRAKONS FIRING BACK"
\n3162 PRINT "                                                                "
\n3170 LET RD=INT (RND*12)
\n3180 IF RD=11 THEN GOTO 3250
\n3184 IF S<=5 THEN GOTO 6500
\n3185 PRINT AT 17,4;"ENDEAVOUR HAS BEEN HIT"
\n3187 PRINT AT 19,6;"                 "
\n3190 LET E=E-INT (G*3/DIST)
\n3200 IF E<=0 THEN GOTO 6500
\n3210 LET S=S-INT (G/(12-(RND*4)))
\n3215 IF S<0 THEN LET S=0
\n3220 IF Y=0 THEN PRINT AT 15,1;"ALL DRAKONS IN THIS SECTOR","           %D%E%S%T%R%O%Y%E%D                                                                           "
\n3230 GOSUB 1000
\n3240 RETURN 
\n3250 PRINT TAB 6;"DRAKONS HAVE MISSED"
\n3260 GOTO 3230
\n3300 PRINT AT 19,12;"MR SCOTCH";TAB 2;"REPORTS SHIELDS AT LOW POWER"
\n3310 RETURN 
\n6000 IF CH=-1 OR RND*8>4 OR Y=0 THEN RETURN 
\n6005 PRINT AT 15,6;"HELM REPORTS THAT","THE ENDEAVOUR IS UNDER ATTACK."
\n6010 LET G=200*Y
\n6020 LET S=S-INT (G/(RND*4+6))
\n6030 LET E=E-INT (G/(RND*4.5))
\n6040 IF S<=0 OR E<=0 THEN GOTO 6500
\n6050 GOSUB 1000
\n6060 RETURN 
\n6100 CLS 
\n6110 PRINT AT 3,6;"RESIGNATION ACCEPTED"
\n6115 PRINT 
\n6120 GOTO 6710
\n6500 CLS 
\n6501 SLOW 
\n6505 IF E<=0 THEN GOTO 6530
\n6510 IF S<=0 THEN GOTO 6610
\n6515 IF DATE<=0 THEN GOTO 6680
\n6520 IF K=0 THEN GOTO 6750
\n6530 PRINT "THE ENDEAVOUR IS LYING DEAD IN"
\n6532 PRINT "SPACE DUE TO LACK OF ENERGY."
\n6534 PRINT "YOU AND YOUR CREW HAVE DIED AS"
\n6536 PRINT "THE LIFE SUPPORT SYSTEMS ARE"
\n6538 PRINT "INOPERATIVE."
\n6540 PRINT "THE ENDEAVOUR IS CAPTURED BY"
\n6542 PRINT "THE DRAKONS."
\n6544 GOTO 6700
\n6610 PRINT "THE ENDEAVOUR WAS CAUGHT WITH"
\n6620 PRINT "ITS SHIELDS DOWN. YOU HAVE BEEN"
\n6625 PRINT TAB 11;"%D%E%S%T%R%O%Y%E%D"
\n6650 GOTO 6700
\n6680 PRINT "STARFLEET COMMAND REPORTS"
\n6682 PRINT TAB 8;"""TIME HAS RUN OUT"""
\n6684 PRINT "THE DRAKONS HAVE CAPTURED THE"
\n6690 PRINT "FEDERATIONS HEADQUARTERS..."
\n6695 PRINT 
\n6700 PRINT TAB 12;"%Y%O%U% %L%O%S%E"
\n6705 PRINT 
\n6710 PRINT "ANOTHER GAME? (Y OR N)"
\n6720 INPUT A$
\n6725 IF A$="Y" THEN CLS 
\n6730 IF A$="Y" THEN RUN 
\n6740 STOP 
\n6750 PRINT "WELL DONE CAPTAIN. YOU HAVE"
\n6752 PRINT "DESTROYED ALL THE DRAKONS IN"
\n6754 PRINT "THE GALAXY."
\n6756 PRINT "YOU HAVE BEEN PROMOTED TO..."
\n6758 PRINT TAB 11;"%C%O%M%M%A%N%D%E%R"
\n6760 PRINT 
\n6770 PRINT TAB 12;"%Y%O%U% %W%I%N"
\n6772 PRINT 
\n6774 GOTO 6710
\n6800 CLS 
\n6810 PRINT "YOU HAVE CRASHED THE ENDEAVOUR"
\n6820 PRINT "INTO A ";
\n6825 IF D<=W THEN PRINT "STAR "
\n6830 IF D>=W+1 AND D<=W+Z THEN PRINT "STARBASE "
\n6835 IF D>W+Z THEN PRINT "DRAKON "
\n6840 PRINT 
\n6845 SLOW 
\n6850 GOTO 6700
\n7000 LET K=0
\n7010 DIM A(8,8)
\n7015 DIM Q(2)
\n7020 FOR X=1 TO 8
\n7030 FOR Y=1 TO 8
\n7040 LET B=INT (RND*7+3)
\n7050 LET B=B+10*INT (RND*2)
\n7060 LET B=B+100*INT (RND*(DEG+1))
\n7070 LET K=K+INT (B/100)
\n7080 LET A(X,Y)=B
\n7090 NEXT Y
\n7100 NEXT X
\n7105 LET DATE=INT (DEG*100*RND+350)
\n7106 LET C=1
\n7110 LET E=3000
\n7120 LET T=15
\n7130 LET S=100
\n7140 LET Q(1)=INT (RND*8+1)
\n7145 LET Q(2)=INT (RND*8+1)
\n7150 LET M=INT (RND*10+3)
\n7155 LET L=INT (RND*18+1)
\n7160 RETURN 
\n7300 IF E>1200 THEN LET S=100
\n7310 IF E>1200 THEN LET E=E-600
\n7320 LET DATE=DATE-1
\n7325 IF E>1200 THEN GOTO 7335
\n7326 IF E<1200 THEN LET E=E-INT (6*(100-S))
\n7330 IF E<1200 THEN LET S=S+INT (E/12)
\n7333 IF E<=0 THEN GOTO 6500
\n7335 PRINT AT 19,0;"                                                                "
\n7340 IF S>100 THEN LET S=100
\n7360 IF S=100 THEN PRINT AT 15,6;"SHIELDS AT FULL POWER"
\n7370 GOSUB 1000
\n7380 RETURN 
\n8000 IF Q(1)<1 THEN LET Q(1)=1
\n8002 IF Q(1)>8 THEN LET Q(1)=8
\n8004 IF Q(2)<1 THEN LET Q(2)=1
\n8006 IF Q(2)>8 THEN LET Q(2)=8
\n8008 LET X=A(Q(1),Q(2))
\n8010 LET Y=INT (X/100)
\n8020 LET Z=INT ((X-(Y*100))/10)
\n8030 LET W=X-Y*100-Z*10
\n8035 LET G=200*Y
\n8040 DIM B(W+Y+Z,2)
\n8050 LET B(1,2)=INT (RND*18+1)
\n8060 LET B(1,1)=INT (RND*10+3)
\n8070 FOR J=2 TO W+Y+Z
\n8080 LET B(J,2)=INT (RND*18+1)
\n8090 LET B(J,1)=INT (RND*10+3)
\n8100 FOR D=1 TO J-1
\n8110 IF (B(J,1)=B(D,1) AND B(J,2)=B(D,2)) OR (B(J,1)=L AND B(J,2)=M) THEN GOTO 8080
\n8120 NEXT D
\n8130 NEXT J
\n8140 RETURN 
\n8200 IF T=0 THEN LET E=E-400
\n8205 LET G=Y*200
\n8206 LET DIST=10
\n8210 IF E<=0 THEN GOTO 6500
\n8212 IF T=0 THEN GOSUB 1000
\n8215 IF T=0 THEN RETURN 
\n8216 IF Y=0 THEN PRINT AT 17,0;"NO DRAKONS ENERGY WASTED=500"
\n8217 LET E=E-500
\n8218 IF Y=0 THEN GOSUB 1000
\n8219 IF Y=0 THEN RETURN 
\n8220 PRINT AT 15,6;"%P%H%O%T%O%N% %T%O%R%P%E%D%O%E%S"
\n8230 PRINT AT 17,0;"DIRECTION (1-8)?"
\n8240 INPUT DI
\n8244 IF DI<1 OR DI>8 THEN GOTO 8240
\n8245 PRINT AT 17,10;" ";DI;"      "
\n8246 LET T=T-1
\n8250 PRINT AT 19,12;"%F%I%R%E%D"
\n8260 LET VX=L
\n8265 LET VY=M
\n8270 LET VX=VX+(DI=2 OR DI=3 OR DI=4)-(DI=8 OR DI=7 OR DI=6)
\n8280 LET VY=VY-(DI=1 OR DI=2 OR DI=8)+(DI=4 OR DI=5 OR DI=6)
\n8285 PRINT AT VY,VX;"%+"
\n8290 FOR D=1 TO W+Y+Z
\n8300 IF (VY=B(D,1) AND VX=B(D,2)) THEN GOTO 8390
\n8310 NEXT D
\n8320 IF VX<1 OR VX>18 OR VY<3 OR VY>12 THEN GOTO 8350
\n8340 GOTO 8270
\n8350 PRINT AT 19,12;"%M%I%S%S%E%D"
\n8370 GOSUB 1000
\n8380 RETURN 
\n8390 IF D<=W THEN GOTO 8440
\n8400 IF D>=W+1 AND D<=W+Z THEN GOTO 8460
\n8410 PRINT AT 19,6;"%D%R%A%K%O%N% %D%E%S%T%R%O%Y%E%D"
\n8415 LET K=K-1
\n8420 LET A(Q(1),Q(2))=A(Q(1),Q(2))-100
\n8430 GOTO 3150
\n8440 PRINT AT 19,11;"%A%B%S%O%R%B%E%D"
\n8450 GOTO 3150
\n8460 PRINT AT 19,3;"YOUVE DESTROYED A STARBASE"
\n8470 LET A(Q(1),Q(2))=A(Q(1),Q(2))-10
\n8480 GOTO 3150
\n9000 CLS 
\n9005 PRINT "   YOU ARE IN COMMAND OF THE";TAB 6;"STARSHIP ENDEAVOUR"
\n9010 PRINT 
\n9020 PRINT "THE GALAXY IS BEING ATTACKED BY"
\n9030 PRINT "THE DRAKONS. YOUR MISSION IS TO"
\n9040 PRINT "SEEK THEM OUT AND DESTROY THEM."
\n9042 PRINT "BEFORE TIME RUNS OUT."
\n9043 PRINT 
\n9044 PRINT "SYMBOLS ON THE SCREEN ARE:-"
\n9045 PRINT 
\n9046 PRINT "1. %*=STAR"
\n9047 PRINT "2. %O=THE ENDEAVOUR"
\n9048 PRINT "3. %V=A DRAKON"
\n9049 PRINT "4. %X=A STARBASE"
\n9050 PRINT 
\n9054 PRINT "YOU HAVE AT YOUR DISPOSAL"
\n9060 PRINT "SEVERAL COMMANDS."
\n9070 PRINT 
\n9080 PRINT "FOR A PRINTOUT OF THESE:-"
\n9090 PRINT TAB 9;"PRESS NEWLINE"
\n9100 INPUT A$
\n9110 CLS 
\n9120 PRINT "1. HELM","1.WARP SPEED"
\n9130 PRINT ,"2.DIRECTION"
\n9140 PRINT "2. LONG RANGE SCAN"
\n9150 PRINT "3. PHASERS"
\n9160 PRINT "4. PHOTON TORPEDOES"
\n9170 PRINT "5. SHIELDS"
\n9180 PRINT "6. RESIGNATION"
\n9190 PRINT 
\n9200 PRINT "DIRECTIONS ARE AS FOLLOWS."
\n9205 PRINT 
\n9210 PRINT TAB 13;"8 1 2"
\n9220 PRINT TAB 13;"\ '\. \: \.'"
\n9230 PRINT TAB 12;"7\..\..\:.\..\. 3"
\n9240 PRINT TAB 14;"\. \: \. "
\n9250 PRINT TAB 13;"\ ' \: \ '"
\n9255 PRINT TAB 13;"6 5 4"
\n9260 PRINT 
\n9261 PRINT "YOU MAY DOCK WITH STARSHIPS BY"
\n9262 PRINT "MOVING INTO THE SQUARE NEXT TO"
\n9263 PRINT "IT. YOU ARE THEN REFUELED."
\n9264 PRINT 
\n9270 PRINT "PRESS NEWLINE TO CONTINUE."
\n9280 INPUT A$
\n9290 CLS 
\n9300 PRINT "THE GALAXY IS DIVIDED UP INTO"
\n9310 PRINT "64 SECTORS. THESE ARE NUMBERED "
\n9320 PRINT "AS FOLLOWS:-"
\n9330 PRINT 
\n9340 FOR J=1 TO 8
\n9350 PRINT TAB 4;9-J;"\: "
\n9360 NEXT J
\n9370 PRINT TAB 5;"\''\''\''\''\''\''\''\''\''"
\n9380 PRINT TAB 5;"12345678"
\n9390 PRINT 
\n9395 PRINT AT 9,10;"% "
\n9400 PRINT AT 16,0;"THE NUMBER UP IS GIVEN FIRST."
\n9410 PRINT "E.G. THE BLACK SQUARE IS AT 3,6"
\n9420 PRINT 
\n9430 PRINT "PRESS NEWLINE"
\n9435 INPUT A$
\n9450 CLS 
\n9460 PRINT "THE NUMBER IN EACH SECTOR GIVES"
\n9470 PRINT "IMFORMATION ABOUT THE CONTENTS"
\n9480 PRINT "OF THAT SECTOR."
\n9490 PRINT 
\n9500 PRINT "THE IMFORMATON IS GIVEN AS:-"
\n9510 PRINT 
\n9520 PRINT "THE NO. OF","THE NO. OF"
\n9525 PRINT "\''\''\''\''\''\''\''\''\''\''","\''\''\''\''\''\''\''\''\''\''"
\n9530 PRINT "HUNDREDS    =   DRAKKONS."
\n9540 PRINT "TENS        =   STARBASES"
\n9550 PRINT "UNITS       =   STARS"
\n9560 PRINT 
\n9570 PRINT "TO PLAY PRESS NEWLINE."
\n9580 INPUT A$
\n9590 CLS 
\n9600 RETURN