Source Code
10 REM *** PROGRAM "MAGNIFY12"
20 REM *** UPDATED 1/15/84 PM
30 DIM L$(10): DIM C(2)
40 DIM A$(2,255): DIM D(2)
50 CLS : INK 3
60 PRINT AT 11,4;"NUMBER OF LINES (1 OR 2)?"
70 INPUT LINES: CLS
80 PRINT AT 9,0;"FOR RELIEF STYLE (LIGHT) PRESS 7"
90 PRINT "FOR RELIEF STYLE (DARK) PRESS 9"
100 PRINT AT 13,6;"OTHERWISE, PRESS ENTER"
110 PRINT TAB 11;" TO CONTINUE "
120 INPUT D$
130 IF D$<" " THEN GO TO 180
140 IF D$="7" THEN LET D(2)=8
150 IF D$="9" THEN LET D(2)=10
160 LET D(1)=VAL D$
170 GO TO 410
180 CLS
190 PRINT AT 5,12;"\a\a \b\b \::\::"
200 PRINT TAB 12;"\a\a \b\b \::\::"
210 PRINT AT 8,6;"1 2 3 4"
220 BORDER 6
230 PRINT '''" SELECT BACKGROUND CHARACTER"
240 PRINT 'TAB 8;"ENTER 1, 2, 3 OR 4"
250 PRINT TAB 7;" OR ENTER 5 FOR OTHER"
260 INPUT D(1)
270 PRINT AT 11,0,,: BORDER 5
280 PRINT AT 11,6;"SELECT TEXT CHARACTER"
290 INPUT D(2)
300 IF D(1)=D(2) AND D(1)<>5 THEN GO TO 290
310 CLS
320 IF D(1)<5 AND D(2)<5 THEN GO TO 410
330 IF D(1)<5 THEN GO TO 380
340 PRINT AT 11,PI;"ENTER BACKGROUND CHARACTER"
350 INPUT L$(5,1)
360 CLS
370 IF D(2)<5 THEN GO TO 410
380 PRINT AT 11,6;"ENTER TEXT CHARACTER"
390 INPUT L$(6,1)
400 LET D(2)=6
410 CLS
420 LET LENGTH=0
430 FOR G=1 TO LINES
440 PRINT AT 11,7;"ENTER TEXT - LINE ";G
450 INPUT Y$
460 IF LEN Y$>LENGTH THEN LET LENGTH=LEN Y$
470 CLS
480 LET A$(G)=Y$
490 NEXT G
500 LET L$( TO 4)=" \a\b\::"
510 LET L$(7 TO )="\ '\. \':\:."
520 LET M=4/LINES
530 LET C(1)=7
540 IF LINES=1 THEN LET C(1)=15
550 LET C(2)=23
560 LET ROW=11
570 CLS
580 FOR X=1 TO LENGTH
590 INK 7
600 PRINT AT 20,0;A$(1,X)
610 PRINT AT 21,0;A$(2,X)
620 IF LINES=1 THEN PRINT AT 21,0;A$(1,X)
630 INK 9
640 GO SUB 680
650 CLS
660 NEXT X
670 STOP
680 FOR C=0 TO 7
690 FOR N=1 TO M
700 FOR B=0 TO LINES-1
710 FOR R=0 TO 7
720 LET SWITCH=2
730 IF POINT (C,R+B*8)=0 THEN LET SWITCH=1
740 LET RCOOR=ROW-(M/2*8)+(C*M)+N
750 FOR L=1 TO M
760 LET CCOOR=C(B+1)-(M/2*8)+(R*M)+L
770 IF LINES=1 THEN GO TO 790
780 PRINT AT RCOOR,CCOOR;L$(D(SWITCH),1)
790 LPRINT TAB CCOOR;L$(D(SWITCH),1);
800 NEXT L: NEXT R: NEXT B: NEXT N: NEXT C: RETURN
