Big Letters: The ENLARGE Procedure

In English: A SuperBASIC procedure, ENLARGE, that draws enlarged text on the screen with BLOCK by reading the character patterns of the QL's built-in fonts, taking the string, character spacing, width, height, X and Y position and colour. A short demo (lines 120-230) writes QL_DOC and "Le bulletin QUEBECOIS pour QL seulement" in big shadowed letters and cycles the colours with RECOL.

Printed title: GROSSES LETTRES .procedure ENLARGE. The article below is in French, as printed in QL_DOC n7 (December 1988-January 1989).

---

100 REMark GROSSES LETTRES  .procedure ENLARGE
110 :
120 MODE 4:WINDOW 512,206,0,0:PAPER 0:INK 7:CLS:CLS#0
130 ENLARGE 'QL_DOC',2,10,10,50,20,63
140 ENLARGE 'QL_DOC',2,10,10,52,22,2
150 ENLARGE 'Le bulletin QUEBECOIS pour QL seulement',1,2,5,5,116,7
160 ENLARGE 'Le bulletin QUEBECOIS pour QL seulement',1,2,5,6,117,4
170 ENLARGE 'QL',2,30,6,83,163,33
180 ENLARGE 'SINCLAIR',1,10,2,10,180,24
190 :
200 REPeat demo
210 RECOL 0,1,4,3,2,5,6,7
220 RECOL 0,1,2,3,4,5,6,7
230 END REPeat demo
240 :
250 :
260 DEFine PROCedure ENLARGE(STRING$,espace,large,haut,X,Y,couleur)
270 LOCal BASE1,BASE2,BYTE,BIT,PEEKED,ADRESSE,CAR,ACROSS,CDE
280 BASE1=PEEK_L(42+(PEEK_L(PEEK_L(163960)+4)))-277
290 BASE2=PEEK_L(46+(PEEK_L(PEEK_L(163960)+4)))-1141
300 FOR CAR=1 TO LEN(STRING$)
310   CDE=CODE(STRING$(CAR))
320   SELect ON CDE
330    =32 TO 127 :ADRESSE=BASE1+9*CDE
340    =128 TO 191:ADRESSE=BASE2+9*CDE
350    =REMAINDER :ADRESSE=BASE2+1143
360   END SELect
370   FOR BYTE=0 TO 8
380    PEEKED=PEEK(ADRESSE+BYTE)
390    IF PEEKED > 0 THEN
400     ACROSS =X+(large*(5+espace)*(CAR-1))
410 FOR BIT=64,32,16,8,4
420     IF (PEEKED && BIT)>0
430     BLOCK large,haut,ACROSS,Y+BYTE*haut,couleur
440     END IF
450     ACROSS=ACROSS+large
460    END FOR BIT
470   END IF
480  END FOR BYTE
490 END FOR CAR
500 END DEFine ENLARGE

Ce programme contient une procédure ENLARGE qui “imprime” des grosses lettres à l’écran.

Les paramètres sont: STRING$ - ce qu'on veut imprimer
                     espace  - espace entre les caractères
                     large   - largeur des caractères
                     haut    - hauteur des caractères
                     X & Y   - position graphique de l'impression
                     couleur - vous l'avez deviner, c'est la couleur
                               que l'on veut!

Essayez le petit demo (lignes 120-230)…