This is a two-part educational grammar drill program teaching English capitalization rules to students in grades 4 through 12. Part I covers capitalizing the pronoun “I,” proper names, first words of sentences and quotes, and titles; Part II covers proper names of groups, geographical names, school subjects, and names of days and months. The program uses UDG (User Defined Graphic) characters — 12 of them, mapped to letters A through L — to construct a decorative logo on the loading screen, with pixel data stored in DATA statements and written via POKE USR. Practice modes, a timed test with a minute:second counter, and a test-practice mode are supported, with the timed test protected by a “cap”/”CAP” code entry gate. Scoring tracks right-on-first-try, right-on-second-try, and wrong answers, broken out by rule category, with percentage scores displayed at the end.
Program Analysis
Overall Structure
The listing contains two largely independent programs, each loaded in sequence. The first section (lines 5–130) is a short loader that defines UDGs, draws a title screen, and then executes LOAD "" to chain to a main program. That main program is presented twice in the listing — once as Part I and once as Part II — sharing nearly identical control logic but differing in their DATA content, menu labels, and some scoring parameters.
Program Flow
- Lines 5–66 (loader): Define 12 UDGs (A–L) via POKE USR and DATA, then fall through to line 100.
- Line 100: Draw the logo screen using UDGs and block graphics.
- Lines 110–130: Display title text with FLASH, then chain-load the main program.
- Line 300 / 400: Entry points with ON ERR handlers, branching to the main menu (line 1000) or the error screen subroutine (line 3000).
- Lines 1000–1090: Initialize all scoring variables, draw the decorative border loop, print the menu, and wait for a selection via subroutine 3510.
- Lines 1500–1560: Display the rules screen for the selected category, then fall into the exercise loop.
- Lines 2000–2140: Main exercise loop — shows directions (line 4000), then iterates
Ttimes, reading sentence data, printing it, accepting a keypress answer, and branching to correct (4500) or wrong (6000) handlers. - Lines 2500–2560: Timed test mode with a minute:second display, using PAUSE 60 per tick.
- Lines 3000–3040: Error/interrupt screen displaying a block-graphic “Software Excellence” logo in a randomly chosen color.
- Lines 4500–4580: Correct-answer handler; updates score counters and continues.
- Lines 4990–5150: Score display routines, including per-category breakdowns and percentages.
- Lines 5500–5730: RESTORE logic to position the DATA pointer to the correct rule header for the current category and question index.
- Lines 6000–6080: Wrong-answer handler; in Part II allows one retry before showing the answer.
- Lines 9900–9930: ON ERR chain: resets, pauses, and continues — a soft error recovery loop.
UDG Definition (Loader)
The loader defines 12 UDGs corresponding to the letters A through L. It reads each letter as a string L$, then POKEs 8 bytes of pixel data into USR L$ through USR L$+7. The pixel patterns are diagonal ramps (e.g., 128, 192, 240, 248…) forming wedge or fill shapes, which are assembled in line 100 into a two-color logo graphic using \a through \l escape sequences.
DATA Organization
Exercise DATA is organized by line number in a scheme where the category number multiplied by 10 gives the base DATA line for that category’s rules header, and subsequent numbered lines (e.g., C*10+Z) hold individual questions. Each question record contains: the sentence split across two (Part I) or three (Part II) strings, four row/column pairs for number overlays, and a single character giving the correct answer. This layout allows RESTORE to seek directly to any question by computed line number.
| Section | Part I Base Lines | Part II Base Lines |
|---|---|---|
| Capitalize “I” / Groups | 10–19 | 10–29 |
| Proper Names / Geography | 20–29 | 50–69 |
| First Words / Subjects | 30–39 | 30–39 |
| Titles / Days & Months | 40–54 | 40–44 |
| Test Practice (C=5) | 60–121 | 70–116 |
| Timed Test (C=6) | RESTORE 90 | RESTORE 90 |
Timed Test Implementation
The timed test (option 6) uses a busy-wait loop at line 2550: PAUSE 60 approximates one second, after which INKEY$ is checked. Variables K (minutes) and L (seconds) are incremented manually. Because PAUSE 60 is not precisely one second on all machines and is interrupted by any keypress, the timer is approximate. The display at line 2540 pads a trailing space when L<10 to prevent a stray digit from the previous two-digit value remaining on screen.
Subroutine 3000 — Interrupt/Error Screen
This subroutine is reached via the ON ERR handler at line 400. It picks a random paper color (1–7) with INK 7-RP for contrast, then displays a block-graphic “Software Excellence” logo stored in DATA lines 3100–3120 using ZX Spectrum block graphic escape sequences. It waits for any key with a BEEP on each poll iteration, making it both a visual and audible interrupt handler.
Key BASIC Idioms
- Keypress flush before wait: Line 2070 loops while
INKEY$<>""to drain any held key before the answer wait at line 2080 — standard debounce practice. - RUN as reset: Pressing ENTER (CHR$ 13) at lines 2085 and 3525 executes
RUN, returning to the start of the program cleanly. - VAL “number” in GO TO: Not present here; computed RESTORE targets are used instead for data navigation.
- ON ERR chain: Lines 9900–9930 use three successive ON ERR statements to cycle through reset, pause, and continue behaviors, providing a layered soft-error recovery.
- Decorative border loop: Lines 1007–1011 draw four concentric rectangles with a
FOR X=0 TO 3loop, each iteration offsetting the PLOT/DRAW coordinates by X to create a thick inset border effect.
Scoring Logic Differences Between Parts
Part I awards a point for every correct first-attempt answer (F), with no retry. Part II introduces a two-attempt system: variable E counts wrong tries per question; on the first wrong answer the program prints “TRY AGAIN” and loops back; only on the second wrong answer does it reveal the correct answer and move on. The score card in Part II therefore distinguishes “Right on first try” (F) from “Right on second try” (S).
Notable Anomalies
- Line 2140 in both parts is unreachable dead code — execution never falls through from
NEXT Zat line 2110 to 2140 because line 2120 calls the score subroutine and line 2130 goes to 1000. - In the Part I wrong-answer handler (line 6002), variables
U$,U, andVare used to save and restoreD$,C, andZaround a call toGO SUB 5500for rule display, butU$is never actually used after the restore, since the rule text is printed from within 5500 via READ. In Part II this save/restore is simplified andU$is dropped. - The Part II wrong-answer handler at line 6000 has a compound structure: the
IF E>1branch prints the answer and callsGO SUB 6030thenGO TO 2110, making the subsequent lines 6002–6020 only reachable on the first wrong attempt (E=1).
Content
Image Gallery
Source Code
5 CLS
10 FOR L=1 TO 12
20 READ L$
30 FOR X=0 TO 7
40 READ R: POKE USR L$+X,R
50 NEXT X
60 NEXT L
62 DATA "A",128,192,240,248,252,255,255,255,"C",240,248,252,255,255,255,255,255,"B",0,0,0,0,0,0,128,192,"D",0,0,0,0,128,192,240,248
64 DATA "E",252,255,255,255,255,255,255,255,"F",0,0,128,192,240,248,252,255,"G",255,255,255,255,255,255,255,252,"H",255,252,248,240,192,128,0,0
66 DATA "I",255,255,255,255,255,252,248,240,"J",248,240,192,128,0,0,0,0,"K",255,255,255,252,248,240,192,128,"L",192,128,0,0,0,0,0,0
100 PRINT AT 7,0;"::::::::::::::::::::::::::::::::";AT 8,0;"::::::::::::::::::::::::::::::::";AT 5,14;"ab";AT 6,14;"::cd";AT 7,16;"ef";AT 8,16; PAPER 5;"gh";AT 9,14;"::ij ";AT 10,14;"kl";AT 10,16;" ";AT 11,16;" "; INK 7;AT 11,14;"ab";AT 12,15;"cd ";AT 13,16;"ef"
110 PAPER 7: INK 2: PRINT AT 5,3;"SOFTWARE";AT 13,20;"EXCELLENCE";AT 18,5; FLASH 1;"Loading Main Program"
120 PAPER 7: INK 7
130 LOAD ""
10 DATA 5," RULES COVERED"," "," "," Capitalize the pronoun ""I"""," -Can I go?-"," "
11 DATA "You and i have excellent","golden tans this summer.",14,9,14,16,16,1,16,18,"1"
12 DATA "The soda, cake, and candy","i'd eaten made me less hungry.",14,5,14,11,14,20,16,1,"4"
13 DATA "Since it is so cold, i'm going","to have some hot chocolate.",14,16,14,22,16,14,16,19,"2"
14 DATA "Bruce said, ""i have a dime,","two dollars, and a penny.""",14,14,14,23,16,5,16,19,"1"
20 DATA 9," RULES COVERED"," ","Capitalize names and initials","given to people and pets."," -G.T. Brooks-"," "
21 DATA "Capitalize names and initials","given to places and things."," -K.W. Andrews School-"," "
22 DATA "The pictures of mountains and","beaches belong to Mrs. cohen.",14,5,14,17,16,1,16,24,"4"
23 DATA "The train to western New York","is the one mike takes today.",14,5,14,14,16,12,16,23,"3"
24 DATA "When I see mud and leaves on","the rug, I look for rex.",14,12,14,20,16,5,16,21,"4"
25 DATA "We have a gerbil and a dog","with the same name - suzy.",14,11,14,24,16,15,16,22,"4"
26 DATA "Did you purchase the watch and","ring on Delancy street?",14,5,14,22,16,1,16,17,"4"
27 DATA "Meet me in front of the J. T.","Hill building at noon.",14,6,14,12,16,6,16,18,"3"
28 DATA "Burton hall is where meetings","are held and disputes settled.",14,8,14,22,16,14,16,23,"1"
29 DATA "Homes Elementary school is","a block from your house.",14,18,16,3,16,14,16,19,"1"
30 DATA 9," RULES COVERED"," ","Capitalize the first word","in a sentence."," -The trees are-"," "
31 DATA "Capitalize the first word","in a quote."," -She said,""They are-"""," "
32 DATA "during the winter months","we ski in the mountains.",14,1,14,12,14,19,16,1,"1"
33 DATA "the redwood tree thrives in","foggy areas near the Pacific.",14,1,14,5,14,13,16,7,"1"
34 DATA "Isaac Newton described the","basic laws of motion to us.",14,24,16,7,16,15,16,25,"n"
35 DATA "opening the cupboard was","impossible for the dog and cat.",14,1,14,12,16,20,16,28,"1"
36 DATA "Mary said,""get the camera and","film before we go to town.""",14,12,14,20,16,1,16,22,"1"
37 DATA "The doctor's notebook had these","words: ""her throat is clear.""",14,5,14,14,16,1,16,9,"4"
38 DATA """Did you have time,"" she asked,","""to clean the china or silver?""",14,15,14,22,16,2,16,15,"n"
39 DATA """The wind is strong,"" she","noted. ""let's sail!""",14,6,14,23,16,1,16,9,"4"
40 DATA 14," RULES COVERED"," ","Capitalize titles used in","place of a person's name."," -Call Mother-"," "
41 DATA "Capitalize titles preceding","a proper name."," -Captain Smith-"," "
42 DATA "Capitalize titles ONLY when","they are used with, or in","place of, a person's name."," -Is your father-"
43 DATA "The guests are here. Is","mother back from town?",14,5,14,16,16,1,16,18,"3"
44 DATA "Some evening your mother","will wear her gold rings.",14,6,14,19,16,15,16,20,"n"
45 DATA "Did you go to your mother's","home over the holidays?",14,5,14,20,16,1,16,15,"n"
46 DATA "Did you know that mother","called your uncle's home?",14,5,14,19,16,13,16,21,"2"
47 DATA "Is the man in the blue","uniform captain Thompson?",14,8,14,19,16,1,16,9,"4"
48 DATA "For math we have professor","Brown. She has three degrees.",14,5,14,18,16,16,16,22,"2"
49 DATA "The high school graduation had","major James as a guest.",14,5,14,10,16,1,16,18,"3"
50 DATA "Is there a lieutenant in","the crowd who could help?",14,4,14,12,16,5,16,11,"n"
51 DATA "Will your uncle be here in","the winter or spring this year?",14,11,16,5,16,15,16,27,"n"
52 DATA "Our geography professor is an","expert on the world's oceans.",14,5,14,15,16,1,16,15,"n"
53 DATA "The doctor called aunt Judy,","my mother, and my sister.",14,5,14,19,16,4,16,19,"2"
54 DATA "The trip to the zoo was made","with my sister and my aunt.",14,5,14,17,16,9,16,23,"n"
60 DATA 1,1,"If I've carried enough stones","to the wagon, i'll quit.",14,4,14,24,16,8,16,15,"4"
61 DATA 2,1,"Debra's dog luke is","a small poodle.",14,9,14,13,16,3,16,9,"2"
62 DATA 2,5,"The pupils are working at Mast","Elementary school today.",14,5,14,16,16,12,16,19,"3"
63 DATA 3,1,"the wake of a great","tanker is hard to see.",14,1,14,5,16,1,16,19,"1"
64 DATA 3,5,"Josh said ""stop!"" to the girls","who were carrying the bottles.",14,12,14,26,16,1,16,23,"1"
65 DATA 4,1,"Will dad take you boys to","the river to fish today?",14,6,14,19,16,5,16,19,"1"
66 DATA 4,5,"For his hospital patients,","doctor Jones needs medicines.",14,9,14,18,16,1,16,20,"3"
67 DATA 4,9,"I asked the major if he had","traveled in the last year.",14,13,14,22,16,1,16,22,"n"
68 DATA 1,1,"To take this trip, i would","need money and more time.",14,14,14,20,16,6,16,21,"2"
69 DATA 2,1,"Robert tyre Jones was a","great champion golfer.",14,8,16,1,16,7,16,16,"1"
70 DATA 2,5,"You can eat fish and see ships","at the Harbor place in town.",14,13,14,26,16,15,16,24,"3"
71 DATA 3,1,"fortunately for us, jet","engines are safe and efficient.",14,1,14,17,14,21,16,1,"1"
72 DATA 3,5,"""Do you know,"" she said, ""how","to clip a poodle's nails?""",14,16,14,27,16,11,16,20,"n"
73 DATA 4,1,"Was grandfather the mayor","of a city years ago?",14,5,14,21,16,6,16,11,"1"
74 DATA 4,5,"Does uncle Josh have a","college degree in physics?",14,6,16,1,16,9,16,19,"1"
75 DATA 4,9,"When I had the flu, I went to","my doctor for tests and help.",14,16,16,4,16,15,16,25,"n"
76 DATA 1,1,"Last year i studied math,","geography, and English.",14,6,14,11,14,21,16,1,"2"
77 DATA 2,1,"Max and sam are both","good names for dogs.",14,9,14,17,16,6,16,16,"1"
78 DATA 2,5,"The Fisher building has auto","executives' offices.",14,12,14,25,16,1,16,13,"1"
79 DATA 3,1,"each of the boys carried","packages into the building.",14,1,14,13,16,1,16,19,"1"
80 DATA 3,5,"Karen asked, ""how do roses get","to the store in the winter?""",14,15,14,22,16,8,16,21,"1"
81 DATA 4,1,"This building was named after","grandmother seven years ago.",14,6,14,19,16,1,16,13,"3"
82 DATA 4,5,"When cousin Samuel starts his","car, we hold our ears.",14,6,16,1,16,6,16,18,"1"
83 DATA 4,9,"Did you ask mother when the","roast would be out of the oven?",14,5,14,13,16,1,16,27,"2"
90 DATA 1,"""If you want the ball,"" said","Tom, ""i will help you.""",14,5,14,18,16,7,16,19,"3"
91 DATA 2,"John f. Kennedy was the 35th","person to win the presidency.",14,6,14,27,16,1,16,19,"1"
92 DATA 2,"Which building has the office","where you apply for jobs?",14,7,14,24,16,7,16,21,"n"
93 DATA 3,"with good intentions, you can","often create problems.",14,1,14,11,14,23,16,14,"1"
94 DATA 3,"The coach said ""run!"" when","the team got to the field.",14,5,14,17,16,5,16,21,"2"
95 DATA 4,"Did your dad and mother ever","get the new car they wanted?",14,10,14,18,16,13,16,17,"n"
96 DATA 4,"For each student needing help","our nurse gave time and care.",14,10,16,5,16,16,16,25,"n"
97 DATA 4,"Nurses and doctors are part","of the team in a hospital.",14,12,14,24,16,8,16,18,"n"
98 DATA 1,"What if i won a house as","a prize in the contest?",14,9,14,17,16,3,16,16,"1"
99 DATA 2,"A small cat named kitty has","a red collar and green eyes.",14,9,14,19,16,7,16,24,"2"
100 DATA 2,"Executive house is the name","of a hotel in our city.",14,11,14,24,16,6,16,19,"1"
101 DATA 3,"if the older girls lead,","the younger girls will follow.",14,1,14,14,14,20,16,13,"1"
102 DATA 3,"""How,"" asked Judy, ""can you","climb the hill with that bike?""",14,21,14,25,16,11,16,26,"n"
103 DATA 4,"That pin belongs to mother, and","the watch is my father's.",14,6,14,21,16,5,16,17,"2"
104 DATA 4,"The car belongs to officer","Jones, who's in the station.",14,5,14,20,16,8,16,21,"2"
105 DATA 4,"Did you ask coach Wilson","if she had the soccer ball?",14,5,14,13,16,4,16,16,"2"
107 DATA 2,"Both the father and the son","were named Tom b. Smith.",14,10,14,25,16,6,16,16,"4"
108 DATA 2,"Which building on this street","is named Mann building?",14,7,14,24,16,4,16,15,"4"
109 DATA 3,"red cars are often used by","the fire department.",14,1,14,5,16,5,16,10,"1"
110 DATA 3,"Mark asked his teacher, ""when","will my sister get her books?""",14,16,14,26,16,9,16,24,"2"
111 DATA 4,"Did my aunt go with my","father and my mother to town?",14,8,16,1,16,15,16,25,"n"
112 DATA 4,"The sweater worn by professor","Smith had a college seal.",14,5,14,21,16,13,16,21,"2"
113 DATA 4,"The book in the professor's","hand is a best seller.",14,5,14,17,16,1,16,16,"n"
114 DATA 2,"In the winter,the same cardinal","visits. We call it big Red.",14,8,14,24,16,1,16,20,"4"
115 DATA 4,"Can I ask a question,professor,","about this math problem?",14,13,14,22,16,12,16,17,"2"
116 DATA 2,"The Anderson school enrolls","boys and girls ages 6 to 16.",14,14,16,1,16,10,16,17,"1"
117 DATA 3,"could you take the books","back to the library today?",14,1,14,20,16,13,16,21,"1"
118 DATA 3,"""If rain comes,"" she yelled,","""you must get coats and hats.""",14,5,14,18,16,2,16,15,"n"
120 DATA 4,"Mike's professor was an expert","in ancient coins and art.",14,8,14,25,16,12,16,22,"n"
121 DATA 4,"My doctor gave me a shot","of medicine for my flu.",14,4,14,21,16,4,16,20,"n"
300 ON ERR GO TO 9900: GO TO 1000
400 ON ERR GO TO 9900: GO SUB 3000
500 PAPER 6: INK 2: BORDER 6: CLS
510 PLOT 152,112: DRAW 0,15: DRAW 7,0: DRAW 0,-15: DRAW -7,0
520 PRINT AT 4,5;"CAPITALIZATION";
530 DRAW -120,0: DRAW 0,55: DRAW 127,0: DRAW 0,-40
540 PRINT AT 8,20;"MASTER"
550 DRAW 56,0: DRAW 0,-44: DRAW -63,0: DRAW 0,29
560 PRINT AT 5,27;"TM"
570 INK 4: PRINT AT 13,13;"Part I";AT 15,8;"Grades 4 thru 12";
580 INK 2: PRINT AT 20,7;"Copyright 1983 by";AT 21,4;"Software for Excellence";
590 PAUSE 240
1000 PAPER 7: BORDER 7: INK 0: CLS
1005 LET K=0: LET L=0: LET KL=0: LET LL=0: LET N=0: LET W1=0: LET W2=0: LET W3=0: LET W4=0: LET W5=0: LET T=4: LET E=0: LET S=0: LET F=0
1007 FOR X=0 TO 3
1010 PLOT 0,140: DRAW 255-X,0: DRAW 0,-140+X: DRAW -255+(2*X),0: DRAW 0,171-(2*X): DRAW 255-(2*X),0: DRAW 0,-31
1011 NEXT X
1020 PRINT AT 2,5;"Capitalization Part I";AT 7,1;"1 Capitalize ""I""";AT 8,1;"2 Capitalize proper names";AT 9,1;"3 Capitalize first words";AT 10,1;"4 Capitalize titles";AT 16,1;"5 Test Practice";AT 17,1;"6 Timed Test";
1030 INK 5: PLOT 8,131: DRAW 239,0: PLOT 8,59: DRAW 239,0
1040 INK 0: PAPER 5: PRINT AT 5,6;"Preparation - Rules";AT 14,8;"Training Camp";AT 20,7; FLASH 1;"CHOOSE A NUMBER";
1050 GO SUB 3510
1055 LET C=N
1060 IF C<1 OR C>6 THEN GO TO 1050
1070 IF C=6 THEN GO TO 2500
1080 IF C=5 THEN GO TO 2000
1090 GO TO 1500
1500 RESTORE C*10: PAPER 7: INK 0: CLS
1505 PLOT 0,16: DRAW 0,159: DRAW 255,0: DRAW 0,-159: DRAW -255,0
1507 READ N
1510 FOR X=1 TO N: READ D$: PRINT AT X+1,1;D$: NEXT X
1550 GO SUB 3500
1560 GO TO 2000
2000 GO SUB 4000
2004 IF C=2 OR C=3 THEN LET T=8
2005 IF C=4 THEN LET T=12
2006 IF C=5 THEN LET RA=6: LET RC=3: LET RM=9: LET T=24
2008 IF C=6 THEN LET RA=8: LET RC=2: LET RM=12: LET T=30
2010 FOR Z=1 TO T
2012 PAPER 7: CLS
2020 IF C<5 THEN GO SUB 5500
2022 IF C=5 THEN GO SUB 5584
2023 IF C=6 THEN READ CN
2030 PRINT AT 9,5;"Press the number under";AT 10,5;"the error or press n."
2040 READ D$: PRINT AT 13,1;D$
2045 READ D$: PRINT AT 15,1;D$
2050 PRINT AT 18,5;"1 2 3 4 n"
2052 FOR X=1 TO 4: READ LN: READ RN: PRINT AT LN,RN;X: NEXT X
2060 READ D$
2070 IF INKEY$<>"" THEN GO TO 2070
2075 IF C=6 THEN GO TO 2540
2080 LET A$=INKEY$: IF A$="" THEN GO TO 2080
2085 IF A$=CHR$ (13) THEN RUN
2087 IF A$<"1" OR A$>"4" THEN IF A$<>"n" AND A$<>"N" THEN GO TO 2080
2090 IF A$=D$ THEN GO TO 4500
2095 IF D$="n" AND A$="N" THEN GO TO 4500
2100 GO TO 6000
2110 NEXT Z
2120 GO SUB 4990
2130 GO TO 1000
2140 IF C<>1 THEN RESTORE C*10+1: READ D$: PRINT AT 5,1;D$: GO TO 2040
2150 GO TO 1000
2500 LET K$=" ": PAPER 7: CLS : PAPER 6: FOR X=1 TO 5: PRINT AT X,8;K$;: NEXT X: PLOT 64,128: DRAW 0,39: DRAW 127,0: DRAW 0,-39: DRAW -127,0: PRINT AT 3,11;"TIMED TEST";AT 8,2; PAPER 7;"To start the test,";AT 9,2;"type the code letters,";AT 10,2;"then press ENTER.": INPUT A$: IF A$<>"cap" AND A$<>"CAP" THEN PRINT AT 20,8;"SORRY WRONG CODE": PAUSE 100: GO TO 1000
2510 RESTORE 90
2530 GO SUB 2000
2535 GO TO 1000
2540 PRINT AT 0,22;"Time ";K;":";L;: IF L<10 THEN PRINT AT 0,30;" "
2550 PAUSE 60: LET A$=INKEY$: IF A$<>"" THEN GO TO 2600
2555 LET L=L+1: IF L=60 THEN LET K=K+1: LET L=0
2560 GO TO 2540
2600 IF A$=D$ THEN GO TO 2110
2603 IF A$<"1" OR A$>"4" THEN IF A$<>"n" AND A$<>"N" THEN GO TO 2540
2605 IF CN=1 THEN LET W1=W1+1
2610 IF CN=2 THEN LET W2=W2+1
2620 IF CN=3 THEN LET W3=W3+1
2630 IF CN=4 THEN LET W4=W4+1
2650 GO TO 2110
3000 LET RP=1+INT (7*RND): PAPER RP: INK 7-RP: CLS : RESTORE 3100
3010 FOR X=3 TO 17: READ G$: PRINT AT X,8;G$: NEXT X
3020 PRINT AT 20,7; INVERSE 1;"PRESS C TO CONTINUE"
3030 IF INKEY$="" THEN BEEP .3,10: GO TO 3030
3040 RETURN
3100 DATA ".''''. ''':''' .''. :''''.",": : : : : :"," ''''. : : : :....'",". : : '. .' : "," '''' ' '' ' "
3110 DATA " ''':''' : : :'''' "," : : : : "," : :'''': :'''"," : : : : "," ' ' ' ''''' "
3120 DATA "''':''' .''. :''''. :'''' "," : : : : : : "," : :....: :'''' :'''"," : : : : : "," ' ' ' ' ''''' "
3500 PRINT AT 20,7; FLASH 1;"PRESS C TO CONTINUE"
3510 IF INKEY$<>"" THEN GO TO 3510
3520 LET C$=INKEY$: IF C$="" THEN GO TO 3520
3525 IF C$=CHR$ (13) THEN RUN
3530 IF C$<"0" OR C$>"9" THEN RETURN
3540 LET N=VAL (C$): RETURN
4000 PAPER 7: CLS : PRINT AT 2,11;"DIRECTIONS";AT 4,2;"(1) You will be given a";AT 5,6;"sentence with four";AT 6,6;"numbered words.";AT 8,2;"(2) Find the word that has";AT 9,6;"a capitalization error.";AT 11,2;"(3) Press the number under";AT 12,6;"that word.";AT 14,2;"(4) Press ""n"" if there";AT 15,6;"is no error."
4010 PLOT 8,16: DRAW 0,152: DRAW 240,0: DRAW 0,-152: DRAW -240,0
4020 GO SUB 3500
4030 RETURN
4500 CLS : PAPER 5: LET K$=" "
4510 FOR X=1 TO 5: PRINT AT X+4,10;K$: NEXT X
4520 FOR X=1 TO 5: PRINT AT X+11,4;K$;AT X+11,15;K$;: NEXT X
4530 PRINT AT 7,13;"CORRECT";AT 14,6;Z;" DONE";AT 14,18;T-Z;" TO GO"
4540 PAPER 7: GO SUB 3500
4550 LET F=F+1
4580 GO TO 2110
4990 IF C=6 THEN GO TO 5050
5000 PAPER 7: CLS : PLOT 4,16: DRAW 0,137: DRAW 245,0: DRAW 0,-137: DRAW -245,0
5010 PRINT AT 2,8;"YOUR SCORE CARD";AT 5,2;F;" Right";AT 8,2;T-F;" Wrong";
5020 LET F=0: LET S=0
5030 GO SUB 3500
5035 IF C=5 THEN GO TO 5050
5040 RETURN
5050 PAPER 7: CLS : PLOT 0,15: DRAW 0,154: DRAW 255,0: DRAW 0,-154: DRAW -255,0
5060 LET R1=RC-W1: LET R2=RM-W2: LET R3=RA-W3: LET R4=RA-W4: LET R6=R1+R2+R3+R4
5070 PRINT AT 0,10;"TEST RESULTS";AT 2,1;"I";AT 2,17;R1;" of ";RC;AT 2,27;INT ((R1/RC)*100);"%"
5072 LET RN=17
5075 IF R2>9 THEN LET RN=16
5080 PRINT AT 4,1;"Proper names";AT 4,RN;R2;" of ";RM;AT 4,27;INT ((R2/RM)*100);"%"
5090 PRINT AT 6,1;"First words";AT 6,17;R3;" of ";RA;AT 6,27;INT ((R3/RA)*100);"%"
5100 PRINT AT 8,1;"Titles";AT 8,17;R4;" of ";RA;AT 8,27;INT ((R4/RA)*100);"%"
5120 PRINT AT 12,1;"Total";AT 12,16;R6;" of ";T;AT 12,27;INT ((R6/T)*100);"%"
5130 IF C=6 THEN PRINT AT 19,1;"Time Used : ";K;":";L;
5140 GO SUB 3500
5150 RETURN
5500 PLOT 3,171: DRAW 249,0: DRAW 0,-56: DRAW -249,0: DRAW 0,56
5502 IF Z>4 THEN GO TO 5700
5509 RESTORE C*10
5510 READ D: READ D$: READ D$
5520 FOR X=1 TO 4: READ D$
5530 PRINT AT X+1,1;D$
5540 NEXT X
5550 IF C=2 OR C=3 THEN RESTORE C*10+1+Z: GO TO 5582
5560 IF C=4 THEN RESTORE 42+Z: GO TO 5582
5580 RESTORE C*10+Z
5582 RETURN
5584 RESTORE 59+Z
5585 READ CN
5590 READ ZN
5600 RETURN
5700 IF C=2 THEN RESTORE 21: GO TO 5520
5710 IF C=3 THEN RESTORE 31: GO TO 5520
5720 IF Z<9 THEN RESTORE 41: GO TO 5520
5730 RESTORE 42: GO TO 5520
6002 IF C<>5 THEN GO TO 6010
6004 LET U$=D$: LET U=C: LET V=Z: LET C=CN: LET Z=ZN
6006 GO SUB 5500
6008 LET D$=U$: LET C=U: LET Z=V
6009 GO SUB 6035
6010 PRINT AT 1,1;"The rule is --";AT 6,1;"The correct answer is ";D$;".": GO SUB 3500
6020 GO TO 2110
6035 IF CN=1 THEN LET W1=W1+1
6040 IF CN=2 THEN LET W2=W2+1
6050 IF CN=3 THEN LET W3=W3+1
6060 IF CN=4 THEN LET W4=W4+1
6080 RETURN
9900 ON ERR RESET
9910 PAUSE 100
9920 ON ERR GO TO 9900
9930 ON ERR CONTINUE
5 CLS
10 FOR L=1 TO 12
20 READ L$
30 FOR X=0 TO 7
40 READ R: POKE USR L$+X,R
50 NEXT X
60 NEXT L
62 DATA "A",128,192,240,248,252,255,255,255,"C",240,248,252,255,255,255,255,255,"B",0,0,0,0,0,0,128,192,"D",0,0,0,0,128,192,240,248
64 DATA "E",252,255,255,255,255,255,255,255,"F",0,0,128,192,240,248,252,255,"G",255,255,255,255,255,255,255,252,"H",255,252,248,240,192,128,0,0
66 DATA "I",255,255,255,255,255,252,248,240,"J",248,240,192,128,0,0,0,0,"K",255,255,255,252,248,240,192,128,"L",192,128,0,0,0,0,0,0
100 PRINT AT 7,0;"::::::::::::::::::::::::::::::::";AT 8,0;"::::::::::::::::::::::::::::::::";AT 5,14;"ab";AT 6,14;"::cd";AT 7,16;"ef";AT 8,16; PAPER 5;"gh";AT 9,14;"::ij ";AT 10,14;"kl";AT 10,16;" ";AT 11,16;" "; INK 7;AT 11,14;"ab";AT 12,15;"cd ";AT 13,16;"ef"
110 PAPER 7: INK 2: PRINT AT 5,3;"SOFTWARE";AT 13,20;"EXCELLENCE";AT 18,5; FLASH 1;"Loading Main Program"
120 PAPER 7: INK 7
130 LOAD ""
10 DATA 15," RULES COVERED"," ","Capitalize names of national,","racial, and ethnic groups."," -an Italian community-"," "
11 DATA "Capitalize names of civic,","social, labor, fraternal, and","business groups."," -for the Boy Scouts-"," "
12 DATA "Do not capitalize proper names","which have acquired a more","general meaning."," -wear oxford cloth-"
13 DATA "The indians in","Idaho have large","land holdings.","1"
14 DATA "American negroes were","declared legally free by","President Lincoln.","1"
15 DATA "This city has a large","polish community active in","both business and politics.","2"
16 DATA "The chinese population in","San Francisco is one of the","largest in the nation.","1"
17 DATA "When can new","people join the","girl scouts?","3"
18 DATA "The Ford Motor company is","the second largest auto","maker in the world.","1"
19 DATA "Do you know the","symbol of the","American red cross?","3"
20 DATA "Her older sister is","a member of the Phi","Delta kappa sorority.","3"
21 DATA "The sun is shining in my","eyes. Would you please close","the venetian blinds?","4"
22 DATA "We must save some room","for dessert. They serve","excellent napoleons here.","4"
23 DATA "Would you like a Frankfurter","or a grilled cheese sandwich","for lunch today?","1"
24 DATA "I like french dressing.","What is your favorite","type of salad dressing?","4"
30 DATA 6," RULES COVERED"," ","Capitalize course titles and","subjects with country names,","but not other subjects."," -Physics I, math, French-"
31 DATA "Last year I studied","mathematics, English,","French, and spelling.","4"
32 DATA "Social studies II","is the one subject","that I am failing.","1"
33 DATA "Music, French, and","mathematics are given","after our lunch hour.","4"
34 DATA "I decided to take","Typing during","summer school.","2"
40 DATA 6," RULES COVERED"," ","Capitalize names of days,","months, and holidays, but","not the seasons."," -Saturday, Halloween-"
41 DATA "Does Christmas occur","on monday again","this year?","2"
42 DATA "The Little Rock","Festival is held in","the Spring each year.","3"
43 DATA "June and july are","two of my favorite","summer months.","1"
44 DATA "Do you know the","date on which palm","Sunday comes this year?","2"
50 DATA 18," RULES COVERED"," ","Capitalize specific","geographical names."," -Boston Harbor-"," "
51 DATA "Capitalize names of nations,","states, and cities."," -London, England-"," "
52 DATA "Capitalize names of regional","areas."," -the Southeast-"," "
53 DATA "Do not capitalize directions,","locations, or points on a","compass."," -eastern Iowa-"
54 DATA "San Francisco bay has","a beautiful blue-green","color.","1"
55 DATA "People in the East know more","about the Smokey Mountains","than people in the West.","4"
56 DATA "Venus and mars are","two planets that we","have studied closely.","1"
57 DATA "Some people who work in","New York City live on","Long Island.","4"
58 DATA "We took the train","to chicago, which is","west of my home.","2"
59 DATA "When our doctor in niles","saw the bump on my","head, he sent me home.","1"
60 DATA "When was the last","time you visited your","sister in St. Louis?","4"
61 DATA "When it is winter in the","United States, it is summer","in south America.","3"
62 DATA "Boston is a large city","in the northeast with","a great deal of shipping.","2"
63 DATA "My aunt and uncle","live in the South","in the winter.","4"
64 DATA "It is reported that more deer","than people live in the upper","Peninsula of Michigan.","2"
65 DATA "Those of you from the east","should raise your hands. We","have maps for you.","1"
66 DATA "We lived in western","New York for a","number of years.","4"
67 DATA "We go to the","western regions","in the summer.","4"
68 DATA "The department store is on","the East side of the street","across from the garage.","2"
69 DATA "If we drive Northwest","from here, we will","soon run into a lake.","1"
70 DATA 1,5,"One of the most important","unions in Detroit is the","united auto workers.","3"
71 DATA 1,9,"Must I wear my Navy blue","suit when I visit the Navy","Department in Washington?","1"
72 DATA 2,1,"The population of","asia is larger than that","of any other continent.","2"
73 DATA 1,1,"Early settlers in Michigan","found indians from at","least five different tribes.","2"
74 DATA 2,5,"Did you know that","Oklahoma has a city","named broken arrow?","3"
75 DATA 2,9,"If you come from the","Middle West you may have an","identifying speech pattern.","4"
76 DATA 2,13,"Do you live in","eastern Pennsylvania,","or more in the middle?","4"
77 DATA 3,1,"Geography and English are my","best subjects. Spelling and","Math are my worst.","3"
78 DATA 4,1,"Father's day is going","to be on June 19 this year","and on June 17 next year.","1"
79 DATA 2,9,"The southwest is one","of the fastest growing","areas in the country.","1"
80 DATA 2,13,"The Northern edge","of Utah is the","border with Idaho.","1"
81 DATA 3,1,"Kentucky history and","calculus are offered.","I also took biology I.","3"
82 DATA 4,1,"Tuesday we leave","home. We should","arrive wednesday.","3"
83 DATA 1,5,"Bob was a boy","Scout for a","number of years.","1"
84 DATA 1,9,"Did you know that my","brother cannot stand the","taste of Bologna?","3"
85 DATA 2,1,"Is the capital of","Russia in Europe","or in Asia?","4"
86 DATA 1,1,"California has large","numbers of orientals","throughout the state.","2"
87 DATA 2,5,"My father went to the","University of Ohio in","Columbus, Ohio.","4"
90 DATA 1,"Oraibi, Arizona, was","the home of Hopi indians","before Columbus was born.","2"
91 DATA 1,"Do you want a baked potato","or french fries along with","your steak?","4"
92 DATA 2,"In geography we saw","pictures of the white cliffs","of Dover in England.","2"
93 DATA 1,"Do you know if","Shiela is a member of","the Camp Fire girls?","3"
94 DATA 2,"The fish we caught","in montana were","mostly river trout.","2"
95 DATA 2,"We lived in the","east before moving","to California.","2"
96 DATA 2,"Would you prefer to","live in a climate like that","of Southern Texas?","3"
97 DATA 3,"Biology and Chemistry","can be taken after","eighth grade.","1"
98 DATA 4,"Do you know if New Year's","day is on a Thursday or","Friday this year?","2"
99 DATA 1,"We have an italian family","running one of the best","restaurants in our area.","1"
100 DATA 2,"Sweden and norway","are countries with","lots of cold weather.","1"
101 DATA 2,"The eastern shore of","Maryland is famous","for fishing and hunting.","1"
102 DATA 2,"If you were heading South","on this highway, how did","you see a large lake?","1"
103 DATA 3,"Mathematics and French are","hard to learn. Spelling,","English,and History are easy.","3"
104 DATA 4,"We need to be away","from monday through thursday","this year.","2"
105 DATA 1,"A major effort is made","by the lions clubs to","help blind people.","2"
106 DATA 1,"Does your brother","know how to count","using Roman numerals?","3"
107 DATA 2,"Did you ever see","pictures of mount","Everest in Nepal?","2"
108 DATA 1,"The community is","composed primarily","of caucasians.","3"
109 DATA 2,"Where is Carson city?","It is in western","Nevada.","1"
110 DATA 2,"The Northwest urban","areas get a lot","of rain.","4"
111 DATA 2,"Turn North at the","crossroads and you","will soon be in Iowa.","1"
112 DATA 3,"In the seventh grade","we teach history as","part of social studies I.","3"
113 DATA 4,"We will buy candy,","popcorn, and apples","for halloween visitors.","3"
114 DATA 1,"The Baltimore Colts","are in the National","football league.","3"
115 DATA 1,"She is wearing a","pair of green slacks","and an Angora sweater.","3"
116 DATA 2,"An inspiration for both","stories and music is the","Mississippi river.","3"
300 ON ERR GO TO 9900: GO TO 1000
400 ON ERR GO TO 9900: GO SUB 3000
500 PAPER 6: INK 2: BORDER 6: CLS
510 PLOT 152,112: DRAW 0,15: DRAW 7,0: DRAW 0,-15: DRAW -7,0
520 PRINT AT 4,5;"CAPITALIZATION";
530 DRAW -120,0: DRAW 0,55: DRAW 127,0: DRAW 0,-40
540 PRINT AT 8,20;"MASTER"
550 DRAW 56,0: DRAW 0,-44: DRAW -63,0: DRAW 0,29
560 PRINT AT 5,27;"TM"
570 INK 4: PRINT AT 13,13;"Part II";AT 15,8;"Grades 4 thru 12";
580 INK 2: PRINT AT 20,7;"Copyright 1983 by";AT 21,4;"Software for Excellence";
590 PAUSE 240
1000 PAPER 7: BORDER 7: INK 0: CLS
1005 LET K=0: LET L=0: LET KL=0: LET LL=0: LET N=0: LET W1=0: LET W2=0: LET W3=0: LET W4=0: LET W5=0: LET T=4: LET E=0: LET S=0: LET F=0
1007 FOR X=0 TO 3
1010 PLOT 0,140: DRAW 255-X,0: DRAW 0,-140+X: DRAW -255+(2*X),0: DRAW 0,171-(2*X): DRAW 255-(2*X),0: DRAW 0,-31
1011 NEXT X
1020 PRINT AT 2,5;"Capitalization Part II";AT 7,1;"1 Proper names of groups";AT 8,1;"2 Geographical names";AT 9,1;"3 School subjects";AT 10,1;"4 Names of days and months";AT 16,1;"5 Test Practice";AT 17,1;"6 Timed Test";
1030 INK 5: PLOT 8,131: DRAW 239,0: PLOT 8,59: DRAW 239,0
1040 INK 0: PAPER 5: PRINT AT 5,6;"Preparation - Rules";AT 14,8;"Training Camp";AT 20,7; FLASH 1;"CHOOSE A NUMBER";
1050 GO SUB 3510
1055 LET C=N
1060 IF C<1 OR C>6 THEN GO TO 1050
1070 IF C=6 THEN GO TO 2500
1080 IF C=5 THEN GO TO 2000
1090 GO TO 1500
1500 LET LN=1: RESTORE C*10: PAPER 7: INK 0: CLS
1502 IF C=2 THEN RESTORE 50: LET LN=0
1505 PLOT 0,16: DRAW 0,159: DRAW 255,0: DRAW 0,-159: DRAW -255,0
1507 READ N
1510 FOR X=1 TO N: READ D$: PRINT AT X+LN,1;D$: NEXT X
1550 GO SUB 3500
1560 GO TO 2000
2000 GO SUB 4000
2002 IF C=1 THEN LET T=12
2004 IF C=2 THEN LET T=16
2006 IF C=5 THEN LET RA=2: LET RC=6: LET RM=8: LET T=18
2008 IF C=6 THEN LET RA=3: LET RC=9: LET RM=12: LET T=27
2010 FOR Z=1 TO T
2012 PAPER 7: CLS
2020 IF C<5 THEN GO SUB 5500
2022 IF C=5 THEN GO SUB 5584
2023 IF C=6 THEN READ CN
2030 PRINT AT 9,9;"SELECT THE LINE";AT 10,7;"THAT HAS THE ERROR"
2040 FOR Y=1 TO 3: READ D$: PRINT AT Y+12,1;Y;" ";D$: NEXT Y
2050 PRINT AT 16,1;"4 No Error"
2060 READ D$
2070 IF INKEY$<>"" THEN GO TO 2070
2075 IF C=6 THEN GO TO 2540
2080 LET A$=INKEY$: IF A$="" THEN GO TO 2080
2085 IF A$=CHR$ (13) THEN RUN
2087 IF A$<"1" OR A$>"4" THEN GO TO 2080
2090 IF A$=D$ THEN GO TO 4500
2100 GO TO 6000
2110 NEXT Z
2120 GO SUB 4990
2130 GO TO 1000
2140 IF C<>1 THEN RESTORE C*10+1: READ D$: PRINT AT 5,1;D$: GO TO 2040
2150 GO TO 1000
2500 LET K$=" ": PAPER 7: CLS : PAPER 6: FOR X=1 TO 5: PRINT AT X,8;K$;: NEXT X: PLOT 64,128: DRAW 0,39: DRAW 127,0: DRAW 0,-39: DRAW -127,0: PRINT AT 3,11;"TIMED TEST";AT 8,2; PAPER 7;"To start the test,";AT 9,2;"type the code letters,";AT 10,2;"then press ENTER.": INPUT A$: IF A$<>"cap" AND A$<>"CAP" THEN PRINT AT 20,8;"SORRY WRONG CODE": PAUSE 100: GO TO 1000
2510 RESTORE 90
2530 GO SUB 2000
2535 GO TO 1000
2540 PRINT AT 0,22;"Time ";K;":";L;: IF L<10 THEN PRINT AT 0,30;" "
2550 PAUSE 60: LET A$=INKEY$: IF A$<>"" THEN GO TO 2600
2555 LET L=L+1: IF L=60 THEN LET K=K+1: LET L=0
2560 GO TO 2540
2600 IF A$=D$ THEN GO TO 2110
2603 IF A$<"1" OR A$>"4" THEN GO TO 2540
2605 IF CN=1 THEN LET W1=W1+1
2610 IF CN=2 THEN LET W2=W2+1
2620 IF CN=3 THEN LET W3=W3+1
2630 IF CN=4 THEN LET W4=W4+1
2650 GO TO 2110
3000 LET RP=1+INT (7*RND): PAPER RP: INK 7-RP: CLS : RESTORE 3100
3010 FOR X=3 TO 17: READ G$: PRINT AT X,8;G$: NEXT X
3020 PRINT AT 20,7; INVERSE 1;"PRESS C TO CONTINUE"
3030 IF INKEY$="" THEN BEEP .3,10: GO TO 3030
3040 RETURN
3100 DATA ".''''. ''':''' .''. :''''.",": : : : : :"," ''''. : : : :....'",". : : '. .' : "," '''' ' '' ' "
3110 DATA " ''':''' : : :'''' "," : : : : "," : :'''': :'''"," : : : : "," ' ' ' ''''' "
3120 DATA "''':''' .''. :''''. :'''' "," : : : : : : "," : :....: :'''' :'''"," : : : : : "," ' ' ' ' ''''' "
3500 PRINT AT 20,7; FLASH 1;"PRESS C TO CONTINUE"
3510 IF INKEY$<>"" THEN GO TO 3510
3520 LET C$=INKEY$: IF C$="" THEN GO TO 3520
3525 IF C$=CHR$ (13) THEN RUN
3530 IF C$<"0" OR C$>"9" THEN RETURN
3540 LET N=VAL (C$): RETURN
4000 PAPER 7: CLS : PRINT AT 2,11;"DIRECTIONS";AT 4,2;"(1) You will be given";AT 5,6;"four lines of words.";AT 7,2;"(2) Select the line that";AT 8,6;"has the error.";AT 10,2;"(3) Press the number";AT 11,6;"of that line."
4010 PLOT 8,16: DRAW 0,152: DRAW 240,0: DRAW 0,-152: DRAW -240,0
4020 GO SUB 3500
4030 RETURN
4500 CLS : PAPER 5: LET K$=" "
4510 FOR X=1 TO 5: PRINT AT X+4,10;K$: NEXT X
4520 FOR X=1 TO 5: PRINT AT X+11,4;K$;AT X+11,15;K$;: NEXT X
4530 PRINT AT 7,13;"CORRECT";AT 14,6;Z;" DONE";AT 14,18;T-Z;" TO GO"
4540 PAPER 7: GO SUB 3500
4550 IF E=1 THEN LET S=S+1
4560 IF E<>1 THEN LET F=F+1
4570 LET E=0
4580 GO TO 2110
4990 IF C=6 THEN GO TO 5050
5000 PAPER 7: CLS : PLOT 4,16: DRAW 0,137: DRAW 245,0: DRAW 0,-137: DRAW -245,0
5010 PRINT AT 2,8;"YOUR SCORE CARD";AT 5,2;F;" Right on first try";AT 7,2;S;" Right on second try";AT 9,2;T-F-S;" Wrong";
5020 LET F=0: LET S=0
5030 GO SUB 3500
5035 IF C=5 THEN GO TO 5050
5040 RETURN
5050 PAPER 7: CLS : PLOT 0,15: DRAW 0,154: DRAW 255,0: DRAW 0,-154: DRAW -255,0
5060 LET R1=RC-W1: LET R2=RM-W2: LET R3=RA-W3: LET R4=RA-W4: LET R6=R1+R2+R3+R4
5070 PRINT AT 0,10;"TEST RESULTS";AT 2,1;"Proper Names";AT 2,17;R1;" of ";RC;AT 2,27;INT ((R1/RC)*100);"%";AT 3,2;"of Groups";
5080 PRINT AT 5,1;"Geographical";AT 5,17;R2;" of ";RM;AT 5,27;INT ((R2/RM)*100);"%";AT 6,2;"Names"
5090 PRINT AT 8,1;"School";AT 8,17;R3;" of ";RA;AT 8,27;INT ((R3/RA)*100);"%";AT 9,2;"Subjects";
5100 PRINT AT 11,1;"Names of Days";AT 11,17;R4;" of ";RA;AT 11,27;INT ((R4/RA)*100);"%";AT 12,2;"and Months";
5120 PRINT AT 14,1;"Total";AT 14,16;R6;" of ";T;AT 14,27;INT ((R6/T)*100);"%"
5130 IF C=6 THEN PRINT AT 19,1;"Time Used : ";K;":";L;
5140 GO SUB 3500
5150 RETURN
5500 PLOT 3,171: DRAW 249,0: DRAW 0,-56: DRAW -249,0: DRAW 0,56
5502 IF C=2 THEN GO TO 5700
5505 IF C=1 AND Z>8 THEN RESTORE 12: GO TO 5520
5507 IF C=1 AND Z>4 THEN RESTORE 11: GO TO 5520
5509 RESTORE C*10
5510 READ D: READ D$: READ D$
5520 FOR X=1 TO 4: READ D$
5530 PRINT AT X+1,1;D$
5540 NEXT X
5550 IF C=1 THEN RESTORE 12+Z: GO TO 5582
5560 IF C=2 THEN RESTORE 53+Z: GO TO 5582
5580 RESTORE C*10+Z
5582 RETURN
5584 RESTORE 69+Z
5585 READ CN
5590 READ ZN
5600 RETURN
5700 IF Z<5 THEN RESTORE 50: GO TO 5510
5710 IF Z<9 THEN RESTORE 51: GO TO 5520
5720 IF Z<13 THEN RESTORE 52: GO TO 5520
5730 RESTORE 53: GO TO 5520
6000 LET E=E+1: IF E>1 THEN PRINT AT 6,1;"The correct answer is ";D$;".": GO SUB 3500: LET E=0: GO SUB 6030: GO TO 2110
6002 IF C<>5 THEN GO TO 6010
6004 LET U=C: LET V=Z: LET C=CN: LET Z=ZN
6006 GO SUB 5500
6008 LET C=U: LET Z=V
6010 PRINT AT 1,1;"The rule is --";AT 6,11;"TRY AGAIN": IF C=5 THEN GO TO 2022
6020 GO TO 2070
6030 IF C<5 THEN RETURN
6035 IF CN=1 THEN LET W1=W1+1
6040 IF CN=2 THEN LET W2=W2+1
6050 IF CN=3 THEN LET W3=W3+1
6060 IF CN=4 THEN LET W4=W4+1
6080 RETURN
9900 ON ERR RESET
9910 PAUSE 100
9920 ON ERR GO TO 9900
9930 ON ERR CONTINUE
Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.