CIMENT_BAS

In English: Jean-Claude Touzin's CIMENT_BAS, a SuperBASIC concrete calculator for home renovation projects. Given rectangular or cylindrical sections in feet and a cement:gravel ratio, it reports the volume in cubic feet and yards, the number of bags of cement, the gravel needed and approximate truckloads, the total weight, and the slab's thermal capacity in Btu per degree F. A worked example (a 12 by 20 foot driveway, 4 inches thick) and the full listing are given.

The article below is in French, as printed in QL_DOC n4 (June-July 1988).

---

Voici, en cette période de rénovation, un calculateur de ciment. Par exemple, disons qu’une personne veut faire elle-même sont entrée de garage en ciment, dont les mesures seront 12 pieds par 20 pieds, 4 pouces d’épais: Taper 1 pour carré ou rectangle; 1 pour une section; 12, 20 et .33 (4/12) pied pour l’épaisseur. Le programme vous donne alors le volume de votre section et vous demande le ratio ciment:gravier; taper le ratio voulu (en général 3); le programe vous fournit alors différents résultats, dont les plus intéressants sont le nombre de poches de ciment requis par votre projet ainsi que le nombre approximatif de voyage(s) de gravier. Il indique également le poids, qui peut avoir son importance dans certains cas. Une dernière donnée, “la capacité thermique” est une indication du nombre de Btu que pourra emmagasiné la masse de béton par degré F de différrence entre le béton et le milieu ambiant. Elle n’est pas nécessaire à ce programme, mais je l’ai laissée là pour ceux que ça pourrait intéresser. Je m’en sers dans d’autres programmes de simulation de perte thermique et de chauffage solaire d’une maison.

JEAN-CLAUDE TOUZIN
C.P. 41
LA SARRE QUEBEC
CANADA J9Z 2X4

100 REMark ciment règle 42
110 REMark pour gravier jusqu'à 2 1/2 po.
120 REMark par Jean-Claude Touzin   La Sarre Qc
130 :
140 REPeat ciment
150    CLS#0:CLS:intro
160    PRINT TO 15,"PROPORTION CIMENT:GRAVIER."
170    PRINT TO 10;"Calcul valable pour gravier jusqu'à 2 1/2 po."
180    PRINT "(N.B. 1 Pelletée de ciment doit égaler 1 pelletée de";
190    PRINT " gravier en volume.)"
200    PRINT#0, "1= carré ou rectangle""2= cylindre"
210    choix=INKEY$(-1)
220    IF choix<>1 AND choix<>2:END REPeat ciment
230    INPUT#0,"Combien de sections? "; sect
240    PRINT "Calcul en cours: ";
250    SELect ON choix
260       =1:PRINT sect;" sections de carrés ou rectangles":carre
270       =2:PRINT sect;" sections de cylindres":cylindre
280    END SELect
290    total
300    ratio
310    PRINT #0,"Taper une touche pour recommencer..."
320    PAUSE
330 END REPeat  ciment
340 :
350 DEFine PROCedure carre
360 DIM lo(sect),la(sect),ep(sect),t(sect)
370 FOR i=1 TO sect
380    PRINT#0, "Section # ";i;" (N.B. pouces/12= pieds)"
390    INPUT#0, "Longueur en pieds ";lo(i)
400    INPUT#0, "Largeur en pieds ";la(i)
410    INPUT#0, "Epaisseur en pieds ";ep(i)
420    t(i)=lo(i)*la(i)*ep(i)
430    PRINT TO 5,"section #";i;"= ";arrondi(t(i));" pi.cu."
440 END FOR i
450 END DEFine carre
460 :
470 DEFine PROCedure total
480 tot=0
490 FOR n=1 TO sect
500    tot=tot+t(n)
510 END FOR n
520 PRINT "Volume total= ";arrondi(tot);" pi.cu.";
530 totv=tot/27
540 PRINT " ou ";arrondi(totv);" verges cu."
550 END DEFine total
560 :
570 DEFine PROCedure ratio
580 INPUT#0, "Ratio ciment:gravier (1:2=2, 1:3=3, 1:4=4...) ";grav
590 PRINT "Ratio 1:";grav;" (i.e. 1 pelletée de ciment pour ";grav;" pelletées de gravier)"
600 poche_ciment=totv*42*(1/(1+grav))
610 gravier=(totv*42*(grav/(1+grav)))
620 PRINT "Ciment= ";arrondi(poche_ciment);" poches"
630 PRINT "Gravier= ";arrondi(gravier);" pi. cu. ou ";arrondi(gravier/27);" verges cu.'
640 REMark 12-15 v.c. par voyage
650 PRINT " (environ ";arrondi(gravier/27/12);" voyages)"
660 PRINT "Poids total: ";arrondi((poche_ciment*94)+(gravier*100));" lbs."
670 PRINT "Capacité thermique: ";arrondi(tot*32.2);" Btu/'F"
680 END DEFine ratio
690 :
700 DEFine PROCedure cylindre
710 DIM rayon(sect),haut(sect),t(sect)
720 FOR i=1 TO sect
730    PRINT#0, "Section # ";i;" (N.B. pouces/12= pieds)"
740    INPUT#0, "Diamètre en pieds ";diam:rayon(i)=diam/2
750    INPUT#0, "Hauteur en pieds ";haut(i)
760    t(i)=PI*(rayon(i)^2)*haut(i)
770    PRINT TO 5,"Section #";i;"= ";arrondi(t(i));" pi.cu."
780 END FOR i
790 END DEFine cylindre
800 :
810 DEFine FuNction arrondi(deux)
820  result=(INT((deux*100)+.5))/100
830   RETurn result
840 END DEFine arrondi
850 :
860 DEFine PROCedure intro
870 REMark MODE 4
880 WINDOW 512,256,0,0:PAPER 5:CLS
890      fenetre 1,504,190,2,4,2
900      fenetre 0,504,48,2,202,4
910 END DEFine intro
920 :
930 DEFine PROCedure fenetre (canal,x,y,ox,oy,couleur)
940 WINDOW#canal,x,y,ox+4,oy+4
950 PAPER#canal,0:CLS#canal
960 WINDOW#canal,x,y,ox,oy
970 PAPER#canal,couleur
980 CLS#canal
990 INK#canal,7*(couleur<4)
1000 BORDER#canal,1,0
1010 END DEFine fenetre