Source Code
10 REM *** Call The Plummer
20 GO SUB 310: LET hi=0
30 GO SUB 280
40 GO SUB 210
50 LET p=INT (RND*30)+1: LET d=d+1: PRINT AT 0,25;"Drip ";d
60 FOR l=6 TO 18
70 PRINT AT 20,v; INK 6;" \g\h ";AT 21,v;" \i\j "
80 PRINT AT l,p; INK 5;" ";AT l+1,p;"\c\d";AT l+2,p;"\e\f"
90 IF l+2=20 AND v+1=p+1 OR l+2=20 AND v+2=p+1 OR l+2=20 AND v+2=p THEN LET sc=sc+1: PRINT AT 0,0;"SCORE ";sc
100 LET v=v+(INKEY$="8" AND v<28)-(INKEY$="5" AND v>0)
110 NEXT l
120 PRINT AT l,p;" ";AT l+1,p;" "
130 IF d=30 THEN GO TO 160
140 BEEP .01,INT (RND*10)+30
150 GO TO 50
160 PRINT AT 5,11;"GAME OVER"
170 PRINT ''''" You Scored ";sc
180 IF sc>hi THEN LET hi=sc
190 PRINT '''" Highest Score Today ";hi
200 INPUT "Press ENTER To Play Again."; LINE a$: GO TO 30
210 CLS
220 PRINT "SCORE ";sc
230 PRINT INK 2;"\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b"
240 PRINT INK 2;"\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a"
250 PRINT INK 2;"\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b"
260 PRINT INK 2;"\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a\b\a"
270 RETURN
280 BORDER 0: PAPER 0: INK 7: CLS : BRIGHT 0
290 LET sc=0: LET v=15: LET d=sc
300 RETURN
310 FOR a=0 TO 79
320 READ u: POKE USR "\a"+a,u
330 NEXT a: RETURN
340 DATA 255,u,u,u,u,u,0,u
350 DATA 252,u,u,u,u,u,0,u
360 DATA 0,u,u,u,u,1,PI,7
370 DATA 0,u,u,u,u,128,192,224
380 DATA 7,u,15,u,u,7,u,PI
390 DATA 224,u,240,u,u,224,u,192
400 DATA 0,u,127,63,95,111,119,59
410 DATA 0,u,254,u,253,251,u,246
420 DATA 62,63,U,u,31,u,u,u
430 DATA 14,254,u,u,252,u,u,u
440 REM a=\a b=\b c=\c d=\d e=\e f=\f g=\g h=\h i=\i j=\j
450 SAVE "LEAKING" LINE 10
