Seven-Bit ASCII Text Filter for the TS-2068 with LarKen disk I/O

Author(s): David Solly
Publication: ZXir QLive Alive!
Pub Details: ZXir QLive Alive! v10 n2 (Volume 10, Issue 2)
Date: Summer 2000
Pages: 9-10

Occasionally, after downloading a text file from an electronic bulletin board (BBS), or, converting HiSoft® PASCAL source code files into an LKDOS file, the file may fail to write to the screen, print, or load into M-Script[1]. This kind of problem is most often caused by rogue bytes which enter the text through line noise, the process of conversion, or perhaps from the operating system of another word processor, and interfere with the Sinclair operating system. The following Pascal program, once compiled, will quickly load an LKDOS file or an ASCII text file, remove from the file any rogue bytes encountered, compact the file, and provide the user with option of saving to disk by overwriting the corrupted file or saving under a separate name. The PASCAL source code listed below was treated in this manner.

LKDOS Files from Sinclair BASIC listings

A Sinclair BASIC listing may also be converted into an LKDOS file, however, the resulting file may still fail to load into M-Script or print on a full-sized printer. This is because in addition to the possibility of having picked up a few rogue bytes during conversion the listing may contain Sinclair block graphics and user defined graphics. These graphic characters pose a special problem because they fall neither within the range of 7-bit ASCII nor conform to any 8-bit ASCII standard. It is necessary, therefore, to bring all Sinclair graphics into the range of 7-bit ASCII before applying the filtering process by using this additional piece of code.

1200  CONST
1205 OFFSET = 79; (* Sinclair graphic to 7-bit ASCII *)
1400 IF (LETTER IN [128..164]) THEN
1410 POKE((START + COUNT),(LETTER - OFFSET));

The final result of this piece of coding is to change all user defined graphics from UDG ‘A’ through to ‘U’ into normal ASCII ‘A’ to ‘U’ and swop all the block graphics for a character between ‘1’ and ‘@’.

Seven Bit ASCII Filter

Program By David Solly

 100 (*$L-*) (* COMPILE OPTION, P. 35 IN MANUAL *)
