Tax Shelter Time Bomb

Practically all tax shelters have a built-in time bomb. Most of those that do not are real tax shelters with a real loss of capital.

Let me describe a seemingly perfect tax shelter. I own a swampy piece of land that was under water for at least two months each year. I valued the land at $1,000 and would have sold it for less.

John, a friendly site locator for a major gasoline company, suggested that I build a gasoline station to their specifications and lease it to them. The offer was rather generous: they would pay $100 per month as land rental; arrange zoning changes, get all permits, contract to fill the swamp, supervise building construction and arrange for a mortgage. The mortgage would be large enough to pay for everything including a $20,000 “fee” for legal service and construction supervision. The total rental was set at exactly the monthly mortgage payment plus the land rent plus a variable amount equal to the real estate taxes. The gasoline company was to be responsible for all maintenance and insurance, including my liability insurance.

It was a perfect situation. I received an annual return equal to 120% of my asking price for the land, the gasoline company real estate department showed an income of $20,000; and I had a tax deduction of about $2,500 for the first year. Thirty years in the future I would own a gasoline station with a potential monthly rental in excess of the land value.

Wonderful! In thirty years I would have a fully funded generous retirement plan plus all those nice tax deductions along the way. Remember all this took place in 1953 when $1,000 per month was a pretty decent income and there were no IRA or KEOUGH plans available at the neighborhood bank.

But wait a minute, what happens when the monthly principal payment on the mortgage exceeds the depreciation? At that point a taxable income is generated with no funds available to pay the tax. When does this happen? I wrote down the method of calculating a mortgage amortization (algorithm, fore-runner to a program): P-(R-iP)=P’. What I was looking for was the month in which (R-iP)=Dep, so I labelled the columns on my accountants pad P, ΔP. My LAX Monroe Calculator (mechanical) was called into service, and I sat in front of it for a half hour totally mesmerized while the discs whirled and clattered. I wrote the numbers in the P and ΔP columns. As I dozed off, I realized that what I was struggling to find was really ΔP: the first differential of the compound interest equation.

            (1+i)^n -1
P = R   ---------------
           i(1+i)^n

I put away the Monroe LAX, picked up my K & E Slide Rule, set the first differential equal to depreciation and 30 seconds later had the answer: 17 years, 11 months from inception of the mortgage, a small taxable income would be generated. The amount of taxable income would increase until the last year of the mortgage when it would be about $5,100.00.

Armed with this knowledge I was able to plan properly so I was not hurt by the mathematics and income tax.

The problem can be solved for n by a brute force trial and error mortgage table comparison process which is long and unwieldy (90 seconds). It can be shortened by using this program which will run in a little over one second.

The formulas used on the Sinclair ZX81 are:

      [10/(1-0.6B²)] + 8B
                       --
                       9
N = ----------------------
            i - i²/2

           (R/D [i/(i+i²)]) -1
Where B = ---------------------
           (R/D [i/(i+i²)]) +1

D = Monthly Depreciation
R = Monthly Payment
i = Monthly Interest, Decimal
N = Number of Months

To bring the story up to date, last week my friendly site locator telephoned from Florida where he lives in semi-retirement. “David,” he said excitedly, “Do I have a tax shelter for you! There’s this shopping center and apartment house available . . .”

Line Notes:

20-30: Input instruction, starting date of mortgage,

40-60: Error trap for incorrect month and year.

70-230: Input instructions, prints.

240-280: Calculation of monthly mortgage payment.

290-340: Calculation of first taxable income, months before end of mortgage.

350-380: Calculation of taxable income, last year of mortgage.

390-470: Conversion of months before end of mortgage to month, year.

480-550: Print result of calculation.

Use RUN to initiate program. To exit use STOP. The running time is 2 seconds.

An answer indicating taxable income before beginning date of mortgage means that there is no tax shelter.

Error statement A/320 means that no taxable income occurs during term of the mortgage.

List of Variables:

Y: Beginning date, (MO. YEAR) of mortgage

T: Term of mortgage, months

I: Percent interest, annual

P: Principal amount of original mortgage

D: Depreciation, annual

A: Intermediate variable, partial solution compound interest mortgage payment equation.

R: Monthly mortgage payment

C,B,E,F,G: Intermediate partial solutions

N: Solution number of months to end of mortgage

Q: Intermediate variable, partial solutions compound interest mortgage equation, last year

L: Principal payment less annual depreciation for last year of mortgage

H: Years until “N” (partial year shown as decimal)

M1: Conversion of decimal year (H) to month

M2: Sum of beginning month and ending month

M3: Correction if M2 is greater than 12 (December)

Z1: Beginning year

Z2: Sum of beginning year and years until “N”

Z3: Correction if M2 is greater than 12 (December)

 10 REM "D=R", PROGRAM TO CALCU
LATE WHEN TAXABLE INCOME OCCURS.
 D. LIPMAN 5/30/83
 20 PRINT " INPUT STARTING DATE
 OF MORGAGE (FORMAT=MO.YEAR): ";
"
 30 INPUT Y
 40 IF Y<1 OR Y>12 THEN GOTO 20
 50 LET YY=(Y-INT Y)*10000
 60 IF YY<1900 OR YY>2100 THEN
GOTO 20
 70 PRINT Y
 80 PRINT
 90 PRINT " INPUT TERM OF MTGE,
 MONTHS: ";
100 INPUT T
110 PRINT T
120 PRINT
130 PRINT " INPUT ANNUAL INTERE
ST RATE: ";
140 INPUT I
150 PRINT I
160 PRINT
170 PRINT " INPUT AMOUNT OF MTG
: $";
180 INPUT P
190 PRINT P
200 PRINT
210 PRINT " INPUT ANNUAL STRAIG
HT LINE DEPRECIATION: $";
220 INPUT D
230 PRINT D
240 FAST
250 LET I=I/1200
260 LET D=D/12
270 LET A=(1+I)**T
280 LET R=P*I/(1-(1/A))
290 LET C=R/D
300 LET E=I/(I+I*I)
310 LET B=(C*E-1)/(C*E+1)
320 LET F=(10/(1-0.6*B**2)+8)*B
/9
330 LET G=I-(I**2/2)
340 LET N=F/G
350 LET Q=1/(1+I)**12
360 LET L=R*(1-Q)/I
370 LET L=INT (L*100)/100
380 LET L=L-D*12
390 LET H=(T-N)/12
400 LET Z=(Y-INT Y)*10000
410 LET Z=Z+INT H
420 LET M=(H-INT H)*12
430 LET M=M+INT Y+1
440 IF M>=13 THEN GOTO 460
450 GOTO 480
460 LET Z=Z+1
470 LET M=M-12
480 PRINT
490 SLOW
500 PRINT "A  SMALL  TAXABLE  I
NCOME  WILL OCCUR ";
510 PRINT "IN  THE  ";INT M;" M
ONTH OF ";Z;","
520 PRINT INT N;" MONTHS BEFORE
 END OF MORTGAGE."
530 PRINT "TAXABLE INCOME WILL
INCREASE"
540 PRINT "UNTIL IT  REACHES  $
";L;" IN  THE";
550 PRINT " LAST YEAR OF THE MO
RTGAGE"

An expanded program that calculates all of the IRS acceptable depreciation schedules is available on tape @ $9.95 from the author requires 16K RAM.