Duet Example 2

1 REM                                                        EXAMPLE 2                       WRITTEN BY E & K BOISVERT       ©1986 BYTE POWER                                                MUSIC EVENING SONG BY R SCHUMANN 
    9 REM V1=ADDRESS OF VOICE 1           V2=ADDRESS OF VOICE 2    
   10 LET v1=60000: LET v2=60112
   14 REM FIND FIRST NOTES OF             VOICE 1 & 2               
   15 GO SUB 100: GO SUB 200
   30 REM 255=END OF MUSIC                254=REST (PAUSE)            (MUSIcomp COMPATIBLE DATA)    
   35 IF a1=255 THEN PAUSE 5: STOP 
   39 REM A4 & B4 ARE THE VOLUME          OF VOICE 1 & 2          
   40 LET a4=15: IF a1=254 THEN LET a4=0
   45 LET b4=15: IF b1=254 THEN LET b4=0
   49 REM PLAY NOTES              
   50 SOUND 8,a4;9,b4;7,60;0,a1;1,a2;2,b1;3,b2
   54 REM TEMPO (PAUSE 5)         
   55 PAUSE 5
   59 REM A3 & B3 DURATION OF             NOTE IF EQUAL 0 THEN            FIND NEXT NOTE          
   60 LET a3=a3-1: IF a3=0 THEN GO SUB 100
   65 LET b3=b3-1: IF b3=0 THEN GO SUB 200
   69 REM COMPLETE LOOP             
   70 GO TO 35
  100 REM FIND NOTE OF VOICE 1            AND ADD 3 TO V1                 (NEXT NOTE OF VOICE 1)  
  105 LET a1=PEEK v1: LET a2=PEEK (v1+1): LET a3=PEEK (v1+2): LET v1=v1+3
  109 REM LOWER VOLUME TO                 SEPARATE NOTES                  (NOT 0 FOR SMOOTHER              DELIVERY)              
  110 SOUND 8,13: RETURN 
  200 REM FIND NOTE OF VOICE 2            AND ADD 3 TO V2                 (NEXT NOTE OF VOICE 2)  
  205 LET b1=PEEK v2: LET b2=PEEK (v2+1): LET b3=PEEK (v2+2): LET v2=v2+3
  209 REM LOWER VOLUME TO                 SEPARATE NOTES                  (NOT 0 FOR SMOOTHER              DELIVERY)              
  210 SOUND 9,13: RETURN 
 8999 REM LOAD CODES FOR MUSIC 2  
 9000 LOAD ""CODE 6E4: RUN 
 9999 SAVE "EXAMPLE 2" LINE 9000: SAVE "MUSIC 2"CODE 6E4,224: VERIFY "EXAMPLE 2": VERIFY "MUSIC 2"CODE