110
120 PROGRAM ASCIIFILTER;
122
123
125 (* STORAGE LOCATIONS FOR LKDOS PARAMETERS *)
130 CONST
140 PROGNM = 23300;
150 PROGBGN = 23311;
160 PROGLN = 23313;
170
180 START = #A028; (* TEXT FILE LOAD BUFFER *)
190 NEWSTART = #9C40; (* TEXT FILE COPY BUFFER *)
200
210
220 VAR
230
240 ANS : CHAR;
250 PRINTABLE : SET OF CHAR;
260 NEWLN, BYTES : INTEGER;
270
280
290 PROCEDURE DOUT; (* INVOKES LKDOS WRITE *)
300 BEGIN
310 INLINE (#F3, #CD, #62, #00, #21, #04, #5B, #11,
320 #22, #20, #01, #09, #00, #7E, #FE, #00,
330 #20, #02, #36, #20, #ED, #A0, #78, #B1,
340 #20, #F3, #3E, #0B, #32, #02, #20, #CD,
350 #CC, #00, #2A, #0F, #5B, #22, #33, #20,
360 #2A, #11, #5B, #22, #31, #20, #CD, #CF,
370 #00, #3A, #64, #00, #FB);
380 END;
390
400
410 PROCEDURE DIN; (* INVOKES LKDOS READ *)
420 BEGIN
430 INLINE (#F3, #CD, #62, #00, #21, #04, #5B, #11,
440 #22, #20, #01, #09, #00, #7E, #FE, #00,
450 #20, #02, #36, #20, #ED, #A0, #78, #B1,
460 #20, #F3, #3E, #0B, #32, #02, #20, #CD,
470 #C6, #00, #2A, #0F, #5B, #22, #33, #20,
480 #2A, #11, #5B, #22, #31, #20, #CD, #C9,
490 #00, #3A, #64, #00, #FB);
500 END;
510
520
530 PROCEDURE SPOUT (C : CHAR); (* PASSES CODES TO THE ROM *)
540 BEGIN
550 INLINE (#FD, #21, #3A, #5C, #DD, #7E,
560 2, #D7)
570 END;
580
590
600 PROCEDURE AT (X, Y : INTEGER); (* EMULATES BASIC 'AT' *)
610 BEGIN
620 SPOUT (CHR(22));
630 SPOUT (CHR(X));
640 SPOUT (CHR(Y));
650 END;
660
670 PROCEDURE CLS; (* EMULATES BASIC COMMAND *)
680 BEGIN
690 PAGE;
700 SPOUT (CHR(22));
710 SPOUT (CHR(0));
720 SPOUT (CHR(0));
730 END;
740
750
760 PROCEDURE GETFILE;
770
780 VAR
790 FILENAME : ARRAY [1..9] OF CHAR;
800
810 BEGIN
820 WRITELN;
830 WRITELN ('FILE TO RETRIEVE FROM DISK? ');
840 WRITELN;
850 READLN;
860 READ(FILENAME);
870 POKE(PROGNM,FILENAME);
880 WRITELN('HOW MANY BYTE IN FILE? ');
890 WRITELN;
900 READLN(BYTES);
910 POKE(PROGLN,BYTES);
920 POKE(PROGBGN,START);
930 DIN;
940
950 END; (* GETFILE *)
960
970
980 PROCEDURE STOREFILE(NEWLN : INTEGER);
990
1000 VAR
1010
1020 FILENAME : ARRAY [1..9] OF CHAR;
1030
1040 BEGIN
1050
1060 WRITELN;
1070 WRITELN;
1080 WRITELN('NEW NAME FOR FILE? ');
1090 WRITELN;
1100 READLN;
1110 READ(FILENAME);
1120 POKE(PROGNM,FILENAME);
1130 POKE(PROGBGN,NEWSTART);
1140 POKE(PROGLN, NEWLN);
1150 DOUT;
1160
1170 END; (* STOREFILE *)
1180
1190 PROCEDURE FILTER(VAR NEWLN : INTEGER);
1200
1210 VAR
1220
1230 LETTER, COUNTER, SCRATCHED : INTEGER;
1240
1250 BEGIN
1260
1270 PRINTABLE := [' '..'}'];
1280 COUNTER := 0;
1290 NEWLN := 0;
1300 SCRATCHED := 0;
1310
1320 CLS; AT(11,3);
1330 WRITE('WORKING! KEEP YER SHIRT ON!');
1340
1350
1360 REPEAT
1370
1380 LETTER := PEEK((START + COUNTER),INTEGER);
1390
1400 (* ENTER HERE ANY SPECIAL ROUTINE *)
1410 (* REQUIRED TO HANDLE SINCLAIR *)
1420 (* GRAPHICS OR 8 BIT CHARS *)
1425
1430 IF (CHR(LETTER) IN PRINTABLE) OR
1440 (LETTER IN [13, 27]) THEN
1450 POKE((NEWSTART + NEWLN),LETTER)
1460 ELSE
1470
1480 SCRATCHED := SCRATCHED +1;
1490
1500 COUNTER := COUNTER + 1;
1510 NEWLN := COUNTER - SCRATCHED;
1520
1530 UNTIL COUNTER = BYTES;
1540
1550
1560 CLS; AT(11,12);
1570 WRITE('FINISHED!');
1580 AT(15,0);
1590 WRITELN('NO. OF LETTERS REMOVED: ', SCRATCHED);
1600 WRITELN;
1610 WRITELN('NO. OF LETTERS COPIED: ', NEWLN);
1620 WRITELN;
1630 WRITELN('ORIGINAL LETTER COUNT: ', BYTES);
1640 END; (* FILTER *)
1650
1660
1670 BEGIN (* MAIN PROGRAM *)
1680
1690 REPEAT
1700
1710 CLS; AT(5,0);
1720 WRITELN('SEVEN BIT ASCII FILTER');
1730 AT(7,0);
1740 WRITELN('THIS PROGRAM IS FOR REMOVING');
1750 WRITELN('STRAY CHARACTERS FROM AN ASCII');
1760 WRITELN('FILE WHICH MIGHT INTERFERE');
1770 WRITELN('IN THE NORMAL OPERATION OF A');
1780 WRITELN('WORD PROCESSOR.');
1790
1800 GETFILE;
1810 FILTER(NEWLN);
1820 STOREFILE(NEWLN);
1830 WRITELN;
1840 WRITE('ANOTHER FILE? ');
1850 READLN;
1860 READ(ANS);
1870
1880 UNTIL (ANS IN ['N', 'n']);
1890
1900 WRITELN;
1910 WRITELN('TYPE RUN TO RESTART PROGRAM');
1920
1930 END.

[1] LKDOS is able to convert Sinclair BASIC listings and some other types of tokenized texts into straight ASCII text and save them to disk as a sequential file. For this article they will be called LKDOS files.