Tom Wood’s ZX Data Finder and Strength of Materials on one tape.
Content
Image Gallery
Source Code
5 REM **STROMAT**
7 PRINT "% % % % STRENGTH OF MATERIALS % % % % % "
8 PRINT "% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % "
10 PRINT "% % % % % % % % % SHAPE TABLE % % % % % % % % % % "
11 PRINT
12 PRINT
13 PRINT " 1 % SQ/RECT SOLID"
14 PRINT " 2 O SQ/RECT TUBE"
16 PRINT " 3 * ROUND SOLID"
18 PRINT " 4 O ROUND TUBE"
20 PRINT " 5 I SECTION"
22 PRINT " 6 H SECTION"
24 PRINT " 7 C SECTION"
26 PRINT " 8 L SECTION"
28 PRINT " 9 V SECTION (INVERTED)"
30 PRINT " 10 T SECTION"
32 PRINT " 11 + SECTION"
40 PRINT
45 PRINT
50 PRINT "ENTER APPROPRIATE SHAPE CODE"
55 INPUT N
60 CLS
65 IF N>11 THEN LET N=19
70 GOTO N*100
100 PRINT "% % % SQUARE/RECTANGULAR SOLID % % % "
104 PRINT
106 PRINT "\ .\..\..\..\..\..\. ----*-"
108 PRINT "\ :% % % % % \: : LOAD"
110 PRINT "\ :% % % % % \: : \: "
112 PRINT "\ :% % % % % \: -*- D \'.\:.\' "
114 PRINT "\ :% % % % % \: : : \' "
116 PRINT "\ :% % % % % \: Y :"
118 PRINT "\ '\''\''\''\''\''\' -*--*-"
120 PRINT ": :"
122 PRINT "*--B--*"
124 PRINT
128 PRINT "B=";
130 INPUT B
132 PRINT B;" ";
136 PRINT "D=";
138 INPUT D
140 PRINT D;" ";
142 LET Y=D/2
146 PRINT "Y=";Y
148 PRINT
149 LET T=0
150 LET A=B*D
152 LET I=(B*(D**3))/12
154 LET Z=I/Y
155 LET K=SQR (I/A)
156 GOSUB 1600
168 GOTO 1500
200 PRINT "% % % % SQUARE/RECTANGULAR TUBE % % % "
202 PRINT "\ .\..\..\..\..\..\. ----*-"
204 PRINT "\ :\:'\''\''\''\':\: --*-: D=OUTSIDE DEPTH"
206 PRINT "\ :\: \ :\: : : B=OUTSIDE BREARDTH"
208 PRINT "\ :\: \ :\: H : H=INSIDE DEPTH"
210 PRINT "\ :\: \ :\: *-: D K=INSIDE BREARDTH"
212 PRINT "\ :\: \ :\: : : : T=THICKNESS (WALL)"
214 PRINT "\ :\: \ :\: Y : : Y=MOMENT"
216 PRINT "\ :\:.\..\..\..\.:\: :-*-:"
218 PRINT "\ '\''\''\''\''\''\' *-*-*-"
220 PRINT ":*-K-*: :"
222 PRINT ":: -**--T ENTER (IF KNOWN)"
224 PRINT "*--B--* ""0"" (IF UNKNOWN)"
226 PRINT ": :"
230 INPUT T
236 PRINT "D=";
238 INPUT D
240 PRINT D;" B=";
244 INPUT B
246 PRINT B
248 IF T<>0 THEN GOTO 262
249 PRINT "H=";
250 INPUT H
252 PRINT H;
253 PRINT " K=";
254 INPUT K
256 LET T=(B-K)/2
258 PRINT K;" T=";T
260 GOTO 270
262 LET H=D-2*T
264 LET K=B-2*T
266 PRINT "H=";H;" K=";K;" T=";T
268 LET Y=D/2
270 LET A=(D*B)-(H*K)
272 LET I=((B*D**3)-(H*K**3))/12
274 LET Z=I/Y
275 LET K=SQR (I/A)
276 GOSUB 1600
278 PRINT
280 GOTO 1500
282 STOP
300 PRINT "% % % % % % % % % ROUND SOLID % % % % % % % % % % "
301 PRINT
302 PRINT " \..\..\..-----*-"
304 PRINT " \ .% % % % % \. :"
306 PRINT " % % % % % % % :"
308 PRINT "\ :% % % % % % % \: D D=DIAMETER"
310 PRINT "\ :% % % % % % % \: *-:"
312 PRINT "\ :% % % % % % % \: : :"
314 PRINT " % % % % % % % Y : Y=DEM(NEUT FIBER)"
316 PRINT " \ '% % % % % \' : :"
318 PRINT " \''\''\''---*-*-"
320 PRINT
322 PRINT "D=";
324 INPUT D
326 LET Y=D/2
328 PRINT D;" Y=";Y
329 LET B=D
330 LET A=PI/4*(D**2)
331 LET T=0
332 LET I=PI/64*(D**4)
334 LET Z=I/Y
335 LET K=SQR (I/A)
336 GOSUB 1600
340 GOTO 1500
350 STOP
400 PRINT "% % % % % % % % % % ROUND TUBE % % % % % % % % % % "
402 PRINT " \..\..\..-------*-"
404 PRINT " \ .% \:'\''\':% \. ---*-:"
406 PRINT " % \' \ '% : :"
408 PRINT "\ :\:' \':\: ID :"
410 PRINT "\ :\: \ :\: *-: :"
412 PRINT "\ :\:. \.:\: : :OD"
414 PRINT " % \. \ .% Y : :"
416 PRINT " \ '% \:.\..\.:% \' -:-*-:"
418 PRINT " \''\''\''---*-*-*-"
420 PRINT TAB 11;":"
422 PRINT TAB 11;"T"
424 PRINT "ENTER ""T""(IF KNOWN),""0""(IF NOT)"
426 INPUT T
432 PRINT "OD=";
434 INPUT OD
435 LET Y=OD/2
436 IF T<>0 THEN GOTO 446
438 PRINT OD,"ID=";
440 INPUT ID
442 PRINT ID,"T=";(OD-ID)/2,"Y=";OD/2
444 GOTO 451
446 LET ID=OD-(2*T)
450 PRINT OD,"ID=";ID,"T=";T,"Y=";Y
451 LET B=ID
452 LET A=PI/4*(OD**2-ID**2)
453 LET D=OD
454 LET I=(PI/64)*(OD**4-ID**4)
456 LET Z=I/Y
457 LET K=SQR (I/A)
458 GOSUB 1600
462 GOTO 1500
464 STOP
500 PRINT "% % % % % % % % % % % I-SECTION % % % % % % % % % % "
501 LET N=5
502 PRINT " \ .\..\..\..\..\. ---*-"
503 PRINT " \ '\''\':\:'\''\' -*-:"
504 PRINT " \ :\: : : LOAD"
505 PRINT "-*---\ :\: H : \: "
506 PRINT " : \ :\: : : \'.\:.\' "
508 PRINT " Y \ :\: : D \' "
516 PRINT " : \ .\..\.:\:.\..\. -*-:"
518 PRINT "-*-\ '\''\''\''\''\' -*-*-"
520 PRINT " : :: : :"
522 PRINT " T--**-: F"
524 PRINT " *--B-*"
526 PRINT " : :"
530 PRINT "T=";
532 INPUT T
534 PRINT T;" F=";
536 INPUT F
538 PRINT F;" D=";
540 INPUT D
542 LET H=D-(2*F)
543 LET Y=D/2
544 PRINT D,"Y=";Y;" H=";H;" B=";
546 INPUT B
548 PRINT B
550 IF N<>5 THEN GOTO 30+(N*100)
552 LET Y=D/2
554 LET A=(B*D)-(H*(B-T))
556 LET I=((B*(D**3))-((H**3)*(B-T)))/12
558 LET Z=I/Y
561 LET K=SQR (I/A)
564 GOSUB 1600
566 GOTO 1500
600 PRINT "% % % % % % % % % % H-SECTION % % % % % % % % % % % "
601 LET N=6
602 PRINT " \ .\. \ .\. ---*-"
604 PRINT " \ :\: \ :\: T : LOAD"
606 PRINT " \ :\: \ :\: : : \: "
608 PRINT " \ :\:.\..\..\..\.:\: -*-B \'.\:.\' "
610 PRINT " \ :\:'\''\''\''\':\: -*-: \' "
612 PRINT " \ :\: \ :\: : :"
614 PRINT " \ :\: \ :\: Y :"
616 PRINT " \ '\' \ '\' -*-*-:"
618 PRINT " : ::"
620 PRINT " : -**-F"
622 PRINT " *--D--*"
624 PRINT " : :"
628 GOTO 528
630 LET Y=B/2
632 LET A=(B*D)-(H*(B-T))
634 LET I=((2*F*(B**3))+(H*(T**3)))/12
636 LET Z=I/Y
639 LET K=SQR (I/A)
640 GOSUB 564
700 PRINT "% % % % % % % % % % C-SECTION % % % % % % % % % % % "
701 LET N=7
702 PRINT " \ .\..\..\..\..\..\. -----*-"
704 PRINT " \ :\:'\''\''\''\''\' ---*-:"
706 PRINT " \ :\: : : LOAD"
708 PRINT " \ :\: H : \ :"
710 PRINT " \ :\: ------*-: D \ '\.:\.'"
712 PRINT " \ :\: : : : \ '"
714 PRINT " \ :\: Y : :"
716 PRINT " \ :\:.\..\..\..\..\. -:-*-:"
718 PRINT " \ '\''\''\''\''\''\' -*-*-*-"
720 PRINT " :: : :"
722 PRINT "-**-T : F"
724 PRINT " :: : :"
726 PRINT " *--B--*"
727 PRINT " : :"
728 GOTO 528
730 LET Y=D/2
732 LET A=(B*D)-(H*(B-T))
734 LET I=((B*(D**3))-((H**3)*(B-T)))/12
736 LET Z=I/Y
739 LET K=SQR (I/A)
740 GOTO 564
800 PRINT "% % % % % % % % % % L-SECTION % % % % % % % % % % % "
801 LET N=8
806 PRINT "-*-\ .\. ------*-*-"
808 PRINT " : \ :\: : :"
810 PRINT " : \ :\: LOAD : :"
812 PRINT " B \ :\: \: Y :"
814 PRINT " : \ :\: \'.\:.\' : :"
816 PRINT " : \ :\: \' : H"
818 PRINT " :-\ :\: ------*-:"
820 PRINT " : \ :\: :"
822 PRINT " : \ :\:.\..\..\..\..\..\. --*-"
824 PRINT "-*-\ '\''\''\''\''\''\''\' --*-"
826 PRINT " : : :"
828 PRINT " *--D---* T"
830 PRINT " : :"
834 PRINT "T=";
836 INPUT T
838 PRINT T;" B=";
840 INPUT B
841 PRINT B;" D=";
842 INPUT D
845 LET H=B-T
846 LET Y=B-(T*(2*H+D)+(H**2))/(2*(H+D))
848 PRINT D,"H=";H;" Y=";Y
850 LET A=T*(D+H)
851 LET P2=(T*(Y**3))+D*((B-Y)**3)
852 LET P1=(D-T)*((B-Y-T)**3)
853 LET I=(P2-P1)/3
854 LET Z=I/Y
856 LET K=SQR (I/A)
858 GOTO 564
900 PRINT "% % % % % % % % % % V-SECTION % % % % % % % % % % % "
901 LET N=9
902 PRINT " *"
904 PRINT " / \..-----*-"
906 PRINT " / \.:\''\:. :"
908 PRINT " B \.:\' \ '\:. Y"
910 PRINT " / \.:\' \ '\:. :"
912 PRINT " / \.:\' -----\ '\:.-*-N.F."
914 PRINT " * \.:\' \ '\:."
916 PRINT " \ '\' \ '\' "
918 PRINT " //"
920 PRINT " T"
921 PRINT
922 PRINT "T=";
924 INPUT T
926 PRINT T;" B=";
927 INPUT B
928 PRINT B;
930 LET A=T*((2*B)-T)
931 LET D=B
932 LET Y=((B**2)+(B*T)-(T**2))/(2*(2*B-T)*COS (PI/4))
934 LET P1=Y*COS (PI/4)
936 LET I=(2*(P1**4)-(2*(P1-T)**4)+T*(B-(2*P1-T/2))**3)/2
938 LET Z=I/Y
940 LET K=SQR (I/A)
942 PRINT " Y=";Y,"AREA=";A,,"S.MOD.=";Z
944 GOTO 564
950 STOP
\n1000 PRINT "% % % % % % % % % % T-SECTION % % % % % % % % % % % "
\n1002 PRINT " *----B---*"
\n1004 PRINT " : : :"
\n1006 PRINT "-*---\ .\..\..\..\..\..\..\..\..\. -*-"
\n1008 PRINT "-*-*-\ '\''\''\''\':\:'\''\''\''\' :"
\n1010 PRINT " : : \ :\: :"
\n1012 PRINT " F : NF--\ :\: --*- :"
\n1014 PRINT " H \ :\: : D"
\n1016 PRINT " : \ :\: Y :"
\n1018 PRINT " : \ :\: : :"
\n1020 PRINT " -*-----\ '\' --*--*-"
\n1022 PRINT " ::"
\n1024 PRINT " -**-T"
\n1025 PRINT "T=";
\n1026 INPUT T
\n1028 PRINT T;" F=";
\n1030 INPUT F
\n1032 PRINT F;" B=";
\n1034 INPUT B
\n1036 PRINT B;" D=";
\n1038 INPUT D
\n1040 PRINT D
\n1041 LET H=D-F
\n1042 LET A=B*F+H*T
\n1044 LET Y=D-(((D**2)*T+(F**2)*(B-T))/(2*A))
\n1045 PRINT "H=";H;" Y=";Y
\n1046 LET I=.5*(T*Y**3)+B*(D-Y)**3-(B-T)*(D-Y-F)**3
\n1048 LET Z=I/Y
\n1050 LET K=SQR (I/A)
\n1052 GOTO 564
\n1100 PRINT "% % % % % % % % % % +-SECTION % % % % % % % % % % % "
\n1101 LET N=11
\n1104 PRINT " -* *-T"
\n1106 PRINT " : :"
\n1108 PRINT " \ .\..\. ------*-"
\n1110 PRINT " \ :% \: :"
\n1112 PRINT " : \ :% \: D"
\n1114 PRINT "-*-\ .\..\..\.:% \:.\..\..\. :"
\n1116 PRINT " F \ :% % % % % % % \: -*-:"
\n1118 PRINT "-*-\ '\''\''\':% \:'\''\''\' : :"
\n1120 PRINT " : : \ :% \: : Y :"
\n1122 PRINT " : \ :% \: : : :"
\n1124 PRINT " : \ '\''\' ----*-*-"
\n1125 PRINT " : :"
\n1126 PRINT " *---B---*"
\n1128 PRINT " : :"
\n1130 PRINT "T=";
\n1132 INPUT T
\n1134 PRINT T," F=";
\n1135 INPUT F
\n1136 PRINT F,"D=";
\n1137 INPUT D
\n1138 PRINT D;" B=";
\n1140 INPUT B
\n1142 LET A=D*T+F*(B-T)
\n1144 LET Y=D/2
\n1146 LET I=((T*D**3)+(F**3)*(B-T))/12
\n1148 LET Z=I/Y
\n1150 LET K=SQR (I/A)
\n1152 PRINT B;" Y=";Y
\n1154 GOTO 564
\n1200 PRINT "% % % % % % % % MATERIAL TABLE % % % % % % % % "
\n1205 PRINT
\n1210 PRINT " 1 CLASS 25 CAST GRAY IRON"
\n1215 PRINT " 2 DUCTILE (NODULAR) CAST IRON"
\n1220 PRINT " 3 1020 LOW CARBON STEEL"
\n1225 PRINT " 4 30302 STAINLESS STEEL"
\n1230 PRINT " 5 51430 STAINLESS STEEL"
\n1235 PRINT " 6 6063 T5 ALUMINUM"
\n1240 PRINT " 7 6061 T6 ALUMINUM"
\n1245 PRINT " 8 NO.2 STRUCTUAL DOUGLAS FIR"
\n1250 PRINT " 9 ABS INJ. MOLDED OR HIS"
\n1255 PRINT "10 MOLDED NYLON 6+40 PCT. GLASS"
\n1260 PRINT
\n1265 PRINT "ENTER OPPROPRIATE MATERIAL CODE"
\n1270 INPUT Q
\n1275 PRINT
\n1280 PRINT
\n1300 IF Q=1 THEN LET P=14.2
\n1305 IF Q=1 THEN LET S=25000
\n1310 IF Q=2 THEN LET P=25
\n1315 IF Q=2 THEN LET S=80000
\n1320 IF Q=3 THEN LET P=30
\n1325 IF Q=3 THEN LET S=80000
\n1330 IF Q=4 THEN LET P=28
\n1335 IF Q=4 THEN LET S=105000
\n1340 IF Q=5 THEN LET P=29
\n1345 IF Q=5 THEN LET S=80000
\n1350 IF Q=6 THEN LET P=10.3
\n1355 IF Q=6 THEN LET S=29000
\n1360 IF Q=7 THEN LET P=11.3
\n1365 IF Q=7 THEN LET S=48000
\n1370 IF Q=8 THEN LET P=1.3
\n1375 IF Q=8 THEN LET S=1300
\n1380 IF Q=9 THEN LET P=.29
\n1385 IF Q=9 THEN LET S=5500
\n1390 IF Q=10 THEN LET P=1.5
\n1395 IF Q=10 THEN LET S=26000
\n1400 PRINT
\n1410 LET P=P*1E6
\n1415 PRINT "TESILE=";S;" MOD.EL.=";P
\n1500 PRINT AT 21,0;"ENT:(1)SEC(2)MAT(3)LOAD(4)RECALC"
\n1502 INPUT N$
\n1504 IF CODE N$<29 AND CODE N$>33 THEN GOTO 1548
\n1510 LET N=VAL N$
\n1512 IF N=5 THEN GOTO 3800
\n1515 CLS
\n1520 IF N=1 THEN GOTO 10
\n1530 IF N=2 THEN GOTO 1200
\n1540 IF N=3 THEN GOTO 2000
\n1545 IF N=4 THEN GOTO 2055
\n1548 CLS
\n1550 PRINT AT 11,10;"% %P%A%R%D%O%N%?% "
\n1552 FOR J=1 TO 30
\n1554 NEXT J
\n1556 GOTO 1500
\n1600 IF NOT A THEN GOTO 10
\n1610 PRINT "SECTION AREA= ";A
\n1615 PRINT "SECTION MODULUS= ";Z
\n1620 PRINT "MOMENT OF INERTIA= ";I
\n1625 PRINT "RADIUS OF GYRATION=";K
\n1630 RETURN
\n2000 CLS
\n2001 PRINT "% % % % % % % % BEAM LOAD TABLE % % % % % % % "
\n2002 LET X=0
\n2003 LET W=0
\n2004 LET L=0
\n2005 PRINT
\n2006 PRINT "WWWWWWWWW"
\n2007 PRINT "\:'\''\''\''\''\''\''\''\': 1 SUPPORTED BOTH ENDS"
\n2008 PRINT "\: \ : UNIFORM LOAD"
\n2009 GOSUB 2070
\n2010 PRINT TAB 4;"W"
\n2012 PRINT "\:'\''\''\''\''\''\''\''\': 2 SUPPORTED BOTH ENDS"
\n2014 PRINT "\: \ : LOAD AT CENTER"
\n2015 GOSUB 2070
\n2016 PRINT " W"
\n2018 PRINT "\:'\''\''\''\''\''\''\''\': 3 SUPPORTED BOTH ENDS"
\n2020 PRINT "\: \ : LOAD OFF CENTER"
\n2021 PRINT
\n2022 GOSUB 2070
\n2023 PRINT "% % WWWWWWW 4 FIXED ONE END"
\n2024 PRINT "% % \''\''\''\''\''\''\'' UNIFORM LOAD"
\n2026 PRINT "\''\''"
\n2027 GOSUB 2070
\n2028 PRINT "% % W 5 FIXED ONE END"
\n2030 PRINT "% % \''\''\''\''\''\''\'' CONCENTRATED LOAD"
\n2032 PRINT "\''\''"
\n2033 GOSUB 2070
\n2034 PRINT "% % WWWWW% % 6 FIXED BOTH ENDS"
\n2036 PRINT "% % \''\''\''\''\''% % UNIFORM LOAD"
\n2038 PRINT "\''\'' \''\''"
\n2039 GOSUB 2070
\n2040 PRINT " **ENTER APPROPRIATE CODE**"
\n2045 INPUT X
\n2050 CLS
\n2055 GOTO 2000+(X*100)
\n2060 STOP
\n2070 IF X>0 THEN GOTO 2020+(X*100)
\n2075 RETURN
\n2080 STOP
\n2100 LET X=1
\n2110 GOTO 2006
\n2120 PRINT
\n2130 GOSUB 3000
\n2140 LET S2=-(W*L)/(8*Z)
\n2150 LET U=(5*(W*(L**3)))/(384*P*I)
\n2160 GOSUB 3500
\n2170 STOP
\n2200 LET X=2
\n2210 GOTO 2010
\n2220 PRINT
\n2230 GOSUB 3000
\n2240 LET S2=(W*L)/(4*Z)
\n2250 LET U=(W*(L**3))/(48*P*I)
\n2260 GOTO 3500
\n2270 STOP
\n2300 LET X=3
\n2310 GOTO 2016
\n2320 PRINT
\n2330 GOSUB 3000
\n2340 LET S2=(W*(X1*(L-X1)))/(Z*L)
\n2345 LET V=SQR (((I/3)+(2*X1))/(3*(L-X1)))*(L-X1)
\n2350 LET U=(W*X1*(V**3))/(3*P*I*L)
\n2360 GOTO 3500
\n2370 STOP
\n2400 LET X=4
\n2410 GOTO 2023
\n2420 PRINT
\n2430 GOSUB 3000
\n2440 LET S2=(W*L)/(2*Z)
\n2450 LET U=(W*(L**3))/(8*P*I)
\n2460 GOTO 3500
\n2470 STOP
\n2500 LET X=5
\n2510 GOTO 2028
\n2520 PRINT
\n2530 GOSUB 3000
\n2540 LET S2=(W*L)/Z
\n2550 LET U=(W*(L**3))/(3*P*I)
\n2560 GOTO 3500
\n2570 STOP
\n2600 LET X=6
\n2610 GOTO 2034
\n2620 PRINT
\n2630 GOSUB 3000
\n2640 LET S2=(W*L)/(12*Z)
\n2650 LET U=(W*(L**3))/(384*P*I)
\n2660 GOTO 3500
\n2670 STOP
\n3000 PRINT "W (LOAD IN LS.)=";
\n3005 IF W>0 THEN GOTO 3020
\n3010 INPUT W
\n3020 PRINT W
\n3030 PRINT "L (BEAM LENGTH-IN.)=";
\n3035 IF L>0 THEN GOTO 3050
\n3040 INPUT L
\n3050 PRINT L
\n3060 IF X<>3 THEN GOTO 3100
\n3070 PRINT "X (DIST-W TO NEAR SUPP)=";
\n3080 INPUT X1
\n3090 PRINT X1
\n3100 RETURN
\n3500 PRINT
\n3502 PRINT "LOAD=";W*L;" IN.LBS."
\n3503 PRINT "SECTION=";D;" X ";B;" X ";T
\n3504 PRINT "MATL. STRENGTH =";S;" PSI"
\n3505 PRINT "STRESS (CRIT.PT.)=";INT S2;" PSI"
\n3510 PRINT "DEFL. (CRIT. PT.)=";(INT (U*1E6))/1E6;" IN."
\n3520 PRINT
\n3525 IF ABS S2<S THEN GOTO 3650
\n3530 PRINT
\n3600 FOR N=1 TO 10
\n3605 PRINT AT 14,8;" "
\n3608 FOR J=1 TO 3
\n3610 NEXT J
\n3615 PRINT AT 14,8;"% %O%V%E%R% %S%T%R%E%S%S%E%D% "
\n3620 FOR J=1 TO 6
\n3625 NEXT J
\n3630 NEXT N
\n3650 GOSUB 1600
\n3655 PRINT AT 20,5;"ENTER 5 FOR COPY"
\n3660 GOTO 1500
\n3800 COPY
\n3810 GOTO 1500
\n9900 CLS
\n9905 CLEAR
\n9910 PRINT AT 11,9;"START RECORDER"
\n9920 PRINT AT 13,14;"PRESS ENTER"
\n9930 INPUT Q$
\n9940 SAVE "STROMA%T"
\n9950 CLS
\n9960 RUN
\n9999 STOP