Checking

  10 LET U=0
  20 LET V=0
  30 LET D=0
  40 LET N=0
  50 LET B=0
  60 LET AM=0
  70 LET F=0
  80 DIM I(80)
  90 LET J=0
 100 DIM D$(25,8)
 110 DIM E(80)
 120 DIM W$(80,25)
 130 DIM Q$(80,8)
 140 DIM R(80)
 150 DIM W(25)
 160 DIM I$(80,25)
 170 LET IN=0
 180 DIM P(80)
 190 LET CN=0
 200 LET AM=0
 210 LET INT=0
 220 LET SC=0
 230 LET SCT=0
 240 CLS 
 250 PRINT AT 2,8; "ZX81/TIMEX 1000"
 260 PRINT AT 3,11;"CHECKING"
 270 PRINT AT 4,14;"BY"
 280 PRINT AT 5,4;"HEATH COMPUTER SERVICES"
 290 PRINT AT 6,7;"950 EAST 52 SOUTH"
 300 PRINT AT 7,9;"GREENTOWN IN."
 310 PRINT AT 8,12;"46936"
 320 PRINT AT 10,9;"COPYRIGHT 1982"
 330 PRINT AT 12,6;"PRESS <ENTER> TO RUN"
 340 INPUT S$
 350 CLS 
 360 PRINT AT 2,6;"DO YOU WANT TO--"
 370 PRINT AT 4,3;"(1)ENTER DEPOSITS"
 380 PRINT AT 5,3;"(2)LOOK AT DEPOSITS"
 390 PRINT AT 6,3;"(3)ENTER CHECKS"
 400 PRINT AT 7,3;"(4)LIST ACCOUNTS"
 410 PRINT AT 8,3;"(5)LIST CHECKS"
 420 PRINT AT 9,3;"(6)LOOK AT BALANCE"
 430 PRINT AT 10,3;"(7)SAVE ON TAPE"
 440 PRINT AT 11,3;"(8)SEARCH FOR A CHECK"
 450 PRINT AT 12,3;"(9)ENTER INTEREST AND              SERVICE CHARGES"
 460 PRINT AT 16,5;"PRESS NO. 1-9"
 470 LET M$=INKEY$
 480 IF M$="" THEN GOTO 0470
 490 IF M$="1" THEN GOTO 0590
 500 IF M$="2" THEN GOTO 0720
 510 IF M$="3" THEN GOTO 1270
 520 IF M$="4" THEN GOTO 0950
 530 IF M$="5" THEN GOTO 1800
 540 IF M$="6" THEN GOTO 3280
 550 IF M$="7" THEN GOTO 2170
 560 IF M$="8" THEN GOTO 2280
 570 IF M$="9" THEN GOTO 3020
 580 IF M$>"9" THEN GOTO 0350
 590 CLS 
 600 LET N=N+1
 610 PRINT 
 620 PRINT "PRESS <ENTER> WHEN FINISHED."
 630 PRINT "ENTER DATE ?/?/?"
 640 INPUT G$
 650 IF G$="" THEN LET N=N-1
 660 IF G$="" THEN GOTO 0350
 670 LET D$(N)=G$
 680 PRINT "ENTER AMOUNT OF DEPOSIT"
 690 INPUT W(N)
 700 LET V=V+W(N)
 710 GOTO 0590
 720 CLS 
 730 PRINT 
 740 PRINT "PRESS (P) TO PRINT (L) TO LIST"
 750 LET P$=INKEY$
 760 IF P$="" THEN GOTO 0750
 770 CLS 
 780 LET X=25
 790 IF P$="P" THEN LPRINT "DATE";,"AMOUNT"
 800 FOR Y=1 TO X-1 STEP 20
 810 PRINT "DATE";,"AMOUNT"
 820 FOR Z=Y TO Y+19
 830 IF P$="P" AND D$(Z)="        " THEN GOTO 0350
 840 IF Z=26 THEN GOTO 0880
 850 PRINT D$(Z),"$";W(Z)
 860 IF P$="P" THEN LPRINT D$(Z),"$";W(Z)
 870 NEXT Z
 880 PRINT " PRESS (L) TO LIST (M) FOR MENU."
 890 LET C$=INKEY$
 900 IF C$="" THEN GOTO 0890
 910 IF C$="M" THEN GOTO 0350
 920 CLS 
 930 NEXT Y
 940 GOTO 0350
 950 CLS 
 960 PRINT AT 9,0;"PRESS (P) TO PRINT (L) TO LIST"
 970 LET P$=INKEY$
 980 IF P$="" THEN GOTO 0970
 990 IF P$="L" THEN GOTO 1020
