The Qualifier

    0 
    1 REM QUALIFIER (HOMES)
    2 REM RESET 1987 BYTE POWER
    3 REM BY K. BOISVERT
    4 
   20 GO SUB 2000
   30 PRINT AT 5,0;"Maximum down payment:";
   40 INPUT "Max:";down: IF down<0 THEN GO TO 40
   41 PRINT "$";down
   60 PRINT AT 7,0;"Max. monthly payment:";
   70 INPUT "Max:";month: IF month<0 THEN GO TO 70
   71 PRINT "$";month
   80 PRINT AT 9,0;"Interest rate:";
   90 INPUT "Interest:";rate: IF rate<.001 OR rate>100 THEN GO TO 90
   91 PRINT rate;"%"
   95 LET rate=rate/100: PRINT AT 11,0;"In how many years (30 max):";
   96 INPUT "Year(s):";ye
   97 LET ye=INT ye: IF ye<1 OR ye>30 THEN GO TO 96
   98 PRINT ye
  100 LET f1=(1-((1+(rate/12))^-(12*ye)))
  110 LET f2=f1/(rate/12)
  120 LET lamount=month*f2: LET lamount=INT (lamount/100)*100
  140 LET price=lamount+down: LET price=INT ((price+.5)*100/100)
  150 CLS : GO SUB 2000: PRINT AT 5,0;"You can afford homes that are   selling for:";
  155 PRINT INVERSE 1;"$";price
  160 PRINT '"Mortgage of $";lamount
  190 PRINT '"Down payment of $";down
  200 PRINT '"Monthly payments of $";month
  220 PRINT '"For a period of ";ye;" year"+("s" AND ye>1)
  230 PRINT '"At an interest of ";rate*100;"%"
  240 PRINT AT 20,0;"'RUN' TO GO BACK TO PROGRAM"
 1999 STOP 
 2000 PLOT 65,156: DRAW 116,0: DRAW 0,14: DRAW -116,0: DRAW 0,-14
 2001 PLOT 68,158: DRAW 110,0: DRAW 0,10: DRAW -110,0: DRAW 0,-10: PRINT AT 1,9;"The Qualifier"
 2010 RETURN 
 9999 SAVE "QUALIFIER" LINE 1