Turbos

“TURBOS” is a computer program that I wrote for engine building enthusiasts. I will try to explain how it works and what it does.

By taking an engine that has no turbo, blower, ect., and using it’s rated horsepower, the rpm’s it was rated at, and the engine’s cubic inch displacement, one can figure the cubic feet of air flow through the engine and thus calculate new horsepower ratings and cfm rates at different turbo boost pressures. Most “outright” sold turbo systems have 6 to 15 psi boost. Racing and pulling engines have higher boosts. But anyway you look at it, heat is generated when air is compressed, thus creating new problems at higher boost figures. Cooling the incoming turbo-compressed air, helps to increase power at lower temperatures. This method is called “intercooling”, and can be done in the outside air, or through the engine’s cooling system (thermostat temperature). At low boosts, intercooling is not helpful, but actually hinders results. But calculated results are interesting. Actual engine results will be slightly less due to friction.

Use the program as follows. Input all figures asked for, keeping in mind that outdoor ambient temperature ratings are almost always 70°F or 80°F when calculating engine figures. Engines rated in size by “cc”, can be converted (1 liter = 1000cc = approx. 61 cubic inches).

When entering cooling modes, air to air will be outdoor temperature in “F°”, and air to water will be the engine’s thermostat setting “F°”. The program rounds out all calculations to the nearest hundreth.

All calculations in the program, as far as temperature go, are figured in “absolute temperature”. Everything else in the program comes from physics of turbos, derived from formulas used by tractor manufacturers, but works well for almost all calculations of engines. The program prints out on a standard Timex 2040 (or comparable) printer.

Any questions? Please direct them to me and I’ll answer them as best as I can.

This program will run on the T/S 2068

   5 REM "SAVE "TURBOS" LINE 0"
   7 DEF FN X(A)=INT ((.005+A)*100)/100
  10 PRINT "THIS PROGRAM FIGURES "''"TURBOCHARGING A NORMALLY"''" ASPIRATED ENGINE."'''"IT TAKES INTO CONSIDERATION"''"THAT A TURBO IS 65% "''"EFFICIENT AND INTERCOOLING "''"IS 70% EFFICIENT."
  15 PRINT : PRINT "HIT [ENTER] TO CONTINUE."
  20 PAUSE 0
  30 INPUT "DISPLACEMENT OF ENGINE(CU.IN.)? ";CUIN
  40 INPUT "RATED HORSEPOWER?";HP
  50 INPUT "RPM HORSEPOWER WAS RATED AT?    ";RPM
  70 INPUT "OUTDOOR AMBIENT TEMPERATURE? (F) ";TEMP
  75 INPUT "AMOUNT OF BOOST OF TURBO? (PSI) ";BOOST
  80 LET CFM=.95*(CUIN*RPM/(2*1728))
  90 LET P1=14.7
 100 LET P2=BOOST+14.7
 110 LET T1=TEMP+460
 120 LET T2=T1*(P2/P1)↑.283
 130 LET TEMPRISE=(T2-T1)/.65
 140 LET TEMPOUT=TEMPRISE+TEMP
 150 LET DENRATIO=(T1/T2)*(P2/P1)
 160 LPRINT "ENGINE DISPLACEMENT=";CUIN
 165 LPRINT
 170 LPRINT "RATED HP=";HP;" AT ";RPM;" RPM"
 180 LPRINT
 185 LPRINT "CFM AIR THRU ENGINE NON-ASP.=   ";FN X(CFM): LPRINT
 190 LPRINT "OUTDOOR TEMP(F)=";TEMP: LPRINT
 195 LPRINT "TURBO BOOST=";BOOST;" PSI": LPRINT
 200 LPRINT "EST. TEMP. OUT OF TURBO=";FN X(TEMPOUT): LPRINT
 220 LPRINT "NEW CFM AIR FLOW=";FN X(CFM*DENRATIO): LPRINT
 230 LPRINT "NEW HP=";FN X(DENRATIO*HP)
 240 LPRINT : LPRINT
 250 INPUT "WANT TO CHECK ON INTERCOOLING?  (Y/N)";A$
 260 IF A$="Y" THEN CLS : GO SUB 500
 270 INPUT "WANT TO SEE ANOTHER BOOST VALUE? (Y/N)";B$
 280 IF B$="Y" THEN : CLS : GO TO 75
 290 INPUT "WANT TO FIGURE A DIFFERENT      ENGINE? (Y/N)";C$
 300 IF C$="Y" THEN CLEAR : CLS : GO TO 30
 310 GO TO 1000
 500 PRINT "INTERCOOLING CAN BE DONE TWO"'"WAYS."''"     1)AIR TO AIR "''"     2)AIR TO WATER."
 510 PRINT '"IN AIR TO AIR PUT IN OUTDOOR"''"AMBIENT AIR TEMPERATURE."''"IN AIR TO WATER PUT IN ENGINE"''"THERMOSTAT TEMPERATURE."
 520 INPUT "COOLING MODE (1/2)?";Z
 530 IF Z<1 OR Z>2 THEN GO TO 515
 540 INPUT "COOLING MODE TEMP. (F)?";CMT
 550 LET NEWTEMP=TEMPOUT-((TEMPOUT-CMT)*.70)
 560 LET X=NEWTEMP-TEMP
 570 LET NEWT2=X*.65+T1
 580 LET NEWDENRATIO=(T1/NEWT2)*(P2/P1)
 590 LET NEWHP=HP*NEWDENRATIO
 600 LET NEWCFM=CFM*NEWDENRATIO
 610 IF Z=1 THEN LPRINT "AIR TO AIR COOLING"
 620 IF Z=2 THEN LPRINT "AIR TO WATER COOLING"
 630 LPRINT "COOLING MEDIUM TEMP.=";CMT: LPRINT
 640 LPRINT "TEMP. OUT OF TURBO=";FN X(NEWTEMP): LPRINT
 650 LPRINT "CFM=";FN X(NEWCFM): LPRINT
 660 LPRINT "HP=";FN X(NEWHP): LPRINT
 670 LPRINT "INTERCOOLING LOWERED TEMP"'"BY ";FN X(TEMPOUT-NEWTEMP);" DEGREES": LPRINT
 680 LET V=TEMPOUT-NEWTEMP
 690 IF V>0 THEN GO TO 720
 700 LPRINT "INTERCOOLING AT THIS LOW"'"BOOST IS NOT BENEFICIAL"
 710 LPRINT : LPRINT : RETURN
 720 LET M=-14.7+(DENRATIO*14.7*NEWT2)/T1
 725 LPRINT "YOU COULD LOWER YOUR BOOST"'"TO ";FN X(M);" PSI AND STILL RETAIN"'"ORIGINAL HORSEPOWER."
 730 LPRINT : LPRINT
 740 RETURN
1000 STOP