\n1000 IF P$="P" THEN GOTO 1020
\n1010 GOTO 0970
\n1020 FOR O=1 TO 80 STEP 9
\n1030 CLS 
\n1040 PRINT 
\n1050 PRINT "ACCOUNT";TAB (23);"AMOUNT"
\n1060 IF P$="L" THEN GOTO 1100
\n1070 LPRINT 
\n1080 LPRINT "ACCOUNT";TAB (23);"AMOUNT"
\n1090 LPRINT 
\n1100 FOR Q=O TO O+8
\n1110 IF P$="L" THEN GOTO 1150
\n1120 IF I$(Q)="                         " THEN GOTO 0350
\n1130 LPRINT I$(Q)
\n1140 LPRINT TAB (22);"$";I(Q)
\n1150 PRINT I$(Q)
\n1160 PRINT TAB (22);"$";I(Q)
\n1170 IF Q=80 THEN GOTO 1200
\n1180 NEXT Q
\n1190 IF P$="P" THEN GOTO 1240
\n1200 PRINT "PRESS (L) TO LIST (M) FOR MENU."
\n1210 LET C$=INKEY$
\n1220 IF C$="" THEN GOTO 1210
\n1230 IF C$="M" THEN GOTO 0350
\n1240 CLS 
\n1250 NEXT O
\n1260 GOTO 0350
\n1270 CLS 
\n1280 PRINT AT 14,1;"ACCOUNT THE SAME PRESS ENTER."
\n1290 PRINT "ENTER ACCOUNT NAME."
\n1300 INPUT K$
\n1310 PRINT " ENTER (0) WHEN FINISHED."
\n1320 PRINT "ENTER CHECK NO."
\n1330 INPUT X
\n1340 IF X=0 THEN GOTO 0350
\n1350 PRINT "ENTER DATE ?/?/?"
\n1360 INPUT L$
\n1370 IF L$="" THEN GOTO 1350
\n1380 IF K$<>"" THEN GOTO 1410
\n1390 IF F=1 THEN LET K$=I$(J)
\n1400 IF K$="" THEN LET K$=I$(D)
\n1410 PRINT "AMOUNT OF CHECK?"
\n1420 LET K=LEN K$
\n1430 INPUT L
\n1440 CLS 
\n1450 PRINT 
\n1460 PRINT "DATE ";L$
\n1470 PRINT 
\n1480 PRINT AT 2,2;"CHECK NUMBER ";X
\n1490 PRINT 
\n1500 PRINT "TO ";K$
\n1510 PRINT 
\n1520 PRINT "CHECK";TAB (12);"TOTAL"
\n1530 PRINT "AMOUNT";TAB (12);"CHECKS";TAB (23);"BALANCE"
\n1540 LET U=U+L
\n1550 LET U=U+.005
\n1560 LET U=INT (U*100)/100
\n1570 PRINT "$";L;TAB (12);"$";U;TAB (23);"$";V-U
\n1580 LET B=B+1
\n1590 LET W$(B)=K$
\n1600 LET R(B)=L
\n1610 LET E(B)=X
\n1620 LET Q$(B)=L$
\n1630 FOR J=1 TO 80
\n1640 IF J>B THEN GOTO 1680
\n1650 LET A$=I$(J)(1 TO K)
\n1660 IF K$=A$ THEN GOTO 1760
\n1670 NEXT J
\n1680 LET D=D+1
\n1690 IF D=81 THEN GOTO 0350
\n1700 REM I$=ACCOUNT,P=CHECK NO.,I=AMOUNT
\n1710 LET I$(D)=K$
\n1720 LET P(D)=X
\n1730 LET I(D)=L
\n1740 LET F=0
\n1750 GOTO 1790
\n1760 LET I(J)=I(J)+L
\n1770 LET H=J
\n1780 LET F=1
\n1790 GOTO 1280
\n1800 CLS 
\n1810 PRINT AT 9,0;"PRESS (P) TO PRINT (L) TO LIST"
\n1820 LET P$=INKEY$
\n1830 IF P$="" THEN GOTO 1820
\n1840 IF P$="L" THEN GOTO 1870
\n1850 IF P$="P" THEN GOTO 1870
\n1860 GOTO 1820
\n1870 FOR Y=1 TO 80 STEP 9
\n1880 CLS 
\n1890 PRINT 
\n1900 PRINT " DATE      NO.       AMOUNT"
\n1910 PRINT 
\n1920 IF P$="L" THEN GOTO 1960
\n1930 LPRINT 
\n1940 LPRINT " DATE      NO.       AMOUNT"
\n1950 LPRINT 
\n1960 FOR Z=Y TO Y+8
\n1970 IF Z>80 THEN GOTO 2130
\n1980 IF P$="L" THEN GOTO 2030
\n1990 IF W$(Z)="                         " THEN GOTO 0350
\n2000 LPRINT W$(Z)
\n2010 LPRINT Q$(Z);TAB (11);E(Z);TAB (21);"$";R(Z)
\n2020 GOTO 2050
\n2030 PRINT W$(Z)
\n2040 PRINT Q$(Z);TAB (11);E(Z);TAB (21);"$";R(Z)
\n2050 NEXT Z
\n2060 IF P$="P" THEN GOTO 2110
\n2070 PRINT "PRESS (L) TO LIST (M) FOR MENU"
\n2080 LET C$=INKEY$
\n2090 IF C$="" THEN GOTO 2080
\n2100 IF C$="M" THEN GOTO 0350
\n2110 CLS 
\n2120 NEXT Y
\n2130 PRINT 
\n2140 PRINT "PRESS <ENTER> FOR MENU"
\n2150 INPUT C$
\n2160 GOTO 0350
\n2170 CLS 
\n2180 PRINT 
\n2190 PRINT "TYPE MONTH"
\n2200 PRINT 
\n2210 PRINT "PRESS PLAY AND RECORD ON THE"
\n2220 PRINT "RECORDER"
\n2230 PRINT 
\n2240 PRINT "PRESS (ENTER) WHEN READY" 
\n2250 INPUT T$
\n2260 SAVE T$
\n2270 GOTO 0240
\n2280 CLS 
\n2290 LET K=1
\n2300 PRINT 
\n2310 LET X$=""
\n2320 LET Y$=""
\n2330 PRINT "   PRESS:"
\n2340 PRINT 
\n2350 PRINT "(C) TO SEARCH BY CHECK NUMBER"
\n2360 PRINT "(D) TO SEARCH BY DATE"
\n2370 PRINT "(N) TO SEARCH BY NAME"
\n2380 PRINT "(A) TO SEARCH BY AMOUNT"
\n2390 PRINT 
\n2400 LET C$=INKEY$
\n2410 IF C$="" THEN GOTO 2400
\n2420 IF C$="C" THEN GOTO 2470
\n2430 IF C$="D" THEN GOTO 2510
\n2440 IF C$="N" THEN GOTO 2560
\n2450 IF C$="A" THEN GOTO 2610
\n2460 GOTO 2400
\n2470 PRINT "ENTER CHECK NUMBER"
\n2480 INPUT CN
\n2490 IF CN=0 THEN GOTO 2280
\n2500 GOTO 2630
\n2510 PRINT "ENTER DATE"
\n2520 INPUT X$
\n2530 IF X$="" THEN GOTO 2280
\n2540 LET K=LEN X$
\n2550 GOTO 2630
\n2560 PRINT "ENTER NAME"
\n2570 INPUT Y$
\n2580 IF Y$="" THEN GOTO 2280
\n2590 LET K=LEN Y$
\n2600 GOTO 2630
\n2610 PRINT "ENTER AMOUNT"
\n2620 INPUT AM
\n2630 CLS 
\n2640 PRINT 
\n2650 PRINT 
\n2660 FOR J=1 TO 80
\n2670 IF J=80 THEN GOTO 2780
\n2680 IF E(J)=0 THEN NEXT J
\n2690 IF C$="D" THEN LET V$=Q$(J)(1 TO K)
\n2700 IF C$="N" THEN LET V$=W$(J)(1 TO K)
\n2710 IF E(J)=CN THEN GOTO 2860
\n2720 IF V$=Y$ THEN GOTO 2860
\n2730 IF V$=X$ THEN GOTO 2860
\n2740 IF R(J)=AM THEN GOTO 2860
\n2750 NEXT J
\n2760 CLS 
\n2770 PRINT 
\n2780 PRINT "CHECK NOT LISTED"
\n2790 PRINT 
\n2800 PRINT "PRESS (M) FOR MENU (S) TO SEARCH"
\n2810 LET C$=INKEY$
\n2820 IF C$="" THEN GOTO 2810
\n2830 IF C$="M" THEN GOTO 0350
\n2840 IF C$="S" THEN GOTO 2280
\n2850 GOTO 2810
\n2860 CLS 
\n2870 PRINT 
\n2880 PRINT "CHECK NO. ";E(J)
\n2890 PRINT "DATE ";Q$(J)
\n2900 PRINT "TO ";W$(J)
\n2910 PRINT "AMOUNT $";R(J)
\n2920 PRINT 
\n2930 LET CN=0
\n2940 LET Y$=""
\n2950 LET X$=""
\n2960 LET AM=0
\n2970 PRINT "PRESS (M) FOR MENU (S) TO SEARCH"
\n2980 LET C$=INKEY$
\n2990 IF C$="" THEN GOTO 2980
\n3000 IF C$="M" THEN GOTO 0350
\n3010 IF C$="S" THEN GOTO 2280
\n3020 CLS 
\n3030 PRINT 
\n3040 PRINT "PRESS -"
\n3050 PRINT 
\n3060 PRINT 
\n3070 PRINT "(S) TO ENTER SERVICE CHARGE"
\n3080 PRINT "(I) TO ENTER INTEREST"
\n3090 PRINT "(M) FOR MENU"
\n3100 PRINT 
\n3110 LET C$=INKEY$
\n3120 IF C$="" THEN GOTO 3110
\n3130 IF C$="S" THEN GOTO 3180
\n3140 IF C$="I" THEN GOTO 3230
\n3150 IF C$="M" THEN GOTO 0350
\n3160 GOTO 3110
\n3170 PRINT 
\n3180 PRINT "ENTER SERVICE CHARGE"
\n3190 INPUT SC
\n3200 LET V=V-SC
\n3210 LET SCT=SCT+SC
\n3220 GOTO 3020
\n3230 PRINT "ENTER INTEREST"
\n3240 INPUT IN
\n3250 LET V=V+IN
\n3260 LET INT=INT+IN
\n3270 GOTO 3020
\n3280 CLS 
\n3290 PRINT AT 8,2;"TOTAL CHECKS";TAB (20);"BALANCE"
\n3300 PRINT TAB (5);"$";U;TAB (21);"$";V-U
\n3310 PRINT AT 14,0;"SERVICE CHARGES     INTEREST"
\n3320 PRINT TAB (5);"$";SCT;TAB (21);"$";INT
\n3330 PRINT 
\n3340 PRINT 
\n3350 PRINT 
\n3360 PRINT "PRESS <ENTER> FOR MENU"
\n3370 INPUT C$
\n3380 GOTO 0350
\n3500 SAVE "CHECKIN%G"
\n3510 GOTO 0010