An upgrade of Ultra-Easy Designer Graphics that designs a whole replacement character set instead of the 21 user-defined graphics. At RUN it copies the ROM character set to RAM at 64598 and points CHARS at the copy, so 115 characters can be redesigned (codes 32 to 127 plus the UDGs, skipping 124 and 126, which the TS2068 prints as STICK and FREE).
The work slate is the one from the original: a 16 by 16 grid holding four characters, a cursor moved with keys 5 to 8, 9 to set a cell and 0 to clear it, and a menu on the right worked with keys 3, 4 and 1. The new “a” key toggles between the slate and a list of all 115 characters with their codes and addresses; it asks whether you will return, so work on the slate is not lost. SAVE and LOAD now handle all 115 characters. In your own programs, set CHARS back (POKE 23606,0: POKE 23607,60, or GO SUB 610 in this program) before listing or breaking, or the text turns to gibberish.
The magazine printed only the new lines (Listing 2) and six steps for changing the version 1.0 listing from the July/August 1986 issue. The file is that full program put together as the article says. Listing 1, a five-line program that prints the eight bytes of each ROM character, is included in the text file but not on the tape.
Published in Time Designs Magazine November/December 1986 (Son of Ultra-Easy Designer Graphics).
Source Code
1 REM "SON OF ULTRA-EASY DESIGNER GRAPHICS" version 1.0 by p. bingham
10 CLEAR 64597: GO SUB 800: FOR t=15616 TO 16384: POKE (t+48982),PEEK t: NEXT t: FOR t=65528 TO 65535: READ o: POKE t,o: NEXT t: FLASH 0: CLS : GO SUB 9015: GO SUB 9520: DATA 0,0,63,252,252,248,0,0
20 DIM k(257): DIM c(4): FOR t=1 TO 4: LET c(t)=32: NEXT t: DIM d(32): DIM u(20): LET cs=7: LET at=7: LET px=5: LET py=1: INPUT "Press ENTER to continue...";n$: GO TO 105
21 LET x=1: LET y=5: GO TO 400
22 LET x=1: LET y=13: GO TO 400
23 LET x=9: LET y=5: GO TO 400
24 LET x=9: LET y=13: GO TO 400
25 GO TO 350
26 PAPER 7: LET k=5+(8*INT (px/13)): FOR h=k TO k+7: PRINT AT py,h;CHR$ 128: NEXT h: RETURN
27 PAPER 0: LET k=5+(8*INT (px/13)): FOR h=k TO k+7: PRINT AT py,h;CHR$ 143: NEXT h: RETURN
28 INPUT "1)SAVE UDGs 2)LOAD UDGs ";t: IF t=1 THEN SAVE "UDG"CODE 64598,941: RETURN
29 LOAD "UDG"CODE 64598,941: GO SUB 9000: RETURN
30 LET s=1: LET x=1: LET y=4: LET q=1: GO TO 35
31 LET s=9: LET x=1: LET y=12: LET q=22: GO TO 35
32 LET s=17: LET x=9: LET y=4: LET q=1: GO TO 35
33 LET s=25: LET x=9: LET y=12: LET q=22: GO TO 35
34 FOR m=30 TO 33: GO SUB m: NEXT m: RETURN
35 GO SUB 300: RETURN
36 LET s=1: LET qx=0: GO TO 410
37 LET s=9: LET qx=1: GO TO 410
38 LET s=17: LET qx=0: GO TO 410
39 LET s=25: LET qx=1: GO TO 410
40 FOR m=36 TO 39: GO SUB m: LET f=1: NEXT m: RETURN
41 INPUT "1)COPY 2)DISPLAY ";t: IF t=1 THEN COPY : LPRINT : LPRINT : LPRINT : RETURN
42 INPUT "1st:";c(1);" 2nd:";c(2);" 3rd:";c(3);" 4th:";c(4)
43 IF ci=9000 THEN GO SUB 350: GO SUB 600: PRINT AT 0,1;CHR$ c(1);CHR$ c(2);AT 1,1;CHR$ c(3);CHR$ c(4): GO SUB 610: FOR t=6 TO 18 STEP 4: PRINT AT 0,t;c(1+(t-6)/4): NEXT t: PAPER 1: RETURN
44 FOR t=1 TO 4: IF t<=2 THEN LET y1=1: LET x1=(INT (t*6/12))*8+4: GO TO 46
45 LET y1=9: LET x1=(INT (t*3/12))*8+4
46 IF c(t)>143 THEN LET h=(c(t)-144)*8+65368: GO TO 63
47 LET h=(c(t)-32)*8+64598
63 FOR m=h TO h+7: LET a1=PEEK m
64 FOR g=8 TO 1 STEP -1: LET a1=a1/2: IF INT a1<a1 THEN PAPER 0: PRINT AT y1,x1+g;CHR$ 143;: LET a1=INT a1: GO TO 66
65 PAPER 7: PRINT AT y1,x1+g;CHR$ 128;
66 NEXT g: LET y1=y1+1: NEXT m: NEXT t: RETURN
100 GO SUB 9000: GO SUB 9520
105 PAPER 1: PRINT AT cs,26;" ": PAPER 7: PRINT AT cs,26;CHR$ 164: IF ci=9600 THEN GO SUB 8000: GO TO 110
107 GO SUB 600: GO SUB 610
110 PAPER 1: PRINT AT cs,26;" ": IF CODE INKEY$=51 THEN LET cs=cs+1: GO TO 120
115 GO TO 140
125 IF cs=9 THEN LET cs=10
130 IF cs=15 THEN LET cs=16
135 IF cs>21 THEN LET cs=1
137 PAPER 7: PRINT AT cs,26;CHR$ 164
140 IF CODE INKEY$=52 THEN LET cs=cs-1: GO TO 160
150 GO TO 190
165 IF cs=9 THEN LET cs=8
170 IF cs=15 THEN LET cs=14
175 IF cs<1 THEN LET cs=21
180 PAPER 7: PRINT AT cs,26;CHR$ 164
190 IF CODE INKEY$=49 THEN GO SUB cs+750
200 IF CODE INKEY$=97 THEN GO SUB ci
210 GO TO 105
300 FOR h=x TO x+7: DIM a(8): LET b=1: LET c=0
310 FOR t=8 TO 1 STEP -1: LET a(t)=INT ((ATTR (h,y+t))/8)
320 IF a(t)<>7 THEN LET c=c+b
330 LET b=b*2: NEXT t: LET d(s)=c: LET s=s+1
340 PAPER 5: BRIGHT 1: PRINT AT h,q;" ": PRINT AT h,q;c: NEXT h: BRIGHT 0: RETURN
350 PAPER 7: IF ci=9000 THEN PRINT AT 0,1;" ";AT 0,6;" ";AT 0,10;" ";AT 0,14;" ";AT 0,18;" ";AT 1,1;" ";AT 21,16;" ": RETURN
360 FOR m=21 TO 24: GO SUB m: NEXT m: RETURN
400 FOR h=x TO x+7: FOR t=y TO y+7: PRINT AT h,t;CHR$ 128: NEXT t: NEXT h: RETURN
410 INPUT "CHR$ Number(C#) as Storage:";vn: IF vn>31 AND vn<128 AND vn<>124 AND vn<>126 OR vn>143 AND vn<165 THEN LET e=vn: GO TO 420
415 INPUT "Illegal entry!--hit ENTER";v$: GO TO 410
420 IF e>127 THEN LET j=INT (s/8): LET w=e-143: LET i=65360+8*w: GO TO 430
425 LET j=INT (s/8): LET w=e-31: LET i=64590+8*w
430 LET ru=s: FOR t=i TO i+7: POKE t,d(ru): LET ru=ru+1: NEXT t
435 PAPER 7: IF ci=9000 THEN GO TO 530
500 LET ki=i: LET f=e: FOR h=18+j TO 21: GO SUB 600: PRINT AT h,11;CHR$ e;AT h,23;CHR$ f: GO SUB 610: PRINT AT h,13;ki;AT h,19;f;: PAPER 5: BRIGHT 1: PRINT " ";: PAPER 7: BRIGHT 0: LET ki=ki+8: LET f=f+1: NEXT h
505 IF CODE CHR$ e=124 OR CODE CHR$ e=126 THEN RETURN
510 GO SUB 600: FOR h=19 TO 21: PRINT AT h,j+1;CHR$ e: NEXT h
520 IF j<2 THEN PRINT AT 19,j+7;CHR$ e: GO SUB 610: RETURN
525 PRINT AT 20,j+5;CHR$ e: GO SUB 610: RETURN
530 IF e<50 THEN LET gx=2: LET gy=28: GO TO 560
535 IF e<70 THEN LET gx=6: LET gy=48: GO TO 560
540 IF e<90 THEN LET gx=10: LET gy=68: GO TO 560
545 IF e<110 THEN LET gx=14: LET gy=88: GO TO 560
550 IF e<128 THEN LET gx=19: LET gy=108: GO TO 560
555 LET gx=24: LET gy=143
560 PRINT AT 21,16;i;AT 0,6+INT (s/8)*4;" ";AT 0,6+INT (s/8)*4;e: GO SUB 600: PRINT AT qx,1+INT (s/17);CHR$ e;AT gy-e,gx;CHR$ e: GO SUB 610: RETURN
600 POKE 23606,86: POKE 23607,251: RETURN
610 POKE 23606,0: POKE 23607,60: RETURN
785 IF ci=9600 THEN GO SUB cs+20: RETURN
790 IF ci=9000 AND cs=5 OR cs=8 OR cs>15 THEN GO SUB cs+20: RETURN
795 RETURN
800 FLASH 1: PRINT AT 17,8;"jesemenet!": RETURN
8000 GO SUB 8100
8002 LET n=CODE INKEY$: IF n=53 THEN GO SUB 8100: LET px=px-1
8005 IF px<5 THEN LET px=20
8010 IF n=54 THEN GO SUB 8100: LET py=py+1
8015 IF py>16 THEN LET py=1
8020 IF n=55 THEN GO SUB 8100: LET py=py-1
8025 IF py<1 THEN LET py=16
8030 IF n=56 THEN GO SUB 8100: LET px=px+1
8035 IF px>20 THEN LET px=5
8040 IF n=48 THEN PAPER 7: PRINT AT py,px;CHR$ 128
8042 IF n=57 THEN PAPER 0: PRINT AT py,px;CHR$ 143: PAPER 7
8045 FOR t=103 TO 105: PLOT 104,t: PLOT t,104: NEXT t
8050 RETURN
8100 LET at=INT ((ATTR (py,px))/8)
8105 IF at=7 THEN PRINT AT py,px;CHR$ 134: PRINT AT py,px;CHR$ 137: PRINT AT py,px;CHR$ 128
8110 IF at=0 THEN PAPER 7: PRINT AT py,px;CHR$ 134: PRINT AT py,px;CHR$ 137: PAPER 0: PRINT AT py,px;CHR$ 143: PAPER 7
8980 RETURN
9000 GO SUB 9015: INPUT "Display previous work? ";n$: IF n$<>"n" THEN LET tx=5: LET ty=1: FOR t=1 TO 256: GO TO 9003
9001 RETURN
9003 IF k(t)=1 THEN PAPER 0: PRINT AT ty,tx;CHR$ 143: PAPER 7: GO TO 9010
9005 PRINT AT ty,tx;CHR$ 128
9010 LET tx=tx+1: IF tx>20 THEN LET tx=5: LET ty=ty+1
9011 NEXT t: GO SUB 34: RETURN
9015 LET ci=9600: BORDER 1: PAPER 5: BRIGHT 1: FOR t=0 TO 21: PRINT AT t,0;" ";: NEXT t
9060 BRIGHT 0: FOR t=4 TO 21: PRINT AT 0,t;" ";AT 17,t;" ": NEXT t
9070 FOR t=1 TO 16: PRINT AT t,4;" ";AT t,21;" ": NEXT t
9080 PRINT AT 0,4;"_";AT 0,21;"_";AT 8,4;"_";AT 8,21;"_"
9090 FOR t=32 TO 39: PLOT 39,t: PLOT 103,t: PLOT 168,t: PLOT 39,t+136: PLOT 103,t+136: PLOT 168,t+136: NEXT t
9092 PRINT AT 0,8;"-1-";AT 17,8;"-3-";AT 0,15;"-2-";AT 17,15;"-4-"
9093 PLOT 39,39: DRAW 0,129: DRAW 129,0: DRAW 0,-129: PLOT 32,39: DRAW 143,0
9130 BRIGHT 0: PAPER 7: FOR t=1 TO 16: PRINT AT t,5;" ": NEXT t
9200 INK 0: PAPER 5: BRIGHT 1
9215 PRINT AT 18,1;"ABCD"
9225 PAPER 7: BRIGHT 0
9250 RETURN
9500 PRINT AT j,a;"-1-";AT j+1,a;"-2-";AT j+2,a;"-3-";AT j+3,a;"-4-";AT j+4,a;"all": RETURN
9520 PAPER 1: BRIGHT 0: FOR t=0 TO 21: PRINT AT t,26;" ": NEXT t
9530 BRIGHT 1: FOR t=0 TO 21: PRINT AT t,27;" ": NEXT t
9540 BRIGHT 0: PRINT AT 0,27;"ERASE";AT 7,27;"SWATH";AT 8,27;"SAVE ";AT 9,27;"CODES";AT 15,27;"STORE";AT 21,27;"PRINT"
9550 BRIGHT 1: LET a=28: LET j=1: GO SUB 9500
9560 LET j=10: GO SUB 9500: LET j=16: GO SUB 9500
9570 PRINT AT 6,a;"row": PAPER 7: BRIGHT 0: RETURN
9600 INPUT "Returning to current work? ";n$: IF n$<>"n" THEN PAPER 7: GO SUB 800: LET tx=5: LET ty=1: FOR t=1 TO 256: GO TO 9602
9601 GO TO 9608
9602 IF INT (ATTR (ty,tx)/8)<>7 THEN LET k(t)=1: GO TO 9605
9603 LET k(t)=0
9605 LET tx=tx+1: IF tx>20 THEN LET tx=5: LET ty=ty+1
9606 NEXT t
9608 LET ci=9000: FLASH 0: BORDER 5: PAPER 5: BRIGHT 0: FOR t=0 TO 21: PRINT AT t,0;" ": NEXT t
9610 LET bb=0: LET xp=32: LET yp=49: LET wp=28: LET xt=0: GO SUB 9720
9620 LET xp=50: LET yp=69: LET wp=48: LET xt=4: GO SUB 9720
9630 LET xp=70: LET yp=89: LET wp=68: LET xt=8: GO SUB 9720
9640 LET xp=90: LET yp=99: LET wp=88: LET xt=12: GO SUB 9720
9650 LET xp=100: LET yp=109: LET xt=11: GO SUB 9720
9660 LET xp=110: LET yp=127: LET wp=108: LET xt=16: GO SUB 9720
9670 LET xp=144: LET yp=164: LET wp=143: LET xt=21: LET bb=1: GO SUB 9720
9680 PAPER 7: PRINT AT 0,6;" ": PAPER 5: PRINT AT 16,25;" ";AT 16,19;"- ";AT 18,19;"- ";AT 0,0;"1 3";AT 1,0;"2 4"
9690 PRINT AT 0,5;"1";AT 0,9;"2";AT 0,13;"3";AT 0,17;"4": BRIGHT 1: PRINT AT 3,0;"C#:";AT 0,21;"UDG:";AT 20,16;"addr:": PAPER 7: BRIGHT 0: PRINT AT 21,16;"63568";AT 0,1;" ";AT 1,1;" "
9700 BRIGHT 0: RETURN
9720 FOR z=xp TO yp: LET aa=z-wp: PAPER 5: BRIGHT bb: PRINT AT aa,xt;z;
9730 POKE 23606,86: POKE 23607,251: PAPER 7: BRIGHT 0: PRINT CHR$ z: POKE 23606,0: POKE 23607,60: NEXT z: RETURN
Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.

