Ski

Developer(s): Charles Eric Goyette
Date: 1986
Type: Program
Platform(s): TS 2068
Tags: Game

A downhill skiing game for one or more players. After the rules, each player enters a name, then steers a skier down a scrolling slope of trees, moguls and flag gates with keys 5 and 8. The skier starts with 8 units of energy: hitting a tree costs 4, skiing between two flags adds 5, and running over a mogul gives bonus points. The run ends when the energy is gone or the slope is finished, with 50 bonus points for hitting no tree. When a player passes 150 points a new slope is created.

At the end of each turn the program shows the player’s points, the best score of the game and the record, then hands over to the next player. Sound effects use the TS2068 SOUND command.

The program is shipped as printed. A reader’s letter in the November/December 1986 issue pointed out that the highest scorer is not always named the winner and suggested changing H$ to S$ in line 500. Another reader suggested new tree graphics in line 9000 and INK 4 in line 1100. Neither change is in this file.

Published in Time Designs July/August 1986 (Ski).

Related Articles

Redirecting output from the screen to the printer on the 2068; Ski and Cavern games a hit; mathematic equalities; help with Larken disk drive; football prediction program.

Image Gallery

Source Code

1 LET IN=1: POKE 23658,8: BORDER 5: SOUND 6,31;7,63-24;8,16;9,10;12,14: LET HI=0: CLS : PRINT FLASH 1;AT 10,9;"STOP THE TAPE": PAUSE 150: CLS : INPUT "DO YOU WANT TO SAVE ?(Y-N)";R$: IF R$="Y" THEN SAVE "SKI" LINE 1
2 GO SUB 700: PAUSE 240: CLS : GO SUB 1000
3 LET H=0
4 IF IN=1 THEN GO SUB 4000
5 LET ROLE=1: INPUT "HOW MANY PLAYERS ?";TOT: GO SUB 600
6 PRINT AT 21,0; FLASH 1;"      WAIT 10 SECONDS        ";: GO SUB 9980
7 LET SUB=0: LET S$=""
8 REM CORRESPONDANCE:  A=\a , B=\b , AB=\a\b , C=\c , D=\d , E=\e , CDE=\c\d\e , F=\f ,                           G=\g , H=\h , I=\i
9 CLS
10 LET Z=50000: LET A=15
11 LET H=0: LET A$="\g\g"
12 POKE 23692,3: PRINT AT 15,0;"PRESS ON KEYS 5 OR 8 TO START.  ",,,,,,,,,,,
13 PRINT AT 21,8;"GET READY,";Y$(ROLE)
14 BEEP .07,10: PAUSE 0
15 CLS
17 LET TRE=0
20 LET SL=0
25 LET T=8
30 PRINT AT 9,A;T;" ENERGY"
40 SOUND 6,31;7,63-24;8,16;9,10;12,14
45 POKE 23692,255
49 IF A=0 THEN LET A=31
50 IF A=31 THEN LET A=0
51 IF INKEY$="5" THEN LET H=-1: SOUND 13,4;1,10: LET A$="\i\i"
52 IF INKEY$="8" THEN LET H=1: SOUND 13,4;1,10: LET A$="\h\h"
53 LET A=A+H
54 IF PEEK (22848+A)<>56 THEN GO TO 300
56 IF PEEK (22849+A)<>56 THEN GO SUB 325
59 PRINT AT 10,A;A$
70 PRINT AT 21,0
75 PRINT TAB (PEEK (Z)); INK 4;"\a\b"
77 IF PEEK (Z)>50 THEN PRINT AT 20,0: PRINT TAB (PEEK (Z))-50; INK 5;"\c\d\e"
79 IF PEEK (Z)>100 THEN PRINT AT 20,0: PRINT TAB (PEEK (Z))-100; INK 2;"\f   \f": PRINT TAB (PEEK (Z))-100; INK 2;"\g___\g"
80 LET Z=Z+1
90 IF Z>50210 THEN LET Z=Z+50: GO TO 400
100 GO TO 45
110 LET Z=Z-50000
120 LET Z=Z+SL
123 CLS
125 IF TRE=0 THEN LET Z=Z+50: PRINT AT 1,0; INK 2;"YOU HAVE HIT NO TREE!!BONUS:50!"
155 PAUSE 50
157 PRINT AT 3,0
160 PRINT Y$(ROLE);" YOU HAVE ";Z;" POINTS",
162 PRINT
165 IF Z<SUB THEN PRINT S$;" HAS THE BEST SCORE:";SUB
171 PRINT
173 IF Z>=SUB THEN IF TOT>1 THEN LET SUB=Z: LET S$=Y$(ROLE): PRINT S$;" HAS THE BEST SCORE:";SUB
174 PRINT
175 IF Z>=HI THEN LET HI=Z: LET H$=Y$(ROLE)
176 PRINT H$;" HAS THE RECORD:";HI
177 PAUSE 50
180 LET ROLE=ROLE+1
185 IF ROLE>TOT THEN GO TO 500
215 GO TO 10
300 IF PEEK (22848+A)=60 THEN LET T=T-4: LET TRE=TRE+1: SOUND 6,31;7,7;8,16;9,16;10,16;12,30;13,9: FOR Q=1 TO 70: NEXT Q: SOUND 6,31;7,63-24;8,16;9,10;12,14
310 IF PEEK (22848+A)=61 THEN SOUND 7,56;8,15;9,15;10,15;11,0;12,0: FOR Q=1 TO 250 STEP 20: SOUND 0,Q;2,250-Q;4,Q: NEXT Q: LET SL=SL+5: LET L=INT (RND*8)-4: LET A=A+L: SOUND 6,31;7,63-24;8,16;9,10;12,14;13,9;10,16
315 IF PEEK (22848+A)=58 AND SCREEN$ (10,A)="_" THEN FOR F=1 TO 5: BEEP .008,10: NEXT F: LET T=T+5
317 PRINT AT 9,A;T
318 IF T<=0 THEN GO TO 400
320 GO TO 59
325 IF PEEK (22849+A)=60 THEN LET T=T-4: LET TRE=TRE+1: SOUND 6,31;7,7;8,16;9,16;10,16;12,30;13,9: FOR Q=1 TO 70: NEXT Q: SOUND 6,31;7,63-24;8,16;9,10;12,14
330 IF PEEK (22849+A)=61 THEN SOUND 6,0;7,56;8,15;9,15;10,15;11,0;12,0: FOR Q=0 TO 250 STEP 20: SOUND 0,Q;2,250-Q;4,Q: NEXT Q: LET SL=SL+5: LET L=INT (RND*8)-4: LET A=A+L: SOUND 6,31;7,63-24;8,16;9,10;12,14;13,9;10,16
332 IF PEEK (22849+A)=58 AND SCREEN$ (10,A)="_" THEN FOR F=1 TO 5: BEEP .008,10: NEXT F: LET T=T+5
334 PRINT AT 9,A;T
335 IF T<=0 THEN GO TO 400
336 RETURN
400 FOR F=8 TO 21: PRINT AT F,0;"  ";: NEXT F
401 FOR F=1 TO 21 STEP 2
403 FOR G=1 TO 8: NEXT G
404 PRINT AT 21,0; INK 4;"\a\b  \a\b  \a\b  \a\b  \a\b  \a\b  \a\b  \a\b    \a\b  \a\b  \a\b  \a\b  \a\b  \a\b  \a\b  \a\b  "
406 NEXT F
410 GO TO 110
500 PAUSE 100: IF TOT>1 THEN PRINT AT 10,0;H$;" HAS WON";AT 11,10;"WITH ";SUB;" POINTS.",,,,,,,,,,,,,,,,
505 FOR U=1 TO 5
510 BEEP .03,0: BEEP .03,3: BEEP .03,7: BEEP .03,1: BEEP .03,4: BEEP .03,9: BEEP .1,15
515 NEXT U
517 LET ROLE=1
520 FOR F=1 TO 50: NEXT F
525 INPUT "DO YOU PLAY ANOTHER GAME ?(Y-N)",S$: IF S$<>"N" THEN GO TO 650
530 RESTORE : GO TO 2
600 DIM Y$(TOT,9)
605 FOR F=1 TO TOT
610 PRINT AT 21,0;"NAME OF PLAYER ";F;: INPUT U$
611 LET U$=U$+"         "
615 LET Y$(F)=U$(1 TO 9)
620 NEXT F
630 RETURN
650 IF TOT=1 AND Z>150 THEN GO TO 6
651 IF TOT=1 THEN GO TO 7
652 LET I$=Y$(1)
655 FOR F=1 TO TOT-1
660 LET Y$(F)=Y$(F+1)
665 NEXT F
670 LET Y$(TOT)=I$
675 IF SUB>150 THEN GO TO 6
699 GO TO 7
700 FOR F=0 TO 7
705 READ X,Y
710 POKE USR "A"+F,X
715 POKE USR "B"+F,Y
720 NEXT F
730 FOR F=0 TO 7
733 READ M,N,O
735 POKE USR "C"+F,M
740 POKE USR "D"+F,N
742 POKE USR "E"+F,O
750 NEXT F
755 FOR F=0 TO 7
760 READ M,N,O,P
765 POKE USR "F"+F,M: POKE USR "G"+F,N
767 POKE USR "H"+F,O: POKE USR "I"+F,P
770 NEXT F
800 RETURN
1000 PLOT 95,150
1010 DRAW -50,-40: DRAW 50,-20: DRAW -50,-40
1020 DRAW 55,40: DRAW -50,20: DRAW 45,40
1030 PLOT 180,150
1040 DRAW 4,-100: DRAW 4,100: DRAW -4,-7: DRAW -4,7
1050 CIRCLE 184,157,7
1060 PLOT 120,150
1070 DRAW 0,-100: DRAW 4,47: DRAW 35,-47: DRAW -35,52: DRAW 35,47: DRAW -35,-52: DRAW -4,47
1080 PAUSE 140
1100 PRINT AT 1,5;"\a\b";AT 16,3;"\a\b";AT 20,17;"\a\b";AT 8,27;"\a\b";AT 4,25;"\a\b";AT 17,22;"\a\b";AT 10,5;"\a\b";AT 5,10;"\a\b";AT 2,15;"\a\b"
1200 FOR F=1 TO 20: BEEP .002,65: NEXT F: PRINT AT 18,1;"JUNE '86-CHARLES ERIC GOYETTE"
1205 PAUSE 15
1210 FOR F=1 TO 40: BEEP .002,65: NEXT F: PAUSE 30: BEEP .04,5: BEEP .02,10: BEEP .05,5
1230 PAUSE 40
2000 RETURN
4000 LET IN=IN+1: CLS
4010 PRINT : PRINT "*************RULES**************"
4020 PRINT : PRINT "YOU START THE GAME WITH 8 UNITS OF ENERGY , WHEN YOU HIT A TREE,"
4030 PRINT "YOU LOSE 4 UNITS , WHEN YOU SKI BETWEEN TWO FLAGS,YOU GET 5     UNITS OF ENERGY ,"
4040 PRINT "WHEN YOU STEP ON A \c\d\e , YOU GETS BONUS POINTS , DESCENDING ALL THE SLOPE GIVES 50 BONUS POINTS."
4045 PRINT "IF YOU HIT NO TREE,YOU GET 50   BONUS POINTS."
4047 PRINT "WHEN ONE OF THE PLAYERS GETS    MORE THAN 150 POINTS,A NEW SLOPEIS CREATED."
4050 PRINT : PRINT "***********GOOD LUCK!***********"
4060 RETURN
9000 DATA 0,128,1,128,7,192,25,152,33,132,15,208,49,140,65,130
9010 DATA 0,0,0,0,0,0,0,126,0,3,129,192,12,0,48,48,0,6,192,0,3,0,0,0
9020 DATA 48,32,128,1,56,32,64,2,62,32,32,4,63,32,16,8,62,32,8,16,56,32,4,32,48,32,2,64,32,32,1,128
9989 FOR F=1 TO 200 STEP 2
9990 LET L=RND*15
9991 POKE 50000+F,(RND*28)+1
9992 POKE 50001+F,(RND*28)+1
9994 IF L<6 THEN POKE 50000+F,(RND*24)+54
9995 IF L>13.5 THEN POKE 50000+F,(RND*26)+101
9996 NEXT F
9997 RETURN

Